source: trunk/grails-app/taglib/dbnp/studycapturing/WizardTagLib.groovy @ 353

Last change on this file since 353 was 353, checked in by duh, 9 years ago
  • refactored termField tag
  • refactored subjects page
  • added terms and ontologies to bootstrap
  • Property svn:keywords set to Date Rev Author
File size: 20.8 KB
Line 
1package dbnp.studycapturing
2
3import org.codehaus.groovy.grails.plugins.web.taglib.JavascriptTagLib
4import dbnp.studycapturing.*
5import dbnp.data.*
6
7/**
8 * Wizard tag library
9 *
10 * @author Jeroen Wesbeek
11 * @since 20100113
12 * @package wizard
13 *
14 * Revision information:
15 * $Rev: 353 $
16 * $Author: duh $
17 * $Date: 2010-04-20 08:49:54 +0000 (di, 20 apr 2010) $
18 */
19class WizardTagLib extends JavascriptTagLib {
20        // define the tag namespace (e.g.: <wizard:action ... />
21        static namespace = "wizard"
22
23        // define the AJAX provider to use
24        static ajaxProvider = "jquery"
25
26        // define default text field width
27        static defaultTextFieldSize = 25;
28
29        /**
30         * ajaxButton tag, this is a modified version of the default
31         * grails submitToRemote tag to work with grails webflows.
32         * Usage is identical to submitToRemote with the only exception
33         * that a 'name' form element attribute is required. E.g.
34         * <wizard:ajaxButton name="myAction" value="myButton ... />
35         *
36         * you can also provide a javascript function to execute after
37         * success. This behaviour differs from the default 'after'
38         * action which always fires after a button press...
39         *
40         * @see http://blog.osx.eu/2010/01/18/ajaxifying-a-grails-webflow/
41         * @see http://www.grails.org/WebFlow
42         * @see http://www.grails.org/Tag+-+submitToRemote
43         * @todo perhaps some methods should be moved to a more generic
44         *        'webflow' taglib or plugin
45         * @param Map attributes
46         * @param Closure body
47         */
48        def ajaxButton = {attrs, body ->
49                // get the jQuery version
50                def jQueryVersion = grailsApplication.getMetadata()['plugins.jquery']
51
52                // fetch the element name from the attributes
53                def elementName = attrs['name'].replaceAll(/ /, "_")
54
55                // javascript function to call after success
56                def afterSuccess = attrs['afterSuccess']
57
58                // src parameter?
59                def src = attrs['src']
60                def alt = attrs['alt']
61
62                // generate a normal submitToRemote button
63                def button = submitToRemote(attrs, body)
64
65                /**
66                 * as of now (grails 1.2.0 and jQuery 1.3.2.4) the grails webflow does
67                 * not properly work with AJAX as the submitToRemote button does not
68                 * handle and submit the form properly. In order to support webflows
69                 * this method modifies two parts of a 'normal' submitToRemote button:
70                 *
71                 * 1) replace 'this' with 'this.form' as the 'this' selector in a button
72                 *    action refers to the button and / or the action upon that button.
73                 *    However, it should point to the form the button is part of as the
74                 *    the button should submit the form data.
75                 * 2) prepend the button name to the serialized data. The default behaviour
76                 *    of submitToRemote is to remove the element name altogether, while
77                 *    the grails webflow expects a parameter _eventId_BUTTONNAME to execute
78                 *    the appropriate webflow action. Hence, we are going to prepend the
79                 *    serialized formdata with an _eventId_BUTTONNAME parameter.
80                 */
81                if (jQueryVersion =~ /^1.([1|2|3]).(.*)/) {
82                        // fix for older jQuery plugin versions
83                        button = button.replaceFirst(/data\:jQuery\(this\)\.serialize\(\)/, "data:\'_eventId_${elementName}=1&\'+jQuery(this.form).serialize()")
84                } else {
85                        // as of jQuery plugin version 1.4.0.1 submitToRemote has been modified and the
86                        // this.form part has been fixed. Consequently, our wrapper has changed as well...
87                        button = button.replaceFirst(/data\:jQuery/, "data:\'_eventId_${elementName}=1&\'+jQuery")
88                }
89
90                // add an after success function call?
91                // usefull for performing actions on success data (hence on refreshed
92                // wizard pages, such as attaching tooltips)
93                if (afterSuccess) {
94                        button = button.replaceFirst(/\.html\(data\)\;/, '.html(data);' + afterSuccess + ';')
95                }
96
97                // got an src parameter?
98                if (src) {
99                        def replace = 'type="image" src="' + src + '"'
100
101                        if (alt) replace = replace + ' alt="' + alt + '"'
102
103                        button = button.replaceFirst(/type="button"/, replace)
104                }
105
106                // replace double semi colons
107                button = button.replaceAll(/;{2,}/, ';')
108
109                // render button
110                out << button
111        }
112
113        /**
114         * generate a ajax submit JavaScript
115         * @see WizardTagLib::ajaxFlowRedirect
116         * @see WizardTagLib::baseElement (ajaxSubmitOnChange)
117         */
118        def ajaxSubmitJs = {attrs, body ->
119                // define AJAX provider
120                setProvider([library: ajaxProvider])
121
122                // got a function name?
123                def functionName = attrs.remove('functionName')
124                if (functionName && !attrs.get('name')) {
125                        attrs.name = functionName
126                }
127
128                // generate an ajax button
129                def button = this.ajaxButton(attrs, body)
130
131                // strip the button part to only leave the Ajax call
132                button = button.replaceFirst(/<[^\"]*\"jQuery.ajax/, 'jQuery.ajax')
133                button = button.replaceFirst(/return false.*/, '')
134
135                // change form if a form attribute is present
136                if (attrs.get('form')) {
137                        button = button.replaceFirst(/this\.form/,
138                                "\\\$('" + attrs.get('form') + "')"
139                        )
140                }
141
142                out << button
143        }
144
145        /**
146         * generate ajax webflow redirect javascript
147         *
148         * As we have an Ajaxified webflow, the initial wizard page
149         * cannot contain a wizard form, as upon a failing submit
150         * (e.g. the form data does not validate) the form should be
151         * shown again. However, the Grails webflow then renders the
152         * complete initial wizard page into the success div. As this
153         * ruins the page layout (a page within a page) we want the
154         * initial page to redirect to the first wizard form to enter
155         * the webflow correctly. We do this by emulating an ajax post
156         * call which updates the wizard content with the first wizard
157         * form.
158         *
159         * Usage: <wizard:ajaxFlowRedirect form="form#wizardForm" name="next" url="[controller:'wizard',action:'pages']" update="[success:'wizardPage',failure:'wizardError']" />
160         * form = the form identifier
161         * name = the action to execute in the webflow
162         * update = the divs to update upon success or error
163         *
164         * OR: to generate a JavaScript function you can call yourself, use 'functionName' instead of 'name'
165         *
166         * Example initial webflow action to work with this javascript:
167         * ...
168         * mainPage {*  render(view: "/wizard/index")
169         *      onRender {*             flow.page = 1
170         *}*    on("next").to "pageOne"
171         *}* ...
172         *
173         * @param Map attributes
174         * @param Closure body
175         */
176        def ajaxFlowRedirect = {attrs, body ->
177                // generate javascript
178                out << '<script type="text/javascript">'
179                out << '$(document).ready(function() {'
180                out << ajaxSubmitJs(attrs, body)
181                out << '});'
182                out << '</script>'
183        }
184
185        /**
186         * render the content of a particular wizard page
187         * @param Map attrs
188         * @param Closure body  (help text)
189         */
190        def pageContent = {attrs, body ->
191                // define AJAX provider
192                setProvider([library: ajaxProvider])
193
194                // render new body content
195                out << render(template: "/wizard/common/tabs")
196                out << '<div class="content">'
197                out << body()
198                out << '</div>'
199                out << render(template: "/wizard/common/navigation")
200                out << render(template: "/wizard/common/error")
201        }
202
203        /**
204         * generate a base form element
205         * @param String inputElement name
206         * @param Map attributes
207         * @param Closure help content
208         */
209        def baseElement = {inputElement, attrs, help ->
210                // work variables
211                def description = attrs.remove('description')
212                def addExampleElement = attrs.remove('addExampleElement')
213                def addExample2Element = attrs.remove('addExample2Element')
214                def helpText = help().trim()
215
216                // got an ajax onchange action?
217                def ajaxOnChange = attrs.remove('ajaxOnChange')
218                if (ajaxOnChange) {
219                        if (!attrs.onChange) attrs.onChange = ''
220
221                        // add onChange AjaxSubmit javascript
222                        attrs.onChange += ajaxSubmitJs(
223                                [
224                                        functionName: ajaxOnChange,
225                                        url: attrs.get('url'),
226                                        update: attrs.get('update'),
227                                        afterSuccess: attrs.get('afterSuccess')
228                                ],
229                                ''
230                        )
231                }
232
233                // execute inputElement call
234                def renderedElement = "$inputElement"(attrs)
235
236                // if false, then we skip this element
237                if (!renderedElement) return false
238
239                // render a form element
240                out << '<div class="element">'
241                out << ' <div class="description">'
242                out << description
243                out << ' </div>'
244                out << ' <div class="input">'
245                out << renderedElement
246                if (helpText.size() > 0) {
247                        out << '        <div class="helpIcon"></div>'
248                }
249
250                // add an disabled input box for feedback purposes
251                // @see dateElement(...)
252                if (addExampleElement) {
253                        def exampleAttrs = new LinkedHashMap()
254                        exampleAttrs.name = attrs.get('name') + 'Example'
255                        exampleAttrs.class = 'isExample'
256                        exampleAttrs.disabled = 'disabled'
257                        exampleAttrs.size = 30
258                        out << textField(exampleAttrs)
259                }
260
261                // add an disabled input box for feedback purposes
262                // @see dateElement(...)
263                if (addExample2Element) {
264                        def exampleAttrs = new LinkedHashMap()
265                        exampleAttrs.name = attrs.get('name') + 'Example2'
266                        exampleAttrs.class = 'isExample'
267                        exampleAttrs.disabled = 'disabled'
268                        exampleAttrs.size = 30
269                        out << textField(exampleAttrs)
270                }
271
272                out << ' </div>'
273
274                // add help content if it is available
275                if (helpText.size() > 0) {
276                        out << '  <div class="helpContent">'
277                        out << '    ' + helpText
278                        out << '  </div>'
279                }
280
281                out << '</div>'
282        }
283
284        /**
285         * render an ajaxButtonElement
286         * @param Map attrs
287         * @param Closure body  (help text)
288         */
289        def ajaxButtonElement = { attrs, body ->
290                baseElement.call(
291                        'ajaxButton',
292                        attrs,
293                        body
294                )
295        }
296
297        /**
298         * render a textFieldElement
299         * @param Map attrs
300         * @param Closure body  (help text)
301         */
302        def textFieldElement = {attrs, body ->
303                // set default size, or scale to max length if it is less than the default size
304                if (!attrs.get("size")) {
305                        if (attrs.get("maxlength")) {
306                                attrs.size = ((attrs.get("maxlength") as int) > defaultTextFieldSize) ? defaultTextFieldSize : attrs.get("maxlength")
307                        } else {
308                                attrs.size = defaultTextFieldSize
309                        }
310                }
311
312                // render template element
313                baseElement.call(
314                        'textField',
315                        attrs,
316                        body
317                )
318        }
319
320        /**
321         * render a select form element
322         * @param Map attrs
323         * @param Closure body  (help text)
324         */
325        def selectElement = {attrs, body ->
326                baseElement.call(
327                        'select',
328                        attrs,
329                        body
330                )
331        }
332
333        /**
334         * render a checkBox form element
335         * @param Map attrs
336         * @param Closure body  (help text)
337         */
338        def checkBoxElement = {attrs, body ->
339                baseElement.call(
340                        'checkBox',
341                        attrs,
342                        body
343                )
344        }
345
346        /**
347         * render a dateElement
348         * NOTE: datepicker is attached through wizard.js!
349         * @param Map attrs
350         * @param Closure body  (help text)
351         */
352        def dateElement = {attrs, body ->
353                // transform value?
354                if (attrs.value instanceof Date) {
355                        // transform date instance to formatted string (dd/mm/yyyy)
356                        attrs.value = String.format('%td/%<tm/%<tY', attrs.value)
357                }
358
359                // add 'rel' field to identity the datefield using javascript
360                attrs.rel = 'date'
361
362                // set some textfield values
363                attrs.maxlength = (attrs.maxlength) ? attrs.maxlength : 10
364                attrs.addExampleElement = true
365
366                // render a normal text field
367                //out << textFieldElement(attrs,body)
368                textFieldElement.call(
369                        attrs,
370                        body
371                )
372        }
373
374        /**
375         * render a dateElement
376         * NOTE: datepicker is attached through wizard.js!
377         * @param Map attrs
378         * @param Closure body  (help text)
379         */
380        def timeElement = {attrs, body ->
381                // transform value?
382                if (attrs.value instanceof Date) {
383                        // transform date instance to formatted string (dd/mm/yyyy)
384                        attrs.value = String.format('%td/%<tm/%<tY %<tH:%<tM', attrs.value)
385                }
386
387                // add 'rel' field to identity the field using javascript
388                attrs.rel = 'datetime'
389
390                attrs.addExampleElement = true
391                attrs.addExample2Element = true
392                attrs.maxlength = 16
393
394                // render a normal text field
395                //out << textFieldElement(attrs,body)
396                textFieldElement.call(
397                        attrs,
398                        body
399                )
400        }
401
402        /**
403         * Button form element
404         * @param Map attributes
405         * @param Closure help content
406         */
407        def buttonElement = {attrs, body ->
408                // render template element
409                baseElement.call(
410                        'ajaxButton',
411                        attrs,
412                        body
413                )
414        }
415
416
417        /**
418         * Term form element
419         * @param Map attributes
420         * @param Closure help content
421         */
422        def termElement = { attrs, body ->
423                // render term element
424                baseElement.call(
425                        'termSelect',
426                        attrs,
427                        body
428                )
429        }
430
431        /**
432         * Term select element
433         * @param Map attributes
434         */
435        def termSelect = { attrs ->
436                def from = []
437
438                // got ontologies?
439                if (attrs.ontology) {
440                        attrs.ontology.split(/\,/).each() { ncboId ->
441                                // trim the id
442                                ncboId.trim()
443                               
444                                // fetch all terms for this ontology
445                                def ontology = Ontology.findAllByNcboId(ncboId)
446
447                                // does this ontology exist?
448                                if (ontology) {
449                                        ontology.each() {
450                                                Term.findAllByOntology(it).each() {
451                                                        // key = ncboId:concept-id
452                                                        from[ from.size() ] = it.name
453                                                }
454                                        }
455                                }
456                        }
457
458                        // sort alphabetically
459                        from.sort()
460                       
461                        // define 'from'
462                        attrs.from = from
463
464                        out << select(attrs)
465                } else {
466                        out << "you should specify: <i>ontology=\"id\"</i> or <i>ontology=\"id1,id2,...,idN\"</i>"
467                }
468        }
469
470        /**
471         * Template form element
472         * @param Map attributes
473         * @param Closure help content
474         */
475        def speciesElement = {attrs, body ->
476                // render template element
477                baseElement.call(
478                        'speciesSelect',
479                        attrs,
480                        body
481                )
482        }
483
484        /**
485         * render a species select element
486         * @param Map attrs
487         */
488        def speciesSelect = {attrs ->
489                // fetch the speciesOntology
490                // note that this is a bit nasty, probably the ontologyName should
491                // be configured in a configuration file... --> TODO: centralize species configuration
492                def speciesOntology = Ontology.findByName('NCBI Taxonomy')
493
494                // fetch all species
495                attrs.from = Term.findAllByOntology(speciesOntology)
496
497                // got a name?
498                if (!attrs.name) {
499                        // nope, use a default name
500                        attrs.name = 'species'
501                }
502
503                out << select(attrs)
504        }
505
506        /**
507         * Ontology form element
508         * @param Map attributes
509         * @param Closure help content
510         */
511        def ontologyElement = { attrs, body ->
512                // @see http://www.bioontology.org/wiki/index.php/NCBO_Widgets#Term-selection_field_on_a_form
513                // @see ontology-chooser.js, table-editor.js
514                baseElement.call(
515                        'textField',
516                        [
517                            name: attrs.name,
518                                value: attrs.value,
519                                description: attrs.description,
520                                rel: 'ontology-' + ((attrs.ontology) ? attrs.ontology : 'all') + '-name',
521                                size: 25
522                        ],
523                        body
524                )
525                out << hiddenField(
526                        name: attrs.name + '-concept_id'
527                )
528                out << hiddenField(
529                        name: attrs.name + '-ontology_id'
530                )
531                out << hiddenField(
532                        name: attrs.name + '-full_id'
533                )
534        }
535
536        /**
537         * Study form element
538         * @param Map attributes
539         * @param Closure help content
540         */
541        def studyElement = { attrs, body ->
542                // render study element
543                baseElement.call(
544                        'studySelect',
545                        attrs,
546                        body
547                )
548        }
549
550
551        /**
552         * render a study select element
553         * @param Map attrs
554         */
555        def studySelect = { attrs ->
556                // for now, just fetch all studies
557                attrs.from = Study.findAll()
558
559                // got a name?
560                if (!attrs.name) {
561                        attrs.name = "study"
562                }
563
564                // got result?
565                if (attrs.from.size() > 0) {
566                        out << select(attrs)
567                } else {
568                        // no, return false to make sure this element
569                        // is not rendered in the template
570                        return false
571                }
572        }
573
574        /**
575         * Template form element
576         * @param Map attributes
577         * @param Closure help content
578         */
579        def templateElement = {attrs, body ->
580                // render template element
581                baseElement.call(
582                        'templateSelect',
583                        attrs,
584                        body
585                )
586        }
587
588        /**
589         * render a template select element
590         * @param Map attrs
591         */
592        def templateSelect = {attrs ->
593                def entity = attrs.remove('entity')
594
595                // fetch templates
596                if (attrs.remove('addDummy')) {
597                        attrs.from = ['']
598                        if (entity && entity instanceof Class) {
599                                Template.findAllByEntity(entity).each() {
600                                        attrs.from[attrs.from.size()] = it
601                                }
602                        }
603                } else {
604                        attrs.from = (entity) ? Template.findAllByEntity(entity) : Template.findAll()
605                }
606
607                // got a name?
608                if (!attrs.name) {
609                        attrs.name = 'template'
610                }
611
612                // got result?
613                if (attrs.from.size() > 0) {
614                        out << select(attrs)
615                } else {
616                        // no, return false to make sure this element
617                        // is not rendered in the template
618                        return false
619                }
620        }
621
622        /**
623         * Protocol form element
624         * @param Map attributes
625         * @param Closure help content
626         */
627        def protocolElement = {attrs, body ->
628                // render protocol element
629                baseElement.call(
630                        'protocolSelect',
631                        attrs,
632                        body
633                )
634        }
635
636        /**
637         * render a protocol select element
638         * @param Map attrs
639         */
640        def protocolSelect = {attrs ->
641                // fetch all protocold
642                attrs.from = Protocol.findAll() // for now, all protocols
643
644                // got a name?
645                if (!attrs.name) {
646                        attrs.name = 'protocol'
647                }
648
649                out << select(attrs)
650        }
651
652        def show = {attrs ->
653                // is object parameter set?
654                def o = attrs.object
655
656                println o.getProperties();
657                o.getProperties().each {
658                        println it
659                }
660
661                out << "!! test version of 'show' tag !!"
662        }
663
664        /**
665         * render table headers for all subjectFields in a template
666         * @param Map attributes
667         */
668        def templateColumnHeaders = {attrs ->
669                def template = attrs.remove('template')
670
671                // output table headers for template fields
672                template.fields.each() {
673                        out << '<div class="' + attrs.get('class') + '">' + it + '</div>'
674                }
675        }
676
677        /**
678         * render table input elements for all subjectFields in a template
679         * @param Map attributes
680         */
681        def templateColumns = {attrs, body ->
682                def subject = attrs.remove('subject')
683                def subjectId = attrs.remove('id')
684                def template = attrs.remove('template')
685                def intFields = subject.templateIntegerFields
686                def stringFields = subject.templateStringFields
687                def floatFields = subject.templateFloatFields
688                def termFields = subject.templateTermFields
689
690                // output columns for these subjectFields
691                template.fields.each() {
692                        def fieldValue = subject.getFieldValue(it.name)
693
694                        // output div
695                        out << '<div class="' + attrs.get('class') + '">'
696
697                        // handle field types
698                        switch (it.type.toString()) {
699                                case ['STRING', 'TEXT', 'INTEGER', 'FLOAT', 'DOUBLE']:
700                                        out << textField(
701                                                name: attrs.name + '_' + it.escapedName(),
702                                                value: fieldValue
703                                        )
704                                        break
705                                case 'STRINGLIST':
706                                        // render stringlist subjectfield
707                                        if (!it.listEntries.isEmpty()) {
708                                                out << select(
709                                                        name: attrs.name + '_' + it.escapedName(),
710                                                        from: it.listEntries,
711                                                        value: fieldValue
712                                                )
713                                        } else {
714                                                out << '<span class="warning">no values!!</span>'
715                                        }
716                                        break
717                                case 'DATE':
718                                        // transform value?
719                                        if (fieldValue instanceof Date) {
720                                                if (fieldValue.getHours() == 0 && fieldValue.getMinutes() == 0) {
721                                                        // transform date instance to formatted string (dd/mm/yyyy)
722                                                        fieldValue = String.format('%td/%<tm/%<tY', fieldValue)
723                                                } else {
724                                                        // transform to date + time
725                                                        fieldValue = String.format('%td/%<tm/%<tY %<tH:%<tM', fieldValue)
726                                                }
727                                        }
728
729                                        // output a date field (not the 'rel' which makes the
730                                        // javascript front-end bind the jquery-ui datepicker)
731                                        out << textField(
732                                                name: attrs.name + '_' + it.escapedName(),
733                                                value: fieldValue,
734                                                rel: 'date'
735                                        )
736                                        break
737                                case 'ONTOLOGYTERM':
738                                        // @see http://www.bioontology.org/wiki/index.php/NCBO_Widgets#Term-selection_field_on_a_form
739                                        // @see ontology-chooser.js, table-editor.js
740                                        //out << it.getClass()
741                                        out << textField(
742                                                name: attrs.name + '_' + it.escapedName(),
743                                                value: fieldValue,
744                                                rel: 'ontology-all-name',
745                                                size: 100
746                                        )
747                                        out << hiddenField(
748                                                name: attrs.name + '_' + it.escapedName() + '-concept_id'
749                                        )
750                                        out << hiddenField(
751                                                name: attrs.name + '_' + it.escapedName() + '-ontology_id'
752                                        )
753                                        out << hiddenField(
754                                                name: attrs.name + '_' + it.escapedName() + '-full_id'
755                                        )
756                                        break
757                                default:
758                                        // unsupported field type
759                                        out << '<span class="warning">!' + it.type + '</span>'
760                                        break
761                        }
762
763                        out << '</div>'
764                }
765        }
766
767        /**
768         * render form elements based on an entity's template
769         * @param Map attributes
770         * @param String body
771         */
772        def templateElements = {attrs ->
773                def entity = (attrs.get('entity'))
774                def template = (entity && entity instanceof TemplateEntity) ? entity.template : null
775
776                // got a template?
777                if (template) {
778                        // render template fields
779                        template.fields.each() {
780                                def fieldValue = entity.getFieldValue(it.name)
781
782                                switch (it.type.toString()) {
783                                        case ['STRING', 'TEXT', 'INTEGER', 'FLOAT', 'DOUBLE']:
784                                                out << textFieldElement(
785                                                        description: it.name,
786                                                        name: it.escapedName(),
787                                                        value: fieldValue
788                                                )
789                                                break
790                                        case 'STRINGLIST':
791                                                if (!it.listEntries.isEmpty()) {
792                                                        out << selectElement(
793                                                                description: it.name,
794                                                                name: it.escapedName(),
795                                                                from: it.listEntries,
796                                                                value: fieldValue
797                                                        )
798                                                } else {
799                                                        out << '<span class="warning">no values!!</span>'
800                                                }
801                                                break
802                                        case 'ONTOLOGYTERM':
803                                                // @see http://www.bioontology.org/wiki/index.php/NCBO_Widgets#Term-selection_field_on_a_form
804                                                // @see ontology-chooser.js
805                                                out << textFieldElement(
806                                                        name: it.escapedName(),
807                                                        value: fieldValue,
808                                                        rel: 'ontology-all-name',
809                                                        size: 100
810                                                )
811                                                out << hiddenField(
812                                                        name: it.name + '-concept_id',
813                                                        value: fieldValue
814                                                )
815                                                out << hiddenField(
816                                                        name: it.escapedName() + '-ontology_id',
817                                                        value: fieldValue
818                                                )
819                                                out << hiddenField(
820                                                        name: it.escapedName() + '-full_id',
821                                                        value: fieldValue
822                                                )
823                                                break
824                                        case 'DATE':
825                                                out << dateElement(
826                                                        description: it.name,
827                                                        name: it.escapedName(),
828                                                        value: fieldValue
829                                                )
830                                                break
831                                        default:
832                                                out << "unkown field type '" + it.type + "'<br/>"
833                                                break
834                                }
835                        }
836                }
837        }
838}
Note: See TracBrowser for help on using the repository browser.