source: trunk/grails-app/services/dbnp/studycapturing/AssayService.groovy @ 2067

Last change on this file since 2067 was 2067, checked in by s.h.sikkema@…, 11 years ago

Set maximum fraction digits to 15 for csv export

  • Property svn:keywords set to Rev Author Date
File size: 25.5 KB
Line 
1/**
2 * AssayService Service
3 *
4 * @author  s.h.sikkema@gmail.com
5 * @since       20101216
6 * @package     dbnp.studycapturing
7 *
8 * Revision information:
9 * $Rev: 2067 $
10 * $Author: s.h.sikkema@gmail.com $
11 * $Date: 2011-10-17 15:19:24 +0000 (ma, 17 okt 2011) $
12 */
13package dbnp.studycapturing
14
15import org.apache.poi.ss.usermodel.*
16import org.apache.poi.xssf.usermodel.XSSFWorkbook
17import org.apache.poi.hssf.usermodel.HSSFWorkbook
18import org.codehaus.groovy.grails.web.json.JSONObject
19import org.dbnp.gdt.RelTime
20import org.dbnp.gdt.TemplateFieldType
21import java.text.NumberFormat
22import dbnp.authentication.SecUser
23
24class AssayService {
25
26        boolean transactional = false
27        def authenticationService
28        def moduleCommunicationService
29
30        /**
31         * Collects the assay field names per category in a map as well as the
32         * module's measurements.
33         *
34         * @param assay         the assay for which to collect the fields
35         * @param samples       list of samples to retrieve the field names for. If not given, all samples from the assay are used.
36         * @return a map of categories as keys and field names or measurements as
37         *  values
38         */
39        def collectAssayTemplateFields(assay, samples, SecUser remoteUser = null) throws Exception {
40
41                def getUsedTemplateFields = { templateEntities ->
42
43                        // gather all unique and non null template fields that haves values
44                        templateEntities*.giveFields().flatten().unique().findAll{ field ->
45
46                                field && templateEntities.any { it?.fieldExists(field.name) && it.getFieldValue(field.name) != null }
47
48                        }.collect{[name: it.name, comment: it.comment, displayName: it.name + (it.unit ? " ($it.unit)" : '')]}
49                }
50
51                def moduleError = '', moduleMeasurements = []
52
53                try {
54                        moduleMeasurements = requestModuleMeasurementNames(assay, remoteUser)
55                } catch (e) {
56                        moduleError = e.message
57                }
58
59                if( !samples )
60                        samples = assay.samples
61
62                [               'Subject Data' :            getUsedTemplateFields( samples*."parentSubject".unique() ),
63                                        'Sampling Event Data' :     getUsedTemplateFields( samples*."parentEvent".unique() ),
64                                        'Sample Data' :             getUsedTemplateFields( samples ),
65                                        'Event Group' :             [[name: 'name', comment: 'Name of Event Group', displayName: 'name']],
66                                        'Module Measurement Data':  moduleMeasurements,
67                                        'Module Error':             moduleError
68                                ]
69
70        }
71
72        /**
73         * Gathers all assay related data, including measurements from the module,
74         * into 1 hash map containing: Subject Data, Sampling Event Data, Sample
75         * Data, and module specific measurement data.
76         * Data from each of the 4 hash map entries are themselves hash maps
77         * representing a descriptive header (field name) as key and the data as
78         * value.
79         *
80         * @param assay                                 the assay to collect data for
81         * @param fieldMap                              map with categories as keys and fields as values
82         * @param measurementTokens     selection of measurementTokens
83         * @param samples                               list of samples for which the data should be retrieved.
84         *                                                              Defaults to all samples from this assay. Supply [] or
85         *                                                              null to include all samples.
86         * @return                              The assay data structure as described above.
87         */
88        def collectAssayData(assay, fieldMap, measurementTokens, samples, SecUser remoteUser = null) throws Exception {
89
90                def collectFieldValuesForTemplateEntities = { headerFields, templateEntities ->
91
92                        // return a hash map with for each field name all values from the
93                        // template entity list
94                        headerFields.inject([:]) { map, headerField ->
95
96                                map + [(headerField.displayName): templateEntities.collect { entity ->
97
98                                                // default to an empty string
99                                                def val = ''
100
101                                                if (entity) {
102                                                        def field
103                                                        try {
104
105                                                                val = entity.getFieldValue(headerField.name)
106
107                                                                // Convert RelTime fields to human readable strings
108                                                                field = entity.getField(headerField.name)
109                                                                if (field.type == TemplateFieldType.RELTIME)
110                                                                        val = new RelTime( val as long )
111
112                                                        } catch (NoSuchFieldException e) { /* pass */ }
113                                                }
114
115                                                (val instanceof Number) ? val : val.toString()}]
116                        }
117                }
118
119                def getFieldValues = { templateEntities, headerFields, propertyName = '' ->
120
121                        def returnValue
122
123                        // if no property name is given, simply collect the fields and
124                        // values of the template entities themselves
125                        if (propertyName == '') {
126
127                                returnValue = collectFieldValuesForTemplateEntities(headerFields, templateEntities)
128
129                        } else {
130
131                                // if a property name is given, we'll have to do a bit more work
132                                // to ensure efficiency. The reason for this is that for a list
133                                // of template entities, the properties referred to by
134                                // propertyName can include duplicates. For example, for 10
135                                // samples, there may be less than 10 parent subjects. Maybe
136                                // there's only 1 parent subject. We don't want to collect field
137                                // values for this single subject 10 times ...
138                                def fieldValues
139
140                                // we'll get the unique list of properties to make sure we're
141                                // not getting the field values for identical template entity
142                                // properties more then once.
143                                def uniqueProperties = templateEntities*."$propertyName".unique()
144
145                                fieldValues = collectFieldValuesForTemplateEntities(headerFields, uniqueProperties)
146
147                                // prepare a lookup hashMap to be able to map an entities'
148                                // property (e.g. a sample's parent subject) to an index value
149                                // from the field values list
150                                int i = 0
151                                def propertyToFieldValueIndexMap = uniqueProperties.inject([:]) { map, item -> map + [(item):i++]}
152
153                                // prepare the return value so that it has an entry for field
154                                // name. This will be the column name (second header line).
155                                returnValue = headerFields*.displayName.inject([:]) { map, item -> map + [(item):[]] }
156
157                                // finally, fill map the unique field values to the (possibly
158                                // not unique) template entity properties. In our example with
159                                // 1 unique parent subject, this means copying that subject's
160                                // field values to all 10 samples.
161                                templateEntities.each{ te ->
162
163                                        headerFields*.displayName.each{
164
165                                                returnValue[it] << fieldValues[it][propertyToFieldValueIndexMap[te[propertyName]]]
166
167                                        }
168
169                                }
170
171                        }
172
173                        returnValue
174
175                }
176
177                // Find samples and sort by name
178                if( !samples )
179                        samples = assay.samples.toList().sort { it.name }
180
181                def eventFieldMap = [:]
182
183                // check whether event group data was requested
184                if (fieldMap['Event Group']) {
185
186                        def names = samples*.parentEventGroup*.name.flatten()
187
188                        // only set name field when there's actual data
189                        if (!names.every {!it}) eventFieldMap['name'] = names
190
191                }
192
193                def moduleError = '', moduleMeasurementData = [:]
194
195                if (measurementTokens) {
196
197                        try {
198                                moduleMeasurementData = requestModuleMeasurements(assay, measurementTokens, samples, remoteUser)
199                        } catch (e) {
200                                moduleMeasurementData = ['error' : ['Module error, module not available or unknown assay'] * samples.size() ]
201                                moduleError =  e.message
202                        }
203
204                }
205
206                [   'Subject Data' :            getFieldValues(samples, fieldMap['Subject Data'], 'parentSubject'),
207                        'Sampling Event Data' :     getFieldValues(samples, fieldMap['Sampling Event Data'], 'parentEvent'),
208                        'Sample Data' :             getFieldValues(samples, fieldMap['Sample Data']),
209                        'Event Group' :             eventFieldMap,
210                        'Module Measurement Data' : moduleMeasurementData,
211                        'Module Error' :            moduleError
212                ]
213        }
214
215        /**
216         * Prepend data from study to the data structure
217         * @param assayData             Column wise data structure of samples
218         * @param assay                 Assay object the data should be selected from
219         * @param numValues             Number of values for this assay
220         * @return                              Extended column wise data structure
221         */
222        def prependStudyData( inputData, Assay assay, numValues ) {
223                if( !assay )
224                        return inputData;
225
226                // Retrieve study data
227                def studyData =[:]
228                assay.parent?.giveFields().each {
229                        def value = assay.parent.getFieldValue( it.name )
230                        if( value )
231                                studyData[ it.name ] = [value] * numValues
232                }
233
234                return [
235                        'Study Data': studyData
236                ] + inputData
237        }
238
239        /**
240         * Prepend data from assay to the data structure
241         * @param assayData             Column wise data structure of samples
242         * @param assay                 Assay object the data should be selected from
243         * @param numValues             Number of values for this assay
244         * @return                              Extended column wise data structure
245         */
246        def prependAssayData( inputData, Assay assay, numValues ) {
247                if( !assay )
248                        return inputData;
249
250                // Retrieve assay data
251                def assayData = [:]
252                assay.giveFields().each {
253                        def value = assay.getFieldValue( it.name )
254                        if( value )
255                                assayData[ it.name ] = [value] * numValues
256                }
257
258                return [
259                        'Assay Data': assayData
260                ] + inputData
261        }
262
263        /**
264         * Retrieves measurement names from the module through a rest call
265         *
266         * @param consumer the url of the module
267         * @param path path of the rest call to the module
268         * @return
269         */
270        def requestModuleMeasurementNames(assay, SecUser remoteUser = null) {
271
272                def moduleUrl = assay.module.url
273
274                def path = moduleUrl + "/rest/getMeasurements/query"
275                def query = "assayToken=${assay.giveUUID()}"
276                def jsonArray
277
278                try {
279                        jsonArray = moduleCommunicationService.callModuleMethod(moduleUrl, path, query, "POST", remoteUser)
280                } catch (e) {
281                        throw new Exception("An error occured while trying to get the measurement tokens from the $assay.module.name. \
282             This means the module containing the measurement data is not available right now. Please try again \
283             later or notify the system administrator if the problem persists. URL: $path?$query.")
284                }
285
286                def result = jsonArray.collect {
287                        if( it == JSONObject.NULL )
288                                return ""
289                        else
290                                return it.toString()
291                }
292
293                return result
294        }
295
296        /**
297         * Retrieves module measurement data through a rest call to the module
298         *
299         * @param assay                         Assay for which the module measurements should be retrieved
300         * @param measurementTokens     List with the names of the fields to be retrieved. Format: [ 'measurementName1', 'measurementName2' ]
301         * @param samples                       Samples to collect measurements for
302         * @return
303         */
304        def requestModuleMeasurements(assay, inputMeasurementTokens, samples, SecUser remoteUser = null) {
305
306                def moduleUrl = assay.module.url
307
308                def tokenString = ''
309
310                inputMeasurementTokens.each{
311                        tokenString+="&measurementToken=${it.encodeAsURL()}"
312                }
313
314                def path = moduleUrl + "/rest/getMeasurementData/query"
315
316                def query = "assayToken=$assay.assayUUID$tokenString"
317
318                def sampleTokens = [], measurementTokens = [], moduleData = []
319
320                try {
321                        (sampleTokens, measurementTokens, moduleData) = moduleCommunicationService.callModuleMethod(moduleUrl, path, query, "POST", remoteUser)
322                } catch (e) {
323                        throw new Exception("An error occured while trying to get the measurement data from the $assay.module.name. \
324             This means the module containing the measurement data is not available right now. Please try again \
325             later or notify the system administrator if the problem persists. URL: $path?$query.")
326                }
327
328                if (!sampleTokens?.size()) return []
329
330                // Convert the three different maps into a map like:
331                //
332                // [ "measurement 1": [ value1, value2, value3 ],
333                //   "measurement 2": [ value4, value5, value6 ] ]
334                //
335                // The returned values should be in the same order as the given samples-list
336                def map = [:]
337                def numSampleTokens = sampleTokens.size();
338
339                measurementTokens.eachWithIndex { measurementToken, measurementIndex ->
340                        def measurements = [];
341                        samples.each { sample ->
342
343                                // Do measurements for this sample exist? If not, a null value is returned
344                                // for this sample. Otherwise, the measurement is looked up in the list with
345                                // measurements, based on the sample token
346                                if( sampleTokens.collect{ it.toString() }.contains( sample.giveUUID() ) ) {
347                                        def tokenIndex = sampleTokens.indexOf( sample.giveUUID() );
348                                        def valueIndex = measurementIndex * numSampleTokens + tokenIndex;
349
350                                        // If the module data is in the wrong format, show an error in the log file
351                                        // and return a null value for this measurement.
352                                        if( valueIndex >= moduleData.size() ) {
353                                                log.error "Module measurements given by module " + assay.module.name + " are not in the right format: " + measurementTokens?.size() + " measurements, " + sampleTokens?.size() + " samples, " + moduleData?.size() + " values"
354                                                measurements << null
355                                        }  else {
356
357                                                def val
358                                                def measurement = moduleData[ valueIndex ]
359
360                                                if          (measurement == JSONObject.NULL)    val = ""
361                                                else if     (measurement instanceof Number)     val = measurement
362                                                else if     (measurement.isDouble())            val = measurement.toDouble()
363                                                else val =   measurement.toString()
364                                                measurements << val
365                                        }
366                                } else {
367                                        measurements << null
368                                }
369                        }
370                        map[ measurementToken.toString() ] = measurements
371                }
372
373                return map;
374        }
375
376        /**
377         * Merges the data from multiple studies into a structure that can be exported to an excel file. The format for each assay is
378         *
379         *      [Category1:
380         *      [Column1: [1,2,3], Column2: [4,5,6]],
381         *   Category2:
382         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
383         *
384         * Where the category describes the category of data that is presented (e.g. subject, sample etc.) and the column names describe
385         * the fields that are present. Each entry in the lists shows the value for that column for an entity. In this case, 3 entities are described.
386         * Each field should give values for all entities, so the length of all value-lists should be the same.
387         *
388         * Example: If the following input is given (2 assays)
389         *
390         *      [
391         *    [Category1:
392         *      [Column1: [1,2,3], Column2: [4,5,6]],
393         *     Category2:
394         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]],
395         *    [Category1:
396         *      [Column1: [16,17], Column6: [18,19]],
397         *     Category3:
398         *      [Column3: [20,21], Column8: [22,23]]]
399         * ]
400         *
401         * the output will be (5 entries for each column, empty values for fields that don't exist in some assays)
402         *
403         *      [
404         *    [Category1:
405         *      [Column1: [1,2,3,16,17], Column2: [4,5,6,,], Column6: [,,,18,19]],
406         *     Category2:
407         *      [Column3: [7,8,9,,], Column4: [10,11,12,,], Column5: [13,14,15,,]],
408         *     Category3:
409         *      [Column3: [,,,20,21], Column8: [,,,22,23]]
410         * ]
411         *
412         *
413         * @param columnWiseAssayData   List with each entry being the column wise data of an assay. The format for each
414         *                                                              entry is described above
415         * @return      Hashmap                         Combined assay data, in the same structure as each input entry. Empty values are given as an empty string.
416         *                                                              So for input entries
417         */
418        def mergeColumnWiseDataOfMultipleStudies(def columnWiseAssayData) {
419                // Compute the number of values that is expected for each assay. This number is
420                // used later on to determine the number of empty fields to add if a field is not present in this
421                // assay
422                def numValues = columnWiseAssayData.collect { assay ->
423                        for( cat in assay ) {
424                                if( cat ) {
425                                        for( field in cat.value ) {
426                                                if( field?.value?.size() > 0 ) {
427                                                        return field.value.size();
428                                                }
429                                        }
430                                }
431                        }
432
433                        return 0;
434                }
435
436                // Merge categories from all assays. Create a list for all categories
437                def categories = columnWiseAssayData*.keySet().toList().flatten().unique();
438                def mergedColumnWiseData = [:]
439                categories.each { category ->
440                        // Only work with this category for all assays
441                        def categoryData = columnWiseAssayData*.getAt( category );
442
443                        // Find the different fields in all assays
444                        def categoryFields = categoryData.findAll{ it }*.keySet().toList().flatten().unique();
445
446                        // Find data for all assays for these fields. If the fields do not exist, return an empty string
447                        def categoryValues = [:]
448                        categoryFields.each { field ->
449                                categoryValues[ field ] = [];
450
451                                // Loop through all assays
452                                categoryData.eachWithIndex { assayValues, idx ->
453                                        if( assayValues && assayValues.containsKey( field ) ) {
454                                                // Append the values if they exist
455                                                categoryValues[ field ] += assayValues[ field ];
456                                        } else {
457                                                // Append empty string for each entity if the field doesn't exist
458                                                categoryValues[ field ] += [""] * numValues[ idx ]
459                                        }
460                                }
461                        }
462
463                        mergedColumnWiseData[ category ] = categoryValues
464                }
465
466                return mergedColumnWiseData;
467        }
468
469        /**
470         * Merges the data from multiple studies into a structure that can be exported to an excel file. The format for each assay is
471         *
472         *      [Category1:
473         *      [Column1: [1,2,3], Column2: [4,5,6]],
474         *   Category2:
475         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
476         *
477         * Where the category describes the category of data that is presented (e.g. subject, sample etc.) and the column names describe
478         * the fields that are present. Each entry in the lists shows the value for that column for an entity. In this case, 3 entities are described.
479         * Each field should give values for all entities, so the length of all value-lists should be the same.
480         *
481         * Example: If the following input is given (2 assays)
482         *
483         *      [
484         *    [Category1:
485         *      [Column1: [1,2,3], Column2: [4,5,6]],
486         *     Category2:
487         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]],
488         *    [Category1:
489         *      [Column1: [16,17], Column6: [18,19]],
490         *     Category3:
491         *      [Column3: [20,21], Column8: [22,23]]]
492         * ]
493         *
494         * the output will be (5 entries for each column, empty values for fields that don't exist in some assays)
495         *
496         *      [
497         *    [Category1:
498         *      [Column1: [1,2,3,16,17], Column2: [4,5,6,,], Column6: [,,,18,19]],
499         *     Category2:
500         *      [Column3: [7,8,9,,], Column4: [10,11,12,,], Column5: [13,14,15,,]],
501         *     Category3:
502         *      [Column3: [,,,20,21], Column8: [,,,22,23]]
503         * ]
504         *
505         *
506         * @param columnWiseAssayData   List with each entry being the column wise data of an assay. The format for each
507         *                                                              entry is described above. The data MUST have a category named 'Sample Data' and in that map a field
508         *                                                              named 'id'. This field is used for matching rows. However, the column is removed, unless
509         *                                                              removeIdColumn is set to false
510         * @param removeIdColumn                If set to true (default), the values for the sample id are removed from the output.
511         * @return      Hashmap                         Combined assay data, in the same structure as each input entry. Empty values are given as an empty string.
512         *                                                              So for input entries
513         */
514        def mergeColumnWiseDataOfMultipleStudiesForASetOfSamples(def columnWiseAssayData, boolean removeIdColumn = true ) {
515                // Merge all assays and studies into one list
516                def mergedData = mergeColumnWiseDataOfMultipleStudies( columnWiseAssayData )
517
518                // A map with keys being the sampleIds, and the values are the indices of that sample in the values list
519                def idMap = [:]
520               
521                // A map with the key being an index in the value list, and the value is the index the values should be copied to
522                def convertMap = [:]
523
524                for( int i = 0; i < mergedData[ "Sample Data" ][ "id" ].size(); i++ ) {
525                        def id = mergedData[ "Sample Data" ][ "id" ][ i ];
526
527                        if( idMap[ id ] == null ) {
528                                // This id occurs for the first time
529                                idMap[ id ] = i;
530                                convertMap[ i ] = i;
531                        } else {
532                                convertMap[ i ] = idMap[ id ];
533                        }
534                }
535               
536                /*
537                 * Example output:
538                 * idMap:      [ 12: 0, 24: 1, 26: 3 ]
539                 * convertMap: [ 0: 0, 1: 1, 2: 0, 3: 3, 4: 3 ]
540                 *   (meaning: rows 0, 1 and 3 should remain, row 2 should be merged with row 0 and row 4 should be merged with row 3)
541                 *   
542                 * The value in the convertMap is always lower than its key. So we sort the convertMap on the keys. That way, we can
543                 * loop through the values and remove the row that has been merged.
544                 */
545               
546                convertMap.sort { a, b -> b.key <=> a.key }.each { 
547                        def row = it.key;
548                        def mergeWith = it.value;
549                       
550                        if( row != mergeWith ) {
551                                // Combine the data on row [row] with the data on row [mergeWith]
552                               
553                                mergedData.each { 
554                                        def cat = it.key; def fields = it.value;
555                                        fields.each { fieldData ->
556                                                def fieldName = fieldData.key; 
557                                                def fieldValues = fieldData.value;
558                                               
559                                                // If one of the fields to merge is empty, use the other one
560                                                // Otherwise the values should be the same (e.g. study, subject, sample data)
561                                                fieldValues[ mergeWith ] = ( fieldValues[ mergeWith ] == null || fieldValues[ mergeWith ] == "" ) ? fieldValues[ row ] : fieldValues[ mergeWith ]
562                                               
563                                                // Remove the row from this list
564                                                fieldValues.remove( row );
565                                        }
566                                }
567                        }
568                }
569               
570                // Remove sample id if required
571                if( removeIdColumn )
572                        mergedData[ "Sample Data" ].remove( "id" );
573               
574                return mergedData
575        }
576
577        /**
578         * Converts column
579         * @param columnData multidimensional map containing column data.
580         * On the top level, the data must be grouped by category. Each key is the
581         * category title and the values are maps representing the columns. Each
582         * column also has a title (its key) and a list of values. Columns must be
583         * equally sized.
584         *
585         * For example, consider the following map:
586         * [Category1:
587         *      [Column1: [1,2,3], Column2: [4,5,6]],
588         *  Category2:
589         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
590         *
591         * which will be written as:
592         *
593         * | Category1  |           | Category2 |           |           |
594         * | Column1    | Column2   | Column3   | Column4   | Column5   |
595         * | 1          | 4         | 7         | 10        | 13        |
596         * | 2          | 5         | 8         | 11        | 14        |
597         * | 3          | 6         | 9         | 12        | 15        |
598         *
599         * @return row wise data
600         */
601        def convertColumnToRowStructure(columnData) {
602
603                // check if all columns have the dimensionality 2
604                if (columnData.every { it.value.every { it.value instanceof ArrayList } }) {
605
606                        def headers = [[],[]]
607
608                        columnData.each { category ->
609
610                                if (category.value.size()) {
611
612                                        // put category keys into first row separated by null values
613                                        // wherever there are > 1 columns per category
614                                        headers[0] += [category.key] + [null] * (category.value.size() - 1)
615
616                                        // put non-category column headers into 2nd row
617                                        headers[1] += category.value.collect{it.key}
618
619                                }
620
621                        }
622
623                        def d = []
624
625                        // add all column wise data into 'd'
626                        columnData.each { it.value.each { d << it.value } }
627
628                        // transpose d into row wise data and combine with header rows
629                        headers + d.transpose()
630                } else []
631
632        }
633
634        /**
635         * Export column wise data in Excel format to a stream.
636         *
637         * @param columnData Multidimensional map containing column data
638         * @param outputStream Stream to write to
639         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
640         * @return
641         */
642        def exportColumnWiseDataToExcelFile(columnData, outputStream, useOfficeOpenXML = true) {
643
644                // transform data into row based structure for easy writing
645                def rows = convertColumnToRowStructure(columnData)
646
647                if (rows) {
648
649                        exportRowWiseDataToExcelFile(rows, outputStream, useOfficeOpenXML)
650
651                } else {
652
653                        throw new Exception('Wrong column data format.')
654
655                }
656
657        }
658
659        /**
660         * Export row wise data in Excel format to a stream
661         *
662         * @param rowData List of lists containing for each row all cell values
663         * @param outputStream Stream to write to
664         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
665         * @return
666         */
667        def exportRowWiseDataToExcelFile(rowData, outputStream, useOfficeOpenXML = true) {
668                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
669                Sheet sheet = wb.createSheet()
670
671                exportRowWiseDataToExcelSheet( rowData, sheet );
672
673                wb.write(outputStream)
674                outputStream.close()
675        }
676
677        /**
678         * Export row wise data in CSV to a stream. All values are surrounded with
679         * double quotes (" ").
680         *
681         * @param rowData List of lists containing for each row all cell values
682         * @param outputStream Stream to write to
683         * @return
684         */
685        def exportRowWiseDataToCSVFile(rowData, outputStream, outputDelimiter = '\t', locale = java.util.Locale.US) {
686
687                def formatter = NumberFormat.getNumberInstance(locale)
688                formatter.setGroupingUsed false // we don't want grouping (thousands) separators
689                formatter.setMaximumFractionDigits(15)
690
691                outputStream << rowData.collect { row ->
692                        row.collect{
693
694                                // omit quotes in case of numeric values and format using chosen locale
695                                if (it instanceof Number) return formatter.format(it)
696
697                                def s = it?.toString() ?: ''
698
699                                def addQuotes = false
700
701                                // escape double quotes with double quotes if they exist and
702                                // enable surround with quotes
703                                if (s.contains('"')) {
704                                        addQuotes = true
705                                        s = s.replaceAll('"','""')
706                                } else {
707                                        // enable surround with quotes in case of comma's
708                                        if (s.contains(',') || s.contains('\n')) addQuotes = true
709                                }
710
711                                addQuotes ? "\"$s\"" : s
712
713                        }.join(outputDelimiter)
714                }.join('\n')
715
716                outputStream.close()
717        }
718
719        /**
720         * Export row wise data for multiple assays in Excel format (separate sheets) to a stream
721         *
722         * @param rowData       List of structures with rowwise data for each assay
723         * @param outputStream Stream to write to
724         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
725         * @return
726         */
727        def exportRowWiseDataForMultipleAssaysToExcelFile(assayData, outputStream, useOfficeOpenXML = true) {
728                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
729
730                assayData.each { rowData ->
731                        Sheet sheet = wb.createSheet()
732
733                        exportRowWiseDataToExcelSheet( rowData, sheet );
734                }
735
736                wb.write(outputStream)
737                outputStream.close()
738        }
739
740        /**
741         * Export row wise data in Excel format to a given sheet in an excel workbook
742         *
743         * @param rowData       List of lists containing for each row all cell values
744         * @param sheet         Excel sheet to append the
745         * @return
746         */
747        def exportRowWiseDataToExcelSheet(rowData, Sheet sheet) {
748                // create all rows
749                rowData.size().times { sheet.createRow it }
750
751                sheet.eachWithIndex { Row row, ri ->
752                        if( rowData[ ri ] ) {
753                                // create appropriate number of cells for this row
754                                rowData[ri].size().times { row.createCell it }
755
756                                row.eachWithIndex { Cell cell, ci ->
757
758                                        // Numbers and values of type boolean, String, and Date can be
759                                        // written as is, other types need converting to String
760                                        def value = rowData[ri][ci]
761
762                                        value = (value instanceof Number | value?.class in [boolean.class, String.class, Date.class]) ? value : value?.toString()
763
764                                        // write the value (or an empty String if null) to the cell
765                                        cell.setCellValue(value ?: '')
766
767                                }
768                        }
769                }
770        }
771}
Note: See TracBrowser for help on using the repository browser.