source: trunk/grails-app/services/dbnp/studycapturing/AssayService.groovy @ 1937

Last change on this file since 1937 was 1937, checked in by robert@…, 9 years ago

Removed debug statements

  • Property svn:keywords set to Rev Author Date
File size: 21.6 KB
Line 
1/**
2 * AssayService Service
3 *
4 * @author  s.h.sikkema@gmail.com
5 * @since       20101216
6 * @package     dbnp.studycapturing
7 *
8 * Revision information:
9 * $Rev: 1937 $
10 * $Author: robert@isdat.nl $
11 * $Date: 2011-06-23 12:16:07 +0000 (do, 23 jun 2011) $
12 */
13package dbnp.studycapturing
14
15import org.apache.poi.ss.usermodel.*
16import org.apache.poi.xssf.usermodel.XSSFWorkbook
17import org.apache.poi.hssf.usermodel.HSSFWorkbook
18import org.codehaus.groovy.grails.web.json.JSONObject
19import org.dbnp.gdt.RelTime
20import org.dbnp.gdt.TemplateFieldType
21import java.text.DecimalFormat
22import java.text.NumberFormat
23import org.dbnp.gdt.Template
24import org.dbnp.gdt.TemplateField
25
26class AssayService {
27
28        boolean transactional = false
29        def authenticationService
30        def moduleCommunicationService
31
32        /**
33         * Collects the assay field names per category in a map as well as the
34         * module's measurements.
35         *
36         * @param assay the assay for which to collect the fields
37         * @return a map of categories as keys and field names or measurements as
38         *  values
39         */
40        def collectAssayTemplateFields(assay) throws Exception {
41
42                def getUsedTemplateFields = { templateEntities ->
43
44                        // gather all unique and non null template fields that haves values
45                        templateEntities*.giveFields().flatten().unique().findAll{ field ->
46
47                                field && templateEntities.any { it?.fieldExists(field.name) && it.getFieldValue(field.name) != null }
48
49                        }.collect{[name: it.name, comment: it.comment, displayName: it.name + (it.unit ? " ($it.unit)" : '')]}
50                }
51
52        def moduleError = '', moduleMeasurements = []
53
54        try {
55            moduleMeasurements = requestModuleMeasurementNames(assay)
56        } catch (e) {
57            moduleError = e.message
58        }
59
60                def samples = assay.samples
61                [               'Subject Data' :            getUsedTemplateFields( samples*."parentSubject".unique() ),
62                                        'Sampling Event Data' :     getUsedTemplateFields( samples*."parentEvent".unique() ),
63                                        'Sample Data' :             getUsedTemplateFields( samples ),
64                                        'Event Group' :             [[name: 'name', comment: 'Name of Event Group', displayName: 'name']],
65                                        'Module Measurement Data':  moduleMeasurements,
66                    'ModuleError':              moduleError
67                ]
68
69        }
70
71        /**
72         * Gathers all assay related data, including measurements from the module,
73         * into 1 hash map containing: Subject Data, Sampling Event Data, Sample
74         * Data, and module specific measurement data.
75         * Data from each of the 4 hash map entries are themselves hash maps
76         * representing a descriptive header (field name) as key and the data as
77         * value.
78         *
79         * @param assay                                 the assay to collect data for
80         * @param fieldMap                              map with categories as keys and fields as values
81         * @param measurementTokens     selection of measurementTokens
82         * @return                              The assay data structure as described above.
83         */
84        def collectAssayData(assay, fieldMap, measurementTokens) throws Exception {
85
86                def collectFieldValuesForTemplateEntities = { headerFields, templateEntities ->
87
88                        // return a hash map with for each field name all values from the
89                        // template entity list
90                        headerFields.inject([:]) { map, headerField ->
91
92                                map + [(headerField.displayName): templateEntities.collect { entity ->
93
94                    // default to an empty string
95                    def val = ''
96
97                    if (entity) {
98                        def field
99                        try {
100
101                            val = entity.getFieldValue(headerField.name)
102
103                            // Convert RelTime fields to human readable strings
104                            field = entity.getField(headerField.name)
105                            if (field.type == TemplateFieldType.RELTIME)
106                                val = new RelTime( val as long )
107
108                        } catch (NoSuchFieldException e) { /* pass */ }
109                    }
110
111                    (val instanceof Number) ? val : val.toString()}]
112                        }
113                }
114
115                def getFieldValues = { templateEntities, headerFields, propertyName = '' ->
116
117                        def returnValue
118
119                        // if no property name is given, simply collect the fields and
120                        // values of the template entities themselves
121                        if (propertyName == '') {
122
123                                returnValue = collectFieldValuesForTemplateEntities(headerFields, templateEntities)
124
125                        } else {
126
127                                // if a property name is given, we'll have to do a bit more work
128                                // to ensure efficiency. The reason for this is that for a list
129                                // of template entities, the properties referred to by
130                                // propertyName can include duplicates. For example, for 10
131                                // samples, there may be less than 10 parent subjects. Maybe
132                                // there's only 1 parent subject. We don't want to collect field
133                                // values for this single subject 10 times ...
134                                def fieldValues
135
136                                // we'll get the unique list of properties to make sure we're
137                                // not getting the field values for identical template entity
138                                // properties more then once.
139                                def uniqueProperties = templateEntities*."$propertyName".unique()
140
141                                fieldValues = collectFieldValuesForTemplateEntities(headerFields, uniqueProperties)
142
143                                // prepare a lookup hashMap to be able to map an entities'
144                                // property (e.g. a sample's parent subject) to an index value
145                                // from the field values list
146                                int i = 0
147                                def propertyToFieldValueIndexMap = uniqueProperties.inject([:]) { map, item -> map + [(item):i++]}
148
149                                // prepare the return value so that it has an entry for field
150                                // name. This will be the column name (second header line).
151                                returnValue = headerFields*.displayName.inject([:]) { map, item -> map + [(item):[]] }
152
153                                // finally, fill map the unique field values to the (possibly
154                                // not unique) template entity properties. In our example with
155                                // 1 unique parent subject, this means copying that subject's
156                                // field values to all 10 samples.
157                                templateEntities.each{ te ->
158
159                                        headerFields*.displayName.each{
160
161                                                returnValue[it] << fieldValues[it][propertyToFieldValueIndexMap[te[propertyName]]]
162
163                                        }
164
165                                }
166
167                        }
168
169                        returnValue
170
171                }
172
173                // Find samples and sort by name
174                def samples = assay.samples.toList().sort { it.name }
175
176                def eventFieldMap = [:]
177
178                // check whether event group data was requested
179                if (fieldMap['Event Group']) {
180
181                        def names = samples*.parentEventGroup*.name.flatten()
182
183                        // only set name field when there's actual data
184                        if (!names.every {!it}) eventFieldMap['name'] = names
185
186                }
187
188                def moduleError = '', moduleMeasurementData = [:]
189
190                if (measurementTokens) {
191
192            try {
193                moduleMeasurementData = requestModuleMeasurements(assay, measurementTokens, samples)
194            } catch (e) {
195                moduleMeasurementData = ['error' : ['Module error, module not available or unknown assay'] * samples.size() ]
196                moduleError =  e.message
197            }
198
199                }
200               
201                [       'Subject Data' :            getFieldValues(samples, fieldMap['Subject Data'], 'parentSubject'),
202                                'Sampling Event Data' :     getFieldValues(samples, fieldMap['Sampling Event Data'], 'parentEvent'),
203                'Sample Data' :             getFieldValues(samples, fieldMap['Sample Data']),
204                'Event Group' :             eventFieldMap,
205                'Module Measurement Data' : moduleMeasurementData,
206                'ModuleError' :             moduleError
207                                ]
208        }
209
210        /**
211         * Prepend data from study to the data structure
212         * @param assayData             Column wise data structure of samples
213         * @param assay                 Assay object the data should be selected from
214         * @param numValues             Number of values for this assay
215         * @return                              Extended column wise data structure
216         */
217        def prependStudyData( inputData, Assay assay, numValues ) {
218                if( !assay )
219                        return inputData;
220
221                // Retrieve study data
222                def studyData =[:]
223                assay.parent?.giveFields().each {
224                        def value = assay.parent.getFieldValue( it.name )
225                        if( value )
226                                studyData[ it.name ] = [value] * numValues
227                }
228
229                return [
230                        'Study Data': studyData
231                ] + inputData
232        }
233
234        /**
235         * Prepend data from assay to the data structure
236         * @param assayData             Column wise data structure of samples
237         * @param assay                 Assay object the data should be selected from
238         * @param numValues             Number of values for this assay
239         * @return                              Extended column wise data structure
240         */
241        def prependAssayData( inputData, Assay assay, numValues ) {
242                if( !assay )
243                        return inputData;
244
245                // Retrieve assay data
246                def assayData = [:]
247                assay.giveFields().each {
248                        def value = assay.getFieldValue( it.name )
249                        if( value )
250                                assayData[ it.name ] = [value] * numValues
251                }
252
253                return [
254                        'Assay Data': assayData
255                ] + inputData
256        }
257
258        /**
259         * Retrieves measurement names from the module through a rest call
260         *
261         * @param consumer the url of the module
262         * @param path path of the rest call to the module
263         * @return
264         */
265        def requestModuleMeasurementNames(assay) {
266
267                def moduleUrl = assay.module.url
268
269                def path = moduleUrl + "/rest/getMeasurements/query"
270        def query = "assayToken=${assay.giveUUID()}"
271        def jsonArray
272
273        try {
274            jsonArray = moduleCommunicationService.callModuleMethod(moduleUrl, path, query, "POST")
275        } catch (e) {
276            throw new Exception("An error occured while trying to get the measurement tokens from the $assay.module.name. \
277             This means the module containing the measurement data is not available right now. Please try again \
278             later or notify the system administrator if the problem persists. URL: $path?$query.")
279        }
280
281                def result = jsonArray.collect {
282                        if( it == JSONObject.NULL )
283                                return ""
284                        else
285                                return it.toString()
286                }
287                       
288                return result
289        }
290
291        /**
292         * Retrieves module measurement data through a rest call to the module
293         *
294         * @param assay                         Assay for which the module measurements should be retrieved
295         * @param measurementTokens     List with the names of the fields to be retrieved. Format: [ 'measurementName1', 'measurementName2' ]
296         * @param samples                       Samples to collect measurements for
297         * @return
298         */
299        def requestModuleMeasurements(assay, inputMeasurementTokens, samples) {
300
301                def moduleUrl = assay.module.url
302
303                def tokenString = ''
304
305                inputMeasurementTokens.each{
306                        tokenString+="&measurementToken=${it.encodeAsURL()}"
307                }
308
309                def path = moduleUrl + "/rest/getMeasurementData/query"
310
311        def query = "assayToken=$assay.assayUUID$tokenString"
312
313                def sampleTokens = [], measurementTokens = [], moduleData = []
314
315        try {
316            (sampleTokens, measurementTokens, moduleData) = moduleCommunicationService.callModuleMethod(moduleUrl, path, query, "POST")
317        } catch (e) {
318            throw new Exception("An error occured while trying to get the measurement data from the $assay.module.name. \
319             This means the module containing the measurement data is not available right now. Please try again \
320             later or notify the system administrator if the problem persists. URL: $path?$query.")
321        }
322
323                if (!sampleTokens?.size()) return []
324
325                // Convert the three different maps into a map like:
326                //
327                // [ "measurement 1": [ value1, value2, value3 ],
328                //   "measurement 2": [ value4, value5, value6 ] ]
329                //
330                // The returned values should be in the same order as the given samples-list
331                def map = [:]
332                def numSampleTokens = sampleTokens.size();
333
334                measurementTokens.eachWithIndex { measurementToken, measurementIndex ->
335                        def measurements = [];
336                        samples.each { sample ->
337
338                                // Do measurements for this sample exist? If not, a null value is returned
339                                // for this sample. Otherwise, the measurement is looked up in the list with
340                                // measurements, based on the sample token
341                                if( sampleTokens.collect{ it.toString() }.contains( sample.giveUUID() ) ) {
342                                        def tokenIndex = sampleTokens.indexOf( sample.giveUUID() );
343                                        def valueIndex = measurementIndex * numSampleTokens + tokenIndex;
344
345                                        // If the module data is in the wrong format, show an error in the log file
346                                        // and return a null value for this measurement.
347                                        if( valueIndex >= moduleData.size() ) {
348                                                log.error "Module measurements given by module " + assay.module.name + " are not in the right format: " + measurementTokens?.size() + " measurements, " + sampleTokens?.size() + " samples, " + moduleData?.size() + " values"
349                                                measurements << null
350                                        }  else {
351
352                        def val
353                        def measurement = moduleData[ valueIndex ]
354
355                        if          (measurement == JSONObject.NULL)    val = ""
356                        else if     (measurement instanceof Number)     val = measurement
357                        else if     (measurement.isDouble())            val = measurement.toDouble()
358                        else val =   measurement.toString()
359                                                measurements << val
360                                        }
361                                } else {
362                                        measurements << null
363                                }
364                        }
365                        map[ measurementToken.toString() ] = measurements
366                }
367
368                return map;
369        }
370
371        /**
372         * Merges the data from multiple studies into a structure that can be exported to an excel file. The format for each assay is
373         *
374         *      [Category1:
375         *      [Column1: [1,2,3], Column2: [4,5,6]],
376         *   Category2:
377         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
378         *
379         * Where the category describes the category of data that is presented (e.g. subject, sample etc.) and the column names describe
380         * the fields that are present. Each entry in the lists shows the value for that column for an entity. In this case, 3 entities are described.
381         * Each field should give values for all entities, so the length of all value-lists should be the same.
382         *
383         * Example: If the following input is given (2 assays)
384         *
385         *      [
386         *    [Category1:
387         *      [Column1: [1,2,3], Column2: [4,5,6]],
388         *     Category2:
389         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]],
390         *    [Category1:
391         *      [Column1: [16,17], Column6: [18,19]],
392         *     Category3:
393         *      [Column3: [20,21], Column8: [22,23]]]
394         * ]
395         *
396         * the output will be (5 entries for each column, empty values for fields that don't exist in some assays)
397         *
398         *      [
399         *    [Category1:
400         *      [Column1: [1,2,3,16,17], Column2: [4,5,6,,], Column6: [,,,18,19]],
401         *     Category2:
402         *      [Column3: [7,8,9,,], Column4: [10,11,12,,], Column5: [13,14,15,,]],
403         *     Category3:
404         *      [Column3: [,,,20,21], Column8: [,,,22,23]]
405         * ]
406         *
407         *
408         * @param columnWiseAssayData   List with each entry being the column wise data of an assay. The format for each
409         *                                                              entry is described above
410         * @return      Hashmap                         Combined assay data, in the same structure as each input entry. Empty values are given as an empty string.
411         *                                                              So for input entries
412         */
413        def mergeColumnWiseDataOfMultipleStudies(def columnWiseAssayData) {
414                // Compute the number of values that is expected for each assay. This number is
415                // used later on to determine the number of empty fields to add if a field is not present in this
416                // assay
417                def numValues = columnWiseAssayData.collect { assay ->
418                        for( cat in assay ) {
419                                if( cat ) {
420                                        for( field in cat.value ) {
421                                                if( field?.value?.size() > 0 ) {
422                                                        return field.value.size();
423                                                }
424                                        }
425                                }
426                        }
427
428                        return 0;
429                }
430
431                // Merge categories from all assays. Create a list for all categories
432                def categories = columnWiseAssayData*.keySet().toList().flatten().unique();
433                def mergedColumnWiseData = [:]
434                categories.each { category ->
435                        // Only work with this category for all assays
436                        def categoryData = columnWiseAssayData*.getAt( category );
437
438                        // Find the different fields in all assays
439                        def categoryFields = categoryData.findAll{ it }*.keySet().toList().flatten().unique();
440
441                        // Find data for all assays for these fields. If the fields do not exist, return an empty string
442                        def categoryValues = [:]
443                        categoryFields.each { field ->
444                                categoryValues[ field ] = [];
445
446                                // Loop through all assays
447                                categoryData.eachWithIndex { assayValues, idx ->
448                                        if( assayValues && assayValues.containsKey( field ) ) {
449                                                // Append the values if they exist
450                                                categoryValues[ field ] += assayValues[ field ];
451                                        } else {
452                                                // Append empty string for each entity if the field doesn't exist
453                                                categoryValues[ field ] += [""] * numValues[ idx ]
454                                        }
455                                }
456                        }
457
458                        mergedColumnWiseData[ category ] = categoryValues
459                }
460
461                return mergedColumnWiseData;
462        }
463
464        /**
465         * Converts column
466         * @param columnData multidimensional map containing column data.
467         * On the top level, the data must be grouped by category. Each key is the
468         * category title and the values are maps representing the columns. Each
469         * column also has a title (its key) and a list of values. Columns must be
470         * equally sized.
471         *
472         * For example, consider the following map:
473         * [Category1:
474         *      [Column1: [1,2,3], Column2: [4,5,6]],
475         *  Category2:
476         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
477         *
478         * which will be written as:
479         *
480         * | Category1  |           | Category2 |           |           |
481         * | Column1    | Column2   | Column3   | Column4   | Column5   |
482         * | 1          | 4         | 7         | 10        | 13        |
483         * | 2          | 5         | 8         | 11        | 14        |
484         * | 3          | 6         | 9         | 12        | 15        |
485         *
486         * @return row wise data
487         */
488        def convertColumnToRowStructure(columnData) {
489
490                // check if all columns have the dimensionality 2
491                if (columnData.every { it.value.every { it.value instanceof ArrayList } }) {
492
493                        def headers = [[],[]]
494
495                        columnData.each { category ->
496
497                                if (category.value.size()) {
498
499                                        // put category keys into first row separated by null values
500                                        // wherever there are > 1 columns per category
501                                        headers[0] += [category.key] + [null] * (category.value.size() - 1)
502
503                                        // put non-category column headers into 2nd row
504                                        headers[1] += category.value.collect{it.key}
505
506                                }
507
508                        }
509
510                        def d = []
511
512                        // add all column wise data into 'd'
513                        columnData.each { it.value.each { d << it.value } }
514
515                        // transpose d into row wise data and combine with header rows
516                        headers + d.transpose()
517                } else []
518
519        }
520
521        /**
522         * Export column wise data in Excel format to a stream.
523         *
524         * @param columnData Multidimensional map containing column data
525         * @param outputStream Stream to write to
526         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
527         * @return
528         */
529        def exportColumnWiseDataToExcelFile(columnData, outputStream, useOfficeOpenXML = true) {
530
531                // transform data into row based structure for easy writing
532                def rows = convertColumnToRowStructure(columnData)
533
534                if (rows) {
535
536                        exportRowWiseDataToExcelFile(rows, outputStream, useOfficeOpenXML)
537
538                } else {
539
540                        throw new Exception('Wrong column data format.')
541
542                }
543
544        }
545
546        /**
547         * Export row wise data in Excel format to a stream
548         *
549         * @param rowData List of lists containing for each row all cell values
550         * @param outputStream Stream to write to
551         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
552         * @return
553         */
554        def exportRowWiseDataToExcelFile(rowData, outputStream, useOfficeOpenXML = true) {
555                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
556                Sheet sheet = wb.createSheet()
557
558                exportRowWiseDataToExcelSheet( rowData, sheet );
559
560                wb.write(outputStream)
561                outputStream.close()
562        }
563
564        /**
565         * Export row wise data in CSV to a stream. All values are surrounded with
566     * double quotes (" ").
567         *
568         * @param rowData List of lists containing for each row all cell values
569         * @param outputStream Stream to write to
570         * @return
571         */
572        def exportRowWiseDataToCSVFile(rowData, outputStream, outputDelimiter = '\t', locale = java.util.Locale.US) {
573
574        def formatter = NumberFormat.getNumberInstance(locale)
575        formatter.setGroupingUsed false // we don't want grouping (thousands) separators
576
577        outputStream << rowData.collect { row ->
578          row.collect{
579
580              // omit quotes in case of numeric values and format using chosen locale
581              if (it instanceof Number) return formatter.format(it)
582
583              def s = it?.toString() ?: ''
584
585              def addQuotes = false
586
587              // escape double quotes with double quotes if they exist and
588              // enable surround with quotes
589              if (s.contains('"')) {
590                  addQuotes = true
591                  s = s.replaceAll('"','""')
592              } else {
593                  // enable surround with quotes in case of comma's
594                  if (s.contains(',') || s.contains('\n')) addQuotes = true
595              }
596
597              addQuotes ? "\"$s\"" : s
598
599          }.join(outputDelimiter)
600        }.join('\n')
601
602                outputStream.close()
603        }
604
605        /**
606         * Export row wise data for multiple assays in Excel format (separate sheets) to a stream
607         *
608         * @param rowData       List of structures with rowwise data for each assay
609         * @param outputStream Stream to write to
610         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
611         * @return
612         */
613        def exportRowWiseDataForMultipleAssaysToExcelFile(assayData, outputStream, useOfficeOpenXML = true) {
614                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
615
616                assayData.each { rowData ->
617                        Sheet sheet = wb.createSheet()
618
619                        exportRowWiseDataToExcelSheet( rowData, sheet );
620                }
621
622                wb.write(outputStream)
623                outputStream.close()
624        }
625
626        /**
627         * Export row wise data in Excel format to a given sheet in an excel workbook
628         *
629         * @param rowData       List of lists containing for each row all cell values
630         * @param sheet         Excel sheet to append the
631         * @return
632         */
633        def exportRowWiseDataToExcelSheet(rowData, Sheet sheet) {
634                // create all rows
635                rowData.size().times { sheet.createRow it }
636
637                sheet.eachWithIndex { Row row, ri ->
638                        if( rowData[ ri ] ) {
639                                // create appropriate number of cells for this row
640                                rowData[ri].size().times { row.createCell it }
641
642                                row.eachWithIndex { Cell cell, ci ->
643
644                                        // Numbers and values of type boolean, String, and Date can be
645                                        // written as is, other types need converting to String
646                                        def value = rowData[ri][ci]
647
648                                        value = (value instanceof Number | value?.class in [boolean.class, String.class, Date.class]) ? value : value?.toString()
649
650                                        // write the value (or an empty String if null) to the cell
651                                        cell.setCellValue(value ?: '')
652
653                                }
654                        }
655                }
656        }
657}
Note: See TracBrowser for help on using the repository browser.