root/trunk/grails-app/services/dbnp/studycapturing/AssayService.groovy @ 1830

Revision 1830, 21.0 KB (checked in by s.h.sikkema@…, 3 years ago)

Clarified error messages related to unreachable module; added functionality to export numbers using comma as decimal separator and made this the default for european csv style export

  • Property svn:keywords set to Rev Author Date
Line 
1/**
2 * AssayService Service
3 *
4 * @author  s.h.sikkema@gmail.com
5 * @since       20101216
6 * @package     dbnp.studycapturing
7 *
8 * Revision information:
9 * $Rev$
10 * $Author$
11 * $Date$
12 */
13package dbnp.studycapturing
14
15import org.apache.poi.ss.usermodel.*
16import org.apache.poi.xssf.usermodel.XSSFWorkbook
17import org.apache.poi.hssf.usermodel.HSSFWorkbook
18import org.codehaus.groovy.grails.web.json.JSONObject
19import org.dbnp.gdt.RelTime
20import org.dbnp.gdt.TemplateFieldType
21import java.text.DecimalFormat
22import java.text.NumberFormat
23
24class AssayService {
25
26        boolean transactional = false
27        def authenticationService
28        def moduleCommunicationService
29
30        /**
31         * Collects the assay field names per category in a map as well as the
32         * module's measurements.
33         *
34         * @param assay the assay for which to collect the fields
35         * @return a map of categories as keys and field names or measurements as
36         *  values
37         */
38        def collectAssayTemplateFields(assay) throws Exception {
39
40                def getUsedTemplateFields = { templateEntities ->
41
42                        // gather all unique and non null template fields that haves values
43                        templateEntities*.giveFields().flatten().unique().findAll{ field ->
44
45                                field && templateEntities.any { it?.fieldExists(field.name) && it.getFieldValue(field.name) != null }
46
47                        }.collect{[name: it.name, comment: it.comment, displayName: it.name + (it.unit ? " ($it.unit)" : '')]}
48                }
49
50                def samples = assay.samples
51                [               'Subject Data' :            getUsedTemplateFields( samples*."parentSubject".unique() ),
52                                        'Sampling Event Data' :     getUsedTemplateFields( samples*."parentEvent".unique() ),
53                                        'Sample Data' :             getUsedTemplateFields( samples ),
54                                        'Event Group' :             [[name: 'name', comment: 'Name of Event Group', displayName: 'name']],
55
56                                        // If module is not reachable, only the field 'module error' is returned, and is filled later on.
57                                        'Module Measurement Data':  moduleCommunicationService.isModuleReachable(assay.module.url) ? requestModuleMeasurementNames(assay) : [ [ name: "Module error" ] ]
58                ]
59
60        }
61
62        /**
63         * Gathers all assay related data, including measurements from the module,
64         * into 1 hash map containing: Subject Data, Sampling Event Data, Sample
65         * Data, and module specific measurement data.
66         * Data from each of the 4 hash map entries are themselves hash maps
67         * representing a descriptive header (field name) as key and the data as
68         * value.
69         *
70         * @param assay                                 the assay to collect data for
71         * @param fieldMap                              map with categories as keys and fields as values
72         * @param measurementTokens     selection of measurementTokens
73         * @return                              The assay data structure as described above.
74         */
75        def collectAssayData(assay, fieldMap, measurementTokens) throws Exception {
76
77                def collectFieldValuesForTemplateEntities = { headerFields, templateEntities ->
78
79                        // return a hash map with for each field name all values from the
80                        // template entity list
81                        headerFields.inject([:]) { map, headerField ->
82
83                                map + [(headerField.displayName): templateEntities.collect {
84
85                    // default to an empty string
86                    def val = ''
87
88                    def field
89                    try {
90
91                        val = it.getFieldValue(headerField.name)
92                       
93                        // Convert RelTime fields to human readable strings
94                        field = it.getField(headerField.name)
95                        if (field.type == TemplateFieldType.RELTIME)
96                            val = new RelTime( val as long )
97
98                    } catch (NoSuchFieldException e) { /* pass */ }
99
100                    val.toString()}]
101                        }
102                }
103
104                def getFieldValues = { templateEntities, headerFields, propertyName = '' ->
105
106                        def returnValue
107
108                        // if no property name is given, simply collect the fields and
109                        // values of the template entities themselves
110                        if (propertyName == '') {
111
112                                returnValue = collectFieldValuesForTemplateEntities(headerFields, templateEntities)
113
114                        } else {
115
116                                // if a property name is given, we'll have to do a bit more work
117                                // to ensure efficiency. The reason for this is that for a list
118                                // of template entities, the properties referred to by
119                                // propertyName can include duplicates. For example, for 10
120                                // samples, there may be less than 10 parent subjects. Maybe
121                                // there's only 1 parent subject. We don't want to collect field
122                                // values for this single subject 10 times ...
123                                def fieldValues
124
125                                // we'll get the unique list of properties to make sure we're
126                                // not getting the field values for identical template entity
127                                // properties more then once.
128                                def uniqueProperties = templateEntities*."$propertyName".unique()
129
130                                fieldValues = collectFieldValuesForTemplateEntities(headerFields, uniqueProperties)
131
132                                // prepare a lookup hashMap to be able to map an entities'
133                                // property (e.g. a sample's parent subject) to an index value
134                                // from the field values list
135                                int i = 0
136                                def propertyToFieldValueIndexMap = uniqueProperties.inject([:]) { map, item -> map + [(item):i++]}
137
138                                // prepare the return value so that it has an entry for field
139                                // name. This will be the column name (second header line).
140                                returnValue = headerFields*.displayName.inject([:]) { map, item -> map + [(item):[]] }
141
142                                // finally, fill map the unique field values to the (possibly
143                                // not unique) template entity properties. In our example with
144                                // 1 unique parent subject, this means copying that subject's
145                                // field values to all 10 samples.
146                                templateEntities.each{ te ->
147
148                                        headerFields*.displayName.each{
149
150                                                returnValue[it] << fieldValues[it][propertyToFieldValueIndexMap[te[propertyName]]]
151
152                                        }
153
154                                }
155
156                        }
157
158                        returnValue
159
160                }
161
162                // Find samples and sort by name
163                def samples = assay.samples.toList().sort { it.name }
164
165                def eventFieldMap = [:]
166
167                // check whether event group data was requested
168                if (fieldMap['Event Group']) {
169
170                        def names = samples*.parentEventGroup*.name.flatten()
171
172                        // only set name field when there's actual data
173                        if (!names.every {!it}) eventFieldMap['name'] = names
174
175                }
176
177                [       'Subject Data' :            getFieldValues(samples, fieldMap['Subject Data'], 'parentSubject'),
178                                'Sampling Event Data' :     getFieldValues(samples, fieldMap['Sampling Event Data'], 'parentEvent'),
179                'Sample Data' :             getFieldValues(samples, fieldMap['Sample Data']),
180                'Event Group' :             eventFieldMap,
181
182                // If module is not reachable, only the message 'module not reachable' is given for each sample
183                'Module Measurement Data':  moduleCommunicationService.isModuleReachable(assay.module.url) ?
184                                                ( measurementTokens ? requestModuleMeasurements(assay, measurementTokens, samples) : [:] ) :
185                                                [ "Module error": [ "Module not reachable" ] * samples.size() ]
186                                ]
187        }
188
189        /**
190         * Prepend data from study to the data structure
191         * @param assayData             Column wise data structure of samples
192         * @param assay                 Assay object the data should be selected from
193         * @param numValues             Number of values for this assay
194         * @return                              Extended column wise data structure
195         */
196        def prependStudyData( inputData, Assay assay, numValues ) {
197                if( !assay )
198                        return inputData;
199
200                // Retrieve study data
201                def studyData =[:]
202                assay.parent?.giveFields().each {
203                        def value = assay.parent.getFieldValue( it.name )
204                        if( value )
205                                studyData[ it.name ] = [value] * numValues
206                }
207
208                return [
209                        'Study Data': studyData
210                ] + inputData
211        }
212
213        /**
214         * Prepend data from assay to the data structure
215         * @param assayData             Column wise data structure of samples
216         * @param assay                 Assay object the data should be selected from
217         * @param numValues             Number of values for this assay
218         * @return                              Extended column wise data structure
219         */
220        def prependAssayData( inputData, Assay assay, numValues ) {
221                if( !assay )
222                        return inputData;
223
224                // Retrieve assay data
225                def assayData = [:]
226                assay.giveFields().each {
227                        def value = assay.getFieldValue( it.name )
228                        if( value )
229                                assayData[ it.name ] = [value] * numValues
230                }
231
232                return [
233                        'Assay Data': assayData
234                ] + inputData
235        }
236
237        /**
238         * Retrieves measurement names from the module through a rest call
239         *
240         * @param consumer the url of the module
241         * @param path path of the rest call to the module
242         * @return
243         */
244        def requestModuleMeasurementNames(assay) {
245
246                def moduleUrl = assay.module.url
247
248                def path = moduleUrl + "/rest/getMeasurements/query"
249        def query = "assayToken=$assay.assayUUID"
250        def jsonArray
251
252        try {
253            jsonArray = moduleCommunicationService.callModuleMethod(moduleUrl, path, query)
254        } catch (e) {
255            throw new Exception("An error occured while trying to get the measurement tokens from the $assay.module.name. \
256             This means the module containing the measurement data is not available right now. Please try again \
257             later or notify the system administrator if the problem persists. URL: $path?$query.")
258        }
259
260                jsonArray.collect {
261                        if( it == JSONObject.NULL )
262                                return ""
263                        else
264                                return it.toString()
265                }
266
267        }
268
269        /**
270         * Retrieves module measurement data through a rest call to the module
271         *
272         * @param assay                         Assay for which the module measurements should be retrieved
273         * @param measurementTokens     List with the names of the fields to be retrieved. Format: [ 'measurementName1', 'measurementName2' ]
274         * @param samples                       Samples for which the module
275         * @return
276         */
277        def requestModuleMeasurements(assay, inputMeasurementTokens, samples) {
278
279                def moduleUrl = assay.module.url
280
281                def tokenString = ''
282
283                inputMeasurementTokens.each{
284                        tokenString+="&measurementToken=${it.encodeAsURL()}"
285                }
286
287                def path = moduleUrl + "/rest/getMeasurementData/query"
288
289        def query = "assayToken=$assay.assayUUID$tokenString"
290
291                def sampleTokens = [], measurementTokens = [], moduleData = []
292
293        try {
294            (sampleTokens, measurementTokens, moduleData) = moduleCommunicationService.callModuleMethod(moduleUrl, path, query)
295        } catch (e) {
296            throw new Exception("An error occured while trying to get the measurement data from the $assay.module.name. \
297             This means the module containing the measurement data is not available right now. Please try again \
298             later or notify the system administrator if the problem persists. URL: $path?$query.")
299        }
300
301                if (!sampleTokens?.size()) return []
302
303                // Convert the three different maps into a map like:
304                //
305                // [ "measurement 1": [ value1, value2, value3 ],
306                //   "measurement 2": [ value4, value5, value6 ] ]
307                //
308                // The returned values should be in the same order as the given samples-list
309                def map = [:]
310                def numSampleTokens = sampleTokens.size();
311
312                measurementTokens.eachWithIndex { measurementToken, measurementIndex ->
313                        def measurements = [];
314                        samples.each { sample ->
315
316                                // Do measurements for this sample exist? If not, a null value is returned
317                                // for this sample. Otherwise, the measurement is looked up in the list with
318                                // measurements, based on the sample token
319                                if( sampleTokens.collect{ it.toString() }.contains( sample.giveUUID() ) ) {
320                                        def tokenIndex = sampleTokens.indexOf( sample.giveUUID() );
321                                        def valueIndex = measurementIndex * numSampleTokens + tokenIndex;
322
323                                        // If the module data is in the wrong format, show an error in the log file
324                                        // and return a null value for this measurement.
325                                        if( valueIndex >= moduleData.size() ) {
326                                                log.error "Module measurements given by module " + assay.module.name + " are not in the right format: " + measurementTokens?.size() + " measurements, " + sampleTokens?.size() + " samples, " + moduleData?.size() + " values"
327                                                measurements << null
328                                        }  else {
329                                                measurements << ( moduleData[ valueIndex ] == JSONObject.NULL ? "" : moduleData[ valueIndex ].toDouble() );
330                                        }
331                                } else {
332                                        measurements << null
333                                }
334                        }
335                        map[ measurementToken.toString() ] = measurements
336                }
337
338                return map;
339        }
340
341        /**
342         * Merges the data from multiple studies into a structure that can be exported to an excel file. The format for each assay is
343         *
344         *      [Category1:
345         *      [Column1: [1,2,3], Column2: [4,5,6]],
346         *   Category2:
347         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
348         *
349         * Where the category describes the category of data that is presented (e.g. subject, sample etc.) and the column names describe
350         * the fields that are present. Each entry in the lists shows the value for that column for an entity. In this case, 3 entities are described.
351         * Each field should give values for all entities, so the length of all value-lists should be the same.
352         *
353         * Example: If the following input is given (2 assays)
354         *
355         *      [
356         *    [Category1:
357         *      [Column1: [1,2,3], Column2: [4,5,6]],
358         *     Category2:
359         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]],
360         *    [Category1:
361         *      [Column1: [16,17], Column6: [18,19]],
362         *     Category3:
363         *      [Column3: [20,21], Column8: [22,23]]]
364         * ]
365         *
366         * the output will be (5 entries for each column, empty values for fields that don't exist in some assays)
367         *
368         *      [
369         *    [Category1:
370         *      [Column1: [1,2,3,16,17], Column2: [4,5,6,,], Column6: [,,,18,19]],
371         *     Category2:
372         *      [Column3: [7,8,9,,], Column4: [10,11,12,,], Column5: [13,14,15,,]],
373         *     Category3:
374         *      [Column3: [,,,20,21], Column8: [,,,22,23]]
375         * ]
376         *
377         *
378         * @param columnWiseAssayData   List with each entry being the column wise data of an assay. The format for each
379         *                                                              entry is described above
380         * @return      Hashmap                         Combined assay data, in the same structure as each input entry. Empty values are given as an empty string.
381         *                                                              So for input entries
382         */
383        def mergeColumnWiseDataOfMultipleStudies(def columnWiseAssayData) {
384                // Compute the number of values that is expected for each assay. This number is
385                // used later on to determine the number of empty fields to add if a field is not present in this
386                // assay
387                def numValues = columnWiseAssayData.collect { assay ->
388                        for( cat in assay ) {
389                                if( cat ) {
390                                        for( field in cat.value ) {
391                                                if( field?.value?.size() > 0 ) {
392                                                        return field.value.size();
393                                                }
394                                        }
395                                }
396                        }
397
398                        return 0;
399                }
400
401                // Merge categories from all assays. Create a list for all categories
402                def categories = columnWiseAssayData*.keySet().toList().flatten().unique();
403                def mergedColumnWiseData = [:]
404                categories.each { category ->
405                        // Only work with this category for all assays
406                        def categoryData = columnWiseAssayData*.getAt( category );
407
408                        // Find the different fields in all assays
409                        def categoryFields = categoryData.findAll{ it }*.keySet().toList().flatten().unique();
410
411                        // Find data for all assays for these fields. If the fields do not exist, return an empty string
412                        def categoryValues = [:]
413                        categoryFields.each { field ->
414                                categoryValues[ field ] = [];
415
416                                // Loop through all assays
417                                categoryData.eachWithIndex { assayValues, idx ->
418                                        if( assayValues && assayValues.containsKey( field ) ) {
419                                                // Append the values if they exist
420                                                categoryValues[ field ] += assayValues[ field ];
421                                        } else {
422                                                // Append empty string for each entity if the field doesn't exist
423                                                categoryValues[ field ] += [""] * numValues[ idx ]
424                                        }
425                                }
426                        }
427
428                        mergedColumnWiseData[ category ] = categoryValues
429                }
430
431                return mergedColumnWiseData;
432        }
433
434        /**
435         * Converts column
436         * @param columnData multidimensional map containing column data.
437         * On the top level, the data must be grouped by category. Each key is the
438         * category title and the values are maps representing the columns. Each
439         * column also has a title (its key) and a list of values. Columns must be
440         * equally sized.
441         *
442         * For example, consider the following map:
443         * [Category1:
444         *      [Column1: [1,2,3], Column2: [4,5,6]],
445         *  Category2:
446         *      [Column3: [7,8,9], Column4: [10,11,12], Column5: [13,14,15]]]
447         *
448         * which will be written as:
449         *
450         * | Category1  |           | Category2 |           |           |
451         * | Column1    | Column2   | Column3   | Column4   | Column5   |
452         * | 1          | 4         | 7         | 10        | 13        |
453         * | 2          | 5         | 8         | 11        | 14        |
454         * | 3          | 6         | 9         | 12        | 15        |
455         *
456         * @return row wise data
457         */
458        def convertColumnToRowStructure(columnData) {
459
460                // check if all columns have the dimensionality 2
461                if (columnData.every { it.value.every { it.value instanceof ArrayList } }) {
462
463                        def headers = [[],[]]
464
465                        columnData.each { category ->
466
467                                if (category.value.size()) {
468
469                                        // put category keys into first row separated by null values
470                                        // wherever there are > 1 columns per category
471                                        headers[0] += [category.key] + [null] * (category.value.size() - 1)
472
473                                        // put non-category column headers into 2nd row
474                                        headers[1] += category.value.collect{it.key}
475
476                                }
477
478                        }
479
480                        def d = []
481
482                        // add all column wise data into 'd'
483                        columnData.each { it.value.each { d << it.value } }
484
485                        // transpose d into row wise data and combine with header rows
486                        headers + d.transpose()
487                }
488
489        }
490
491        /**
492         * Export column wise data in Excel format to a stream.
493         *
494         * @param columnData Multidimensional map containing column data
495         * @param outputStream Stream to write to
496         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
497         * @return
498         */
499        def exportColumnWiseDataToExcelFile(columnData, outputStream, useOfficeOpenXML = true) {
500
501                // transform data into row based structure for easy writing
502                def rows = convertColumnToRowStructure(columnData)
503
504                if (rows) {
505
506                        exportRowWiseDataToExcelFile(rows, outputStream, useOfficeOpenXML)
507
508                } else {
509
510                        throw new Exception('Wrong column data format.')
511
512                }
513
514        }
515
516        /**
517         * Export row wise data in Excel format to a stream
518         *
519         * @param rowData List of lists containing for each row all cell values
520         * @param outputStream Stream to write to
521         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
522         * @return
523         */
524        def exportRowWiseDataToExcelFile(rowData, outputStream, useOfficeOpenXML = true) {
525                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
526                Sheet sheet = wb.createSheet()
527
528                exportRowWiseDataToExcelSheet( rowData, sheet );
529
530                wb.write(outputStream)
531                outputStream.close()
532        }
533
534        /**
535         * Export row wise data in CSV to a stream. All values are surrounded with
536     * double quotes (" ").
537         *
538         * @param rowData List of lists containing for each row all cell values
539         * @param outputStream Stream to write to
540         * @return
541         */
542        def exportRowWiseDataToCSVFile(rowData, outputStream, outputDelimiter = '\t', locale = java.util.Locale.US) {
543
544        def formatter = NumberFormat.getNumberInstance(locale)
545        formatter.setGroupingUsed false // we don't want grouping (thousands) separators
546
547        outputStream << rowData.collect { row ->
548          row.collect{
549
550              // omit quotes in case of numeric values and format using chosen locale
551              if (it instanceof Number) return formatter.format(it)
552
553              def s = it?.toString() ?: ''
554
555              def addQuotes = false
556
557              // escape double quotes with double quotes if they exist and
558              // enable surround with quotes
559              if (s.contains('"')) {
560                  addQuotes = true
561                  s = s.replaceAll('"','""')
562              } else {
563                  // enable surround with quotes in case of comma's
564                  if (s.contains(',') || s.contains('\n')) addQuotes = true
565              }
566
567              addQuotes ? "\"$s\"" : s
568
569          }.join(outputDelimiter)
570        }.join('\n')
571
572                outputStream.close()
573        }
574
575        /**
576         * Export row wise data for multiple assays in Excel format (separate sheets) to a stream
577         *
578         * @param rowData       List of structures with rowwise data for each assay
579         * @param outputStream Stream to write to
580         * @param useOfficeOpenXML Flag to specify xlsx (standard) or xls output
581         * @return
582         */
583        def exportRowWiseDataForMultipleAssaysToExcelFile(assayData, outputStream, useOfficeOpenXML = true) {
584                Workbook wb = useOfficeOpenXML ? new XSSFWorkbook() : new HSSFWorkbook()
585
586                assayData.each { rowData ->
587                        Sheet sheet = wb.createSheet()
588
589                        exportRowWiseDataToExcelSheet( rowData, sheet );
590                }
591
592                wb.write(outputStream)
593                outputStream.close()
594        }
595
596        /**
597         * Export row wise data in Excel format to a given sheet in an excel workbook
598         *
599         * @param rowData       List of lists containing for each row all cell values
600         * @param sheet         Excel sheet to append the
601         * @return
602         */
603        def exportRowWiseDataToExcelSheet(rowData, Sheet sheet) {
604                // create all rows
605                rowData.size().times { sheet.createRow it }
606
607                sheet.eachWithIndex { Row row, ri ->
608                        if( rowData[ ri ] ) {
609                                // create appropriate number of cells for this row
610                                rowData[ri].size().times { row.createCell it }
611
612                                row.eachWithIndex { Cell cell, ci ->
613
614                                        // Numbers and values of type boolean, String, and Date can be
615                                        // written as is, other types need converting to String
616                                        def value = rowData[ri][ci]
617
618                                        value = (value instanceof Number | value?.class in [boolean.class, String.class, Date.class]) ? value : value?.toString()
619
620                                        // write the value (or an empty String if null) to the cell
621                                        cell.setCellValue(value ?: '')
622
623                                }
624                        }
625                }
626        }
627
628}
Note: See TracBrowser for help on using the browser.