source: trunk/grails-app/domain/dbnp/studycapturing/Study.groovy @ 1912

Last change on this file since 1912 was 1912, checked in by work@…, 8 years ago

Resolves #476

  • Property svn:keywords set to Rev Author Date
File size: 18.4 KB
Line 
1package dbnp.studycapturing
2import org.dbnp.gdt.*
3import dbnp.authentication.SecUser
4
5/**
6 * Domain class describing the basic entity in the study capture part: the Study class.
7 *
8 * Revision information:
9 * $Rev: 1912 $
10 * $Author: work@osx.eu $
11 * $Date: 2011-06-06 08:21:12 +0000 (ma, 06 jun 2011) $
12 */
13class Study extends TemplateEntity {
14        static searchable = true
15
16        def moduleNotificationService
17
18        SecUser owner           // The owner of the study. A new study is automatically owned by its creator.
19        String title            // The title of the study
20        String description      // A brief synopsis of what the study is about
21        String code                     // currently used as the external study ID, e.g. to reference a study in a SAM module
22        Date dateCreated
23        Date lastUpdated
24        Date startDate
25        List subjects
26        List events
27        List samplingEvents
28        List eventGroups
29        List samples
30        List assays
31        boolean published = false // Determines whether a study is private (only accessable by the owner and writers) or published (also visible to readers)
32        boolean publicstudy = false  // Determines whether anonymous users are allowed to see this study. This has only effect when published = true
33
34        /**
35         * UUID of this study
36         */
37        String studyUUID
38
39
40        static hasMany = [
41                subjects: Subject,
42                samplingEvents: SamplingEvent,
43                events: Event,
44                eventGroups: EventGroup,
45                samples: Sample,
46                assays: Assay,
47                persons: StudyPerson,
48                publications: Publication,
49                readers: SecUser,
50                writers: SecUser
51        ]
52
53        static constraints = {
54                title(nullable:false, blank: false, unique:true, maxSize: 255)
55                owner(nullable: true, blank: true)
56                code(nullable: true, blank: true, unique: true, maxSize: 255)
57                studyUUID(nullable:true, unique:true, maxSize: 255)
58                persons(size:1..1000)
59                // TODO: add custom validator for 'published' to assess whether the study meets all quality criteria for publication
60                // tested by SampleTests.testStudyPublish
61        }
62
63        // see org.dbnp.gdt.FuzzyStringMatchController and Service
64        static fuzzyStringMatchable = [
65            "title",
66                "code"
67        ]
68
69        static mapping = {
70                autoTimestamp true
71                sort "title"
72
73                // Make sure the TEXT field description is persisted with a TEXT field in the database
74                description type: 'text'
75                // Workaround for bug http://jira.codehaus.org/browse/GRAILS-6754
76                templateTextFields type: 'text'
77
78        }
79
80        // The external identifier (studyToken) is currently the code of the study.
81        // It is used from within dbNP submodules to refer to particular study in this GSCF instance.
82
83        def getToken() { return giveUUID() }
84
85        /**
86         * return the domain fields for this domain class
87         * @return List
88         */
89        static List<TemplateField> giveDomainFields() { return Study.domainFields }
90
91        static final List<TemplateField> domainFields = [
92                new TemplateField(
93                name: 'title',
94                type: TemplateFieldType.STRING,
95                required: true),
96                new TemplateField(
97                name: 'description',
98                type: TemplateFieldType.TEXT,
99                comment:'Give a brief synopsis of what your study is about',
100                required: true),
101                new TemplateField(
102                name: 'code',
103                type: TemplateFieldType.STRING,
104                preferredIdentifier: true,
105                comment: 'Fill out the code by which many people will recognize your study',
106                required: false),
107                new TemplateField(
108                name: 'startDate',
109                type: TemplateFieldType.DATE,
110                comment: 'Fill out the official start date or date of first action',
111                required: true),
112                new TemplateField(
113                name: 'published',
114                type: TemplateFieldType.BOOLEAN,
115                comment: 'Determines whether this study is published (accessible for the study readers and, if the study is public, for anonymous users). A study can only be published if it meets certain quality criteria, which will be checked upon save.',
116                required: false)
117        ]
118
119        /**
120         * return the title of this study
121         */
122        def String toString() {
123                return ( (code) ? code : "[no code]") + " - "+ title
124        }
125
126        /**
127         * returns all events and sampling events that do not belong to a group
128         */
129        def List<Event> getOrphanEvents() {
130                def orphans = events.findAll { event -> !event.belongsToGroup(eventGroups) } +
131                samplingEvents.findAll { event -> !event.belongsToGroup(eventGroups) }
132
133                return orphans
134        }
135
136        /**
137         * Return the unique Subject templates that are used in this study
138         */
139        def List<Template> giveSubjectTemplates() {
140                TemplateEntity.giveTemplates(subjects)
141        }
142
143        /**
144         * Return all subjects for a specific template
145         * @param Template
146         * @return ArrayList
147         */
148        def ArrayList<Subject> giveSubjectsForTemplate(Template template) {
149                subjects.findAll { it.template.equals(template) }
150        }
151
152        /**
153         * Return all unique assay templates
154         * @return Set
155         */
156        List<Template> giveAllAssayTemplates() {
157                TemplateEntity.giveTemplates(((assays) ? assays : []))
158        }
159
160        /**
161         * Return all assays for a particular template
162         * @return ArrayList
163         */
164        def ArrayList giveAssaysForTemplate(Template template) {
165                assays.findAll { it && it.template.equals(template) }
166        }
167
168        /**
169         * Return the unique Event and SamplingEvent templates that are used in this study
170         */
171        List<Template> giveAllEventTemplates() {
172                // For some reason, giveAllEventTemplates() + giveAllSamplingEventTemplates()
173                // gives trouble when asking .size() to the result
174                // So we also use giveTemplates here
175                TemplateEntity.giveTemplates(((events) ? events : []) + ((samplingEvents) ? samplingEvents : []))
176        }
177
178        /**
179         * Return all events and samplingEvenets for a specific template
180         * @param Template
181         * @return ArrayList
182         */
183        def ArrayList giveEventsForTemplate(Template template) {
184                def events = events.findAll { it.template.equals(template) }
185                def samplingEvents = samplingEvents.findAll { it.template.equals(template) }
186
187                return (events) ? events : samplingEvents
188        }
189
190        /**
191         * Return the unique Event templates that are used in this study
192         */
193        List<Template> giveEventTemplates() {
194                TemplateEntity.giveTemplates(events)
195        }
196
197        /**
198         * Return the unique SamplingEvent templates that are used in this study
199         */
200        List<Template> giveSamplingEventTemplates() {
201                TemplateEntity.giveTemplates(samplingEvents)
202        }
203
204        /**
205         * Returns the unique Sample templates that are used in the study
206         */
207        List<Template> giveSampleTemplates() {
208                TemplateEntity.giveTemplates(samples)
209        }
210
211        /**
212         * Return all samples for a specific template, sorted by subject name
213         * @param Template
214         * @return ArrayList
215         */
216        def ArrayList<Subject> giveSamplesForTemplate(Template template) {
217                // sort in a concatenated string as sorting on 3 seperate elements
218                // in a map does not seem to work properly
219                samples.findAll { it.template.equals(template) }.sort {
220                        "${it.parentEvent?.template}|${it.parentEvent?.startTime}|${it.parentSubject?.name}".toLowerCase()
221                }
222        }
223
224        /**
225         * Returns the template of the study
226         */
227        Template giveStudyTemplate() {
228                return this.template
229        }
230
231        /**
232         * Delete a specific subject from this study, including all its relations
233         * @param subject The subject to be deleted
234         * @void
235         */
236        void deleteSubject(Subject subject) {
237                // Delete the subject from the event groups it was referenced in
238                this.eventGroups.each {
239                        if (it.subjects?.contains(subject)) {
240                                it.removeFromSubjects(subject)
241                        }
242                }
243
244                // Delete the samples that have this subject as parent
245                this.samples.findAll { it.parentSubject.equals(subject) }.each {
246                        this.deleteSample(it)
247                }
248
249                // This should remove the subject itself too, because of the cascading belongsTo relation
250                this.removeFromSubjects(subject)
251
252                // But apparently it needs an explicit delete() too
253                subject.delete()
254        }
255
256        /**
257         * Delete an assay from the study
258         * @param Assay
259         * @void
260         */
261        def deleteAssay(Assay assay) {
262                if (assay && assay instanceof Assay) {
263                        // iterate through linked samples
264                        assay.samples.findAll { true }.each() { sample ->
265                                assay.removeFromSamples(sample)
266                        }
267
268                        // remove this assay from the study
269                        this.removeFromAssays(assay)
270
271                        // and delete it explicitly
272                        assay.delete()
273                }
274        }
275
276        /**
277         * Delete an event from the study, including all its relations
278         * @param Event
279         * @void
280         */
281        void deleteEvent(Event event) {
282                // remove event from eventGroups
283                this.eventGroups.each() { eventGroup ->
284                        eventGroup.removeFromEvents(event)
285                }
286
287                // remove event from the study
288                this.removeFromEvents(event)
289
290                // and perform a hard delete
291                event.delete()
292        }
293
294        /**
295         * Delete a sample from the study, including all its relations
296         * @param Event
297         * @void
298         */
299        void deleteSample(Sample sample) {
300                // remove the sample from the study
301                this.removeFromSamples(sample)
302
303                // remove the sample from any sampling events it belongs to
304                this.samplingEvents.findAll { it.samples.any { it == sample }}.each {
305                        it.removeFromSamples(sample)
306                }
307
308                // remove the sample from any assays it belongs to
309                this.assays.findAll { it.samples.any { it == sample }}.each {
310                        it.removeFromSamples(sample)
311                }
312
313                // Also here, contrary to documentation, an extra delete() is needed
314                // otherwise date is not properly deleted!
315                sample.delete()
316        }
317
318        /**
319         * Delete a samplingEvent from the study, including all its relations
320         * @param SamplingEvent
321         * @void
322         */
323        void deleteSamplingEvent(SamplingEvent samplingEvent) {
324                // remove event from eventGroups
325                this.eventGroups.each() { eventGroup ->
326                        eventGroup.removeFromSamplingEvents(samplingEvent)
327                }
328
329                // Delete the samples that have this sampling event as parent
330                this.samples.findAll { it.parentEvent.equals(samplingEvent) }.each {
331                        // This should remove the sample itself too, because of the cascading belongsTo relation
332                        this.deleteSample(it)
333                }
334
335                // Remove event from the study
336                // This should remove the event group itself too, because of the cascading belongsTo relation
337                this.removeFromSamplingEvents(samplingEvent)
338
339                // But apparently it needs an explicit delete() too
340                // (Which can be verified by outcommenting this line, then SampleTests.testDeleteViaParentSamplingEvent fails
341                samplingEvent.delete()
342        }
343
344        /**
345         * Delete an eventGroup from the study, including all its relations
346         * @param EventGroup
347         * @void
348         */
349        void deleteEventGroup(EventGroup eventGroup) {
350                // If the event group contains sampling events
351                if (eventGroup.samplingEvents) {
352                        // remove all samples that originate from this eventGroup
353                        if (eventGroup.samplingEvents.size()) {
354                                // find all samples that
355                                //      - are part of this study
356                                this.samples.findAll { sample ->
357                                        (
358                                                // - belong to this eventGroup
359                                                (
360                                                        (sample.parentEventGroup.id && eventGroup.id && sample.parentEventGroup.id == eventGroup.id)
361                                                        ||
362                                                        (sample.parentEventGroup.getIdentifier() == eventGroup.getIdentifier())
363                                                        ||
364                                                        sample.parentEventGroup.equals(eventGroup)
365                                                )
366                                        )
367                                }
368                                .each() { sample ->
369                                        // remove sample from study
370                                        this.deleteSample(sample)
371                                }
372                        }
373
374                        // remove all samplingEvents from this eventGroup
375                        eventGroup.samplingEvents.findAll {}.each() {
376                                eventGroup.removeFromSamplingEvents(it)
377                        }
378                }
379
380                // If the event group contains subjects
381                if (eventGroup.subjects) {
382                        // remove all subject from this eventGroup
383                        eventGroup.subjects.findAll {}.each() {
384                                eventGroup.removeFromSubjects(it)
385                        }
386                }
387
388                // remove the eventGroup from the study
389                this.removeFromEventGroups(eventGroup)
390
391                // Also here, contrary to documentation, an extra delete() is needed
392                // otherwise cascaded deletes are not properly performed
393                eventGroup.delete()
394        }
395
396        /**
397         * Returns true if the given user is allowed to read this study
398         */
399        public boolean canRead(SecUser loggedInUser) {
400                // Anonymous readers are only given access when published and public
401                if (loggedInUser == null) {
402                        return this.publicstudy && this.published;
403                }
404
405                // Administrators are allowed to read every study
406                if (loggedInUser.hasAdminRights()) {
407                        return true;
408                }
409
410                // Owners and writers are allowed to read this study
411                if (this.owner == loggedInUser || this.writers.contains(loggedInUser)) {
412                        return true
413                }
414
415                // Readers are allowed to read this study when it is published
416                if (this.readers.contains(loggedInUser) && this.published) {
417                        return true
418                }
419
420                return false
421        }
422
423        /**
424         * Returns true if the given user is allowed to write this study
425         */
426        public boolean canWrite(SecUser loggedInUser) {
427                if (loggedInUser == null) {
428                        return false;
429                }
430
431                // Administrators are allowed to write every study
432                if (loggedInUser.hasAdminRights()) {
433                        return true;
434                }
435
436                return this.owner == loggedInUser || this.writers.contains(loggedInUser)
437        }
438
439        /**
440         * Returns true if the given user is the owner of this study
441         */
442        public boolean isOwner(SecUser loggedInUser) {
443                if (loggedInUser == null) {
444                        return false;
445                }
446                return this.owner == loggedInUser
447        }
448
449        /**
450         * Returns a list of studies that are writable for the given user
451         */
452        public static giveWritableStudies(SecUser user, Integer max = null) {
453                // User that are not logged in, are not allowed to write to a study
454                if (user == null)
455                        return [];
456
457                def c = Study.createCriteria()
458
459                // Administrators are allowed to read everything
460                if (user.hasAdminRights()) {
461                        return c.listDistinct {
462                                if (max != null) maxResults(max)
463                                order("title", "asc")
464                               
465                        }
466                }
467
468                return c.listDistinct {
469                        if (max != null) maxResults(max)
470                        order("title", "asc")
471                        or {
472                                eq("owner", user)
473                                writers {
474                                        eq("id", user.id)
475                                }
476                        }
477                }
478        }
479
480        /**
481         * Returns a list of studies that are readable by the given user
482         */
483        public static giveReadableStudies(SecUser user, Integer max = null, int offset = 0) {
484                def c = Study.createCriteria()
485
486                // Administrators are allowed to read everything
487                if (user == null) {
488                        return c.listDistinct {
489                                if (max != null) maxResults(max)
490                                firstResult(offset)
491                                order("title", "asc")
492                                and {
493                                        eq("published", true)
494                                        eq("publicstudy", true)
495                                }
496                        }
497                } else if (user.hasAdminRights()) {
498                        return c.listDistinct {
499                                if (max != null) maxResults(max)
500                                firstResult(offset)
501                                order("title", "asc")
502                        }
503                } else {
504                        return c.listDistinct {
505                                if (max != null) maxResults(max)
506                                firstResult(offset)
507                                order("title", "asc")
508                                or {
509                                        eq("owner", user)
510                                        writers {
511                                                eq("id", user.id)
512                                        }
513                                        and {
514                                                readers {
515                                                        eq("id", user.id)
516                                                }
517                                                eq("published", true)
518                                        }
519                                }
520                        }
521                }
522        }
523
524        /**
525         * perform a text search on studies
526         * @param query
527         * @return
528         */
529        public static textSearchReadableStudies(SecUser user, String query) {
530                def c = Study.createCriteria()
531
532                if (user == null) {
533                        // regular user
534                        return c.listDistinct {
535                                or {
536                                        ilike("title", "%${query}%")
537                                        ilike("description", "%${query}%")
538                                }
539                                and {
540                                        eq("published", true)
541                                        eq("publicstudy", true)
542                                }
543                        }
544                } else if (user.hasAdminRights()) {
545                        // admin can search everything
546                        return c.listDistinct {
547                                or {
548                                        ilike("title", "%${query}%")
549                                        ilike("description", "%${query}%")
550                                }
551                        }
552                } else {
553                        return c.listDistinct {
554                                or {
555                                        ilike("title", "%${query}%")
556                                        ilike("description", "%${query}%")
557                                }
558                                and {
559                                        or {
560                                                eq("owner", user)
561                                                writers {
562                                                        eq("id", user.id)
563                                                }
564                                                and {
565                                                        readers {
566                                                                eq("id", user.id)
567                                                        }
568                                                        eq("published", true)
569                                                }
570                                        }
571                                }
572                        }
573
574                }
575        }
576
577        /**
578         * Returns the number of public studies
579         * @return int
580         */
581        public static countPublicStudies() { return countPublicStudies(true) }
582        public static countPublicStudies(boolean published) {
583                def c = Study.createCriteria()
584                return (c.listDistinct {
585                        and {
586                                eq("published", published)
587                                eq("publicstudy", true)
588                        }
589                }).size()
590        }
591
592        /**
593         * Returns the number of private studies
594         * @return int
595         */
596        public static countPrivateStudies() { return countPrivateStudies(false) }
597        public static countPrivateStudies(boolean published) {
598                def c = Study.createCriteria()
599                return (c.listDistinct {
600                        and {
601                                eq("publicstudy", false)
602                        }
603                        or {
604                                eq("published", published)
605                                eq("publicstudy", true)
606                        }
607                }).size()
608        }
609
610        /**
611         * Returns the number of studies that are readable by the given user
612         */
613        public static countReadableStudies(SecUser user) {
614                def c = Study.createCriteria()
615
616                // got a user?
617                if (user == null) {
618                        return c.count {
619                                and {
620                                        eq("published", true)
621                                        eq("publicstudy", true)
622                                }
623                        }
624                } else if (user.hasAdminRights()) {
625                        // Administrators are allowed to read everything
626                        return Study.count()
627                } else {
628                        return (c.listDistinct {
629                                or {
630                                        eq("owner", user)
631                                        writers {
632                                                eq("id", user.id)
633                                        }
634                                        and {
635                                                readers {
636                                                        eq("id", user.id)
637                                                }
638                                                eq("published", true)
639                                        }
640                                }
641                        }).size()
642                }
643        }
644
645        /**
646         * Returns the number of studies that are readable & writable by the given user
647         */
648        public static countReadableAndWritableStudies(SecUser user) {
649                def c = Study.createCriteria()
650
651                // got a user?
652                if (user == null) {
653                        return 0
654                } else if (user.hasAdminRights()) {
655                        return Study.count()
656                } else {
657                        return (c.listDistinct {
658                                or {
659                                        eq("owner", user)
660                                        writers {
661                                                eq("id", user.id)
662                                        }
663                                }
664                        }).size()
665                }
666        }
667
668        /**
669         * Returns the UUID of this study and generates one if needed
670         */
671        public String giveUUID() {
672                if( !this.studyUUID ) {
673                        this.studyUUID = UUID.randomUUID().toString();
674                        if( !this.save(flush:true) ) {
675                                log.error "Couldn't save study UUID: " + this.getErrors();
676                        }
677                }
678
679                return this.studyUUID;
680        }
681
682        /**
683         * Basic equals method to check whether objects are equals, by comparing the ids
684         * @param o             Object to compare with
685         * @return              True iff the id of the given Study is equal to the id of this Study
686         */
687        public boolean equals( Object o ) {
688                if( o == null )
689                        return false;
690
691                if( !( o instanceof Study ) )
692                        return false
693
694                Study s = (Study) o;
695
696                return this.id == s.id
697        }
698
699    // This closure is used in the before{Insert,Update,Delete} closures below.
700    // It is necessary to prevent flushing in the same session as a top level
701    // database action such as 'save' or 'addTo...'. This confuses hibernate and
702    // produces hard to trace errors.
703    // The same holds for flushing during validation (but that's not the case
704    // here).
705    // http://grails.1312388.n4.nabble.com/Grails-hibernate-flush-causes-IndexOutOfBoundsException-td3031979.html
706    static manualFlush(closure) {
707        withSession {session ->
708            def save
709            try {
710                save = session.flushMode
711                session.flushMode = org.hibernate.FlushMode.MANUAL
712                closure()
713            } finally {
714                if (save) {
715                    session.flushMode = save
716                }
717         }
718        }
719    }
720
721        // Send messages to modules about changes in this study
722        def beforeInsert = {
723        manualFlush{
724            moduleNotificationService.invalidateStudy( this )
725        }
726        }
727        def beforeUpdate = {
728        manualFlush{
729            moduleNotificationService.invalidateStudy( this )
730        }
731        }
732        def beforeDelete = {
733                manualFlush{
734            moduleNotificationService.invalidateStudy( this )
735        }
736        }
737    }
Note: See TracBrowser for help on using the repository browser.