source: trunk/grails-app/domain/dbnp/studycapturing/Study.groovy @ 1910

Last change on this file since 1910 was 1910, checked in by kees.vanbochove@…, 9 years ago

first step on the way to solve #476

  • Property svn:keywords set to Rev Author Date
File size: 18.9 KB
Line 
1package dbnp.studycapturing
2import org.dbnp.gdt.*
3import dbnp.authentication.SecUser
4
5/**
6 * Domain class describing the basic entity in the study capture part: the Study class.
7 *
8 * Revision information:
9 * $Rev: 1910 $
10 * $Author: kees.vanbochove@tno.nl $
11 * $Date: 2011-06-01 16:03:33 +0000 (wo, 01 jun 2011) $
12 */
13class Study extends TemplateEntity {
14        static searchable = true
15
16        def moduleNotificationService
17
18        SecUser owner           // The owner of the study. A new study is automatically owned by its creator.
19        String title            // The title of the study
20        String description      // A brief synopsis of what the study is about
21        String code                     // currently used as the external study ID, e.g. to reference a study in a SAM module
22        Date dateCreated
23        Date lastUpdated
24        Date startDate
25        List subjects
26        List events
27        List samplingEvents
28        List eventGroups
29        List samples
30        List assays
31        boolean published = false // Determines whether a study is private (only accessable by the owner and writers) or published (also visible to readers)
32        boolean publicstudy = false  // Determines whether anonymous users are allowed to see this study. This has only effect when published = true
33
34        /**
35         * UUID of this study
36         */
37        String studyUUID
38
39
40        static hasMany = [
41                subjects: Subject,
42                samplingEvents: SamplingEvent,
43                events: Event,
44                eventGroups: EventGroup,
45                samples: Sample,
46                assays: Assay,
47                persons: StudyPerson,
48                publications: Publication,
49                readers: SecUser,
50                writers: SecUser
51        ]
52
53        static constraints = {
54                title(nullable:false, blank: false, unique:true, maxSize: 255)
55                owner(nullable: true, blank: true)
56                code(nullable: true, blank: true, unique: true, maxSize: 255)
57                studyUUID(nullable:true, unique:true, maxSize: 255)
58                persons(size:1..1000)
59                // TODO: add custom validator for 'published' to assess whether the study meets all quality criteria for publication
60                // tested by SampleTests.testStudyPublish
61        }
62
63        // see org.dbnp.gdt.FuzzyStringMatchController and Service
64        static fuzzyStringMatchable = [
65            "title",
66                "code"
67        ]
68
69        static mapping = {
70                autoTimestamp true
71                sort "title"
72
73                // Make sure the TEXT field description is persisted with a TEXT field in the database
74                description type: 'text'
75                // Workaround for bug http://jira.codehaus.org/browse/GRAILS-6754
76                templateTextFields type: 'text'
77
78        }
79
80        // The external identifier (studyToken) is currently the code of the study.
81        // It is used from within dbNP submodules to refer to particular study in this GSCF instance.
82
83        def getToken() { return giveUUID() }
84
85        /**
86         * return the domain fields for this domain class
87         * @return List
88         */
89        static List<TemplateField> giveDomainFields() { return Study.domainFields }
90
91        static final List<TemplateField> domainFields = [
92                new TemplateField(
93                name: 'title',
94                type: TemplateFieldType.STRING,
95                required: true),
96                new TemplateField(
97                name: 'description',
98                type: TemplateFieldType.TEXT,
99                comment:'Give a brief synopsis of what your study is about',
100                required: true),
101                new TemplateField(
102                name: 'code',
103                type: TemplateFieldType.STRING,
104                preferredIdentifier: true,
105                comment: 'Fill out the code by which many people will recognize your study',
106                required: false),
107                new TemplateField(
108                name: 'startDate',
109                type: TemplateFieldType.DATE,
110                comment: 'Fill out the official start date or date of first action',
111                required: true),
112                new TemplateField(
113                name: 'published',
114                type: TemplateFieldType.BOOLEAN,
115                comment: 'Determines whether this study is published (accessible for the study readers and, if the study is public, for anonymous users). A study can only be published if it meets certain quality criteria, which will be checked upon save.',
116                required: false)
117        ]
118
119        /**
120         * return the title of this study
121         */
122        def String toString() {
123                return ( (code) ? code : "[no code]") + " - "+ title
124        }
125
126        /**
127         * returns all events and sampling events that do not belong to a group
128         */
129        def List<Event> getOrphanEvents() {
130                def orphans = events.findAll { event -> !event.belongsToGroup(eventGroups) } +
131                samplingEvents.findAll { event -> !event.belongsToGroup(eventGroups) }
132
133                return orphans
134        }
135
136        /**
137         * Return the unique Subject templates that are used in this study
138         */
139        def List<Template> giveSubjectTemplates() {
140                TemplateEntity.giveTemplates(subjects)
141        }
142
143        /**
144         * Return all subjects for a specific template
145         * @param Template
146         * @return ArrayList
147         */
148        def ArrayList<Subject> giveSubjectsForTemplate(Template template) {
149                subjects.findAll { it.template.equals(template) }
150        }
151
152        /**
153         * Return all unique assay templates
154         * @return Set
155         */
156        List<Template> giveAllAssayTemplates() {
157                TemplateEntity.giveTemplates(((assays) ? assays : []))
158        }
159
160        /**
161         * Return all assays for a particular template
162         * @return ArrayList
163         */
164        def ArrayList giveAssaysForTemplate(Template template) {
165                assays.findAll { it && it.template.equals(template) }
166        }
167
168        /**
169         * Return the unique Event and SamplingEvent templates that are used in this study
170         */
171        List<Template> giveAllEventTemplates() {
172                // For some reason, giveAllEventTemplates() + giveAllSamplingEventTemplates()
173                // gives trouble when asking .size() to the result
174                // So we also use giveTemplates here
175                TemplateEntity.giveTemplates(((events) ? events : []) + ((samplingEvents) ? samplingEvents : []))
176        }
177
178        /**
179         * Return all events and samplingEvenets for a specific template
180         * @param Template
181         * @return ArrayList
182         */
183        def ArrayList giveEventsForTemplate(Template template) {
184                def events = events.findAll { it.template.equals(template) }
185                def samplingEvents = samplingEvents.findAll { it.template.equals(template) }
186
187                return (events) ? events : samplingEvents
188        }
189
190        /**
191         * Return the unique Event templates that are used in this study
192         */
193        List<Template> giveEventTemplates() {
194                TemplateEntity.giveTemplates(events)
195        }
196
197        /**
198         * Return the unique SamplingEvent templates that are used in this study
199         */
200        List<Template> giveSamplingEventTemplates() {
201                TemplateEntity.giveTemplates(samplingEvents)
202        }
203
204        /**
205         * Returns the unique Sample templates that are used in the study
206         */
207        List<Template> giveSampleTemplates() {
208                TemplateEntity.giveTemplates(samples)
209        }
210
211        /**
212         * Return all samples for a specific template, sorted by subject name
213         * @param Template
214         * @return ArrayList
215         */
216        def ArrayList<Subject> giveSamplesForTemplate(Template template) {
217                // sort in a concatenated string as sorting on 3 seperate elements
218                // in a map does not seem to work properly
219                samples.findAll { it.template.equals(template) }.sort {
220                        "${it.parentEvent?.template}|${it.parentEvent?.startTime}|${it.parentSubject?.name}".toLowerCase()
221                }
222        }
223
224        /**
225         * Returns the template of the study
226         */
227        Template giveStudyTemplate() {
228                return this.template
229        }
230
231        /**
232         * Delete a specific subject from this study, including all its relations
233         * @param subject The subject to be deleted
234         * @void
235         */
236        void deleteSubject(Subject subject) {
237                // Delete the subject from the event groups it was referenced in
238                this.eventGroups.each {
239                        if (it.subjects?.contains(subject)) {
240                                it.removeFromSubjects(subject)
241                        }
242                }
243
244                // Delete the samples that have this subject as parent
245                this.samples.findAll { it.parentSubject.equals(subject) }.each {
246                        this.deleteSample(it)
247                }
248
249                // This should remove the subject itself too, because of the cascading belongsTo relation
250                this.removeFromSubjects(subject)
251
252                // But apparently it needs an explicit delete() too
253                subject.delete()
254        }
255
256        /**
257         * Delete an assay from the study
258         * @param Assay
259         * @void
260         */
261        def deleteAssay(Assay assay) {
262                if (assay && assay instanceof Assay) {
263                        // iterate through linked samples
264                        assay.samples.findAll { true }.each() { sample ->
265                                assay.removeFromSamples(sample)
266                        }
267
268                        // remove this assay from the study
269                        this.removeFromAssays(assay)
270
271                        // and delete it explicitly
272                        assay.delete()
273                }
274        }
275
276        /**
277         * Delete an event from the study, including all its relations
278         * @param Event
279         * @void
280         */
281        void deleteEvent(Event event) {
282                // remove event from eventGroups
283                this.eventGroups.each() { eventGroup ->
284                        eventGroup.removeFromEvents(event)
285                }
286
287                // remove event from the study
288                this.removeFromEvents(event)
289
290                // and perform a hard delete
291                event.delete()
292        }
293
294        /**
295         * Delete a sample from the study, including all its relations
296         * @param Event
297         * @void
298         */
299        void deleteSample(Sample sample) {
300                // remove the sample from the study
301                this.removeFromSamples(sample)
302
303                // remove the sample from any sampling events it belongs to
304                this.samplingEvents.findAll { it.samples.any { it == sample }}.each {
305                        it.removeFromSamples(sample)
306                }
307
308                // remove the sample from any assays it belongs to
309                this.assays.findAll { it.samples.any { it == sample }}.each {
310                        it.removeFromSamples(sample)
311                }
312
313                // Also here, contrary to documentation, an extra delete() is needed
314                // otherwise date is not properly deleted!
315                sample.delete()
316        }
317
318        /**
319         * Delete a samplingEvent from the study, including all its relations
320         * @param SamplingEvent
321         * @void
322         */
323        void deleteSamplingEvent(SamplingEvent samplingEvent) {
324                // remove event from eventGroups
325                this.eventGroups.each() { eventGroup ->
326                        eventGroup.removeFromSamplingEvents(samplingEvent)
327                }
328
329                // Delete the samples that have this sampling event as parent
330                this.samples.findAll { it.parentEvent.equals(samplingEvent) }.each {
331                        // This should remove the sample itself too, because of the cascading belongsTo relation
332                        this.deleteSample(it)
333                }
334
335                // Remove event from the study
336                // This should remove the event group itself too, because of the cascading belongsTo relation
337                this.removeFromSamplingEvents(samplingEvent)
338
339                // But apparently it needs an explicit delete() too
340                // (Which can be verified by outcommenting this line, then SampleTests.testDeleteViaParentSamplingEvent fails
341                samplingEvent.delete()
342        }
343
344        /**
345         * Delete an eventGroup from the study, including all its relations
346         * @param EventGroup
347         * @void
348         */
349        void deleteEventGroup(EventGroup eventGroup) {
350                // If the event group contains sampling events
351                if (eventGroup.samplingEvents) {
352                        // remove all samples that originate from this eventGroup
353                        if (eventGroup.samplingEvents.size()) {
354                                // find all samples related to this eventGroup
355                                // - subject comparison is relatively straightforward and
356                                //   behaves as expected
357                                // - event comparison behaves strange, so now we compare
358                                //              1. database id's or,
359                                //              2. object identifiers or,
360                                //              3. objects itself
361                                //   this seems now to work as expected
362                                // - event group comparison: in progress, doesn't always seem to work but doesn't fail either?
363                                this.samples.findAll { sample ->
364                                        (
365                                                        (eventGroup.subjects.findAll {
366                                                                it.equals(sample.parentSubject)
367                                                        })
368                                                        &&
369                                                        (eventGroup.samplingEvents.findAll {
370                                                                (
371                                                                                (it.id && sample.parentEvent.id && it.id == sample.parentEvent.id)
372                                                                                ||
373                                                                                (it.getIdentifier() == sample.parentEvent.getIdentifier())
374                                                                                ||
375                                                                                it.equals(sample.parentEvent)
376                                                                                )
377                                                        })
378                                                        &&
379                                                        eventGroup.equals(sample.parentEventGroup)
380                                        )
381                                }.each() { sample ->
382                                        // remove sample from study
383                                        this.deleteSample(sample)
384                                }
385                        }
386
387                        // remove all samplingEvents from this eventGroup
388                        eventGroup.samplingEvents.findAll {}.each() {
389                                eventGroup.removeFromSamplingEvents(it)
390                        }
391                }
392
393                // If the event group contains subjects
394                if (eventGroup.subjects) {
395                        // remove all subject from this eventGroup
396                        eventGroup.subjects.findAll {}.each() {
397                                eventGroup.removeFromSubjects(it)
398                        }
399                }
400
401                // remove the eventGroup from the study
402                this.removeFromEventGroups(eventGroup)
403
404                // Also here, contrary to documentation, an extra delete() is needed
405                // otherwise cascaded deletes are not properly performed
406                eventGroup.delete()
407        }
408
409        /**
410         * Returns true if the given user is allowed to read this study
411         */
412        public boolean canRead(SecUser loggedInUser) {
413                // Anonymous readers are only given access when published and public
414                if (loggedInUser == null) {
415                        return this.publicstudy && this.published;
416                }
417
418                // Administrators are allowed to read every study
419                if (loggedInUser.hasAdminRights()) {
420                        return true;
421                }
422
423                // Owners and writers are allowed to read this study
424                if (this.owner == loggedInUser || this.writers.contains(loggedInUser)) {
425                        return true
426                }
427
428                // Readers are allowed to read this study when it is published
429                if (this.readers.contains(loggedInUser) && this.published) {
430                        return true
431                }
432
433                return false
434        }
435
436        /**
437         * Returns true if the given user is allowed to write this study
438         */
439        public boolean canWrite(SecUser loggedInUser) {
440                if (loggedInUser == null) {
441                        return false;
442                }
443
444                // Administrators are allowed to write every study
445                if (loggedInUser.hasAdminRights()) {
446                        return true;
447                }
448
449                return this.owner == loggedInUser || this.writers.contains(loggedInUser)
450        }
451
452        /**
453         * Returns true if the given user is the owner of this study
454         */
455        public boolean isOwner(SecUser loggedInUser) {
456                if (loggedInUser == null) {
457                        return false;
458                }
459                return this.owner == loggedInUser
460        }
461
462        /**
463         * Returns a list of studies that are writable for the given user
464         */
465        public static giveWritableStudies(SecUser user, Integer max = null) {
466                // User that are not logged in, are not allowed to write to a study
467                if (user == null)
468                        return [];
469
470                def c = Study.createCriteria()
471
472                // Administrators are allowed to read everything
473                if (user.hasAdminRights()) {
474                        return c.listDistinct {
475                                if (max != null) maxResults(max)
476                                order("title", "asc")
477                               
478                        }
479                }
480
481                return c.listDistinct {
482                        if (max != null) maxResults(max)
483                        order("title", "asc")
484                        or {
485                                eq("owner", user)
486                                writers {
487                                        eq("id", user.id)
488                                }
489                        }
490                }
491        }
492
493        /**
494         * Returns a list of studies that are readable by the given user
495         */
496        public static giveReadableStudies(SecUser user, Integer max = null, int offset = 0) {
497                def c = Study.createCriteria()
498
499                // Administrators are allowed to read everything
500                if (user == null) {
501                        return c.listDistinct {
502                                if (max != null) maxResults(max)
503                                firstResult(offset)
504                                order("title", "asc")
505                                and {
506                                        eq("published", true)
507                                        eq("publicstudy", true)
508                                }
509                        }
510                } else if (user.hasAdminRights()) {
511                        return c.listDistinct {
512                                if (max != null) maxResults(max)
513                                firstResult(offset)
514                                order("title", "asc")
515                        }
516                } else {
517                        return c.listDistinct {
518                                if (max != null) maxResults(max)
519                                firstResult(offset)
520                                order("title", "asc")
521                                or {
522                                        eq("owner", user)
523                                        writers {
524                                                eq("id", user.id)
525                                        }
526                                        and {
527                                                readers {
528                                                        eq("id", user.id)
529                                                }
530                                                eq("published", true)
531                                        }
532                                }
533                        }
534                }
535        }
536
537        /**
538         * perform a text search on studies
539         * @param query
540         * @return
541         */
542        public static textSearchReadableStudies(SecUser user, String query) {
543                def c = Study.createCriteria()
544
545                if (user == null) {
546                        // regular user
547                        return c.listDistinct {
548                                or {
549                                        ilike("title", "%${query}%")
550                                        ilike("description", "%${query}%")
551                                }
552                                and {
553                                        eq("published", true)
554                                        eq("publicstudy", true)
555                                }
556                        }
557                } else if (user.hasAdminRights()) {
558                        // admin can search everything
559                        return c.listDistinct {
560                                or {
561                                        ilike("title", "%${query}%")
562                                        ilike("description", "%${query}%")
563                                }
564                        }
565                } else {
566                        return c.listDistinct {
567                                or {
568                                        ilike("title", "%${query}%")
569                                        ilike("description", "%${query}%")
570                                }
571                                and {
572                                        or {
573                                                eq("owner", user)
574                                                writers {
575                                                        eq("id", user.id)
576                                                }
577                                                and {
578                                                        readers {
579                                                                eq("id", user.id)
580                                                        }
581                                                        eq("published", true)
582                                                }
583                                        }
584                                }
585                        }
586
587                }
588        }
589
590        /**
591         * Returns the number of public studies
592         * @return int
593         */
594        public static countPublicStudies() { return countPublicStudies(true) }
595        public static countPublicStudies(boolean published) {
596                def c = Study.createCriteria()
597                return (c.listDistinct {
598                        and {
599                                eq("published", published)
600                                eq("publicstudy", true)
601                        }
602                }).size()
603        }
604
605        /**
606         * Returns the number of private studies
607         * @return int
608         */
609        public static countPrivateStudies() { return countPrivateStudies(false) }
610        public static countPrivateStudies(boolean published) {
611                def c = Study.createCriteria()
612                return (c.listDistinct {
613                        and {
614                                eq("publicstudy", false)
615                        }
616                        or {
617                                eq("published", published)
618                                eq("publicstudy", true)
619                        }
620                }).size()
621        }
622
623        /**
624         * Returns the number of studies that are readable by the given user
625         */
626        public static countReadableStudies(SecUser user) {
627                def c = Study.createCriteria()
628
629                // got a user?
630                if (user == null) {
631                        return c.count {
632                                and {
633                                        eq("published", true)
634                                        eq("publicstudy", true)
635                                }
636                        }
637                } else if (user.hasAdminRights()) {
638                        // Administrators are allowed to read everything
639                        return Study.count()
640                } else {
641                        return (c.listDistinct {
642                                or {
643                                        eq("owner", user)
644                                        writers {
645                                                eq("id", user.id)
646                                        }
647                                        and {
648                                                readers {
649                                                        eq("id", user.id)
650                                                }
651                                                eq("published", true)
652                                        }
653                                }
654                        }).size()
655                }
656        }
657
658        /**
659         * Returns the number of studies that are readable & writable by the given user
660         */
661        public static countReadableAndWritableStudies(SecUser user) {
662                def c = Study.createCriteria()
663
664                // got a user?
665                if (user == null) {
666                        return 0
667                } else if (user.hasAdminRights()) {
668                        return Study.count()
669                } else {
670                        return (c.listDistinct {
671                                or {
672                                        eq("owner", user)
673                                        writers {
674                                                eq("id", user.id)
675                                        }
676                                }
677                        }).size()
678                }
679        }
680
681        /**
682         * Returns the UUID of this study and generates one if needed
683         */
684        public String giveUUID() {
685                if( !this.studyUUID ) {
686                        this.studyUUID = UUID.randomUUID().toString();
687                        if( !this.save(flush:true) ) {
688                                log.error "Couldn't save study UUID: " + this.getErrors();
689                        }
690                }
691
692                return this.studyUUID;
693        }
694
695        /**
696         * Basic equals method to check whether objects are equals, by comparing the ids
697         * @param o             Object to compare with
698         * @return              True iff the id of the given Study is equal to the id of this Study
699         */
700        public boolean equals( Object o ) {
701                if( o == null )
702                        return false;
703
704                if( !( o instanceof Study ) )
705                        return false
706
707                Study s = (Study) o;
708
709                return this.id == s.id
710        }
711
712    // This closure is used in the before{Insert,Update,Delete} closures below.
713    // It is necessary to prevent flushing in the same session as a top level
714    // database action such as 'save' or 'addTo...'. This confuses hibernate and
715    // produces hard to trace errors.
716    // The same holds for flushing during validation (but that's not the case
717    // here).
718    // http://grails.1312388.n4.nabble.com/Grails-hibernate-flush-causes-IndexOutOfBoundsException-td3031979.html
719    static manualFlush(closure) {
720        withSession {session ->
721            def save
722            try {
723                save = session.flushMode
724                session.flushMode = org.hibernate.FlushMode.MANUAL
725                closure()
726            } finally {
727                if (save) {
728                    session.flushMode = save
729                }
730         }
731        }
732    }
733
734        // Send messages to modules about changes in this study
735        def beforeInsert = {
736        manualFlush{
737            moduleNotificationService.invalidateStudy( this )
738        }
739        }
740        def beforeUpdate = {
741        manualFlush{
742            moduleNotificationService.invalidateStudy( this )
743        }
744        }
745        def beforeDelete = {
746                manualFlush{
747            moduleNotificationService.invalidateStudy( this )
748        }
749        }
750    }
Note: See TracBrowser for help on using the repository browser.