source: trunk/grails-app/domain/dbnp/studycapturing/Study.groovy @ 1870

Last change on this file since 1870 was 1870, checked in by work@…, 8 years ago
  • improved sample sorting for #423
  • Property svn:keywords set to Rev Author Date
File size: 18.7 KB
Line 
1package dbnp.studycapturing
2import org.dbnp.gdt.*
3import dbnp.authentication.SecUser
4
5/**
6 * Domain class describing the basic entity in the study capture part: the Study class.
7 *
8 * Revision information:
9 * $Rev: 1870 $
10 * $Author: work@osx.eu $
11 * $Date: 2011-05-24 15:06:54 +0000 (di, 24 mei 2011) $
12 */
13class Study extends TemplateEntity {
14        static searchable = true
15
16        def moduleNotificationService
17
18        SecUser owner           // The owner of the study. A new study is automatically owned by its creator.
19        String title            // The title of the study
20        String description      // A brief synopsis of what the study is about
21        String code                     // currently used as the external study ID, e.g. to reference a study in a SAM module
22        Date dateCreated
23        Date lastUpdated
24        Date startDate
25        List subjects
26        List events
27        List samplingEvents
28        List eventGroups
29        List samples
30        List assays
31        boolean published = false // Determines whether a study is private (only accessable by the owner and writers) or published (also visible to readers)
32        boolean publicstudy = false  // Determines whether anonymous users are allowed to see this study. This has only effect when published = true
33
34        /**
35         * UUID of this study
36         */
37        String studyUUID
38
39
40        static hasMany = [
41                subjects: Subject,
42                samplingEvents: SamplingEvent,
43                events: Event,
44                eventGroups: EventGroup,
45                samples: Sample,
46                assays: Assay,
47                persons: StudyPerson,
48                publications: Publication,
49                readers: SecUser,
50                writers: SecUser
51        ]
52
53        static constraints = {
54                title(nullable:false, blank: false, unique:true, maxSize: 255)
55                owner(nullable: true, blank: true)
56                code(nullable: true, blank: true, unique: true, maxSize: 255)
57                studyUUID(nullable:true, unique:true, maxSize: 255)
58                persons(size:1..1000)
59                // TODO: add custom validator for 'published' to assess whether the study meets all quality criteria for publication
60                // tested by SampleTests.testStudyPublish
61        }
62
63        // see org.dbnp.gdt.FuzzyStringMatchController and Service
64        static fuzzyStringMatchable = [
65            "title",
66                "code"
67        ]
68
69        static mapping = {
70                autoTimestamp true
71                sort "title"
72
73                // Make sure the TEXT field description is persisted with a TEXT field in the database
74                description type: 'text'
75                // Workaround for bug http://jira.codehaus.org/browse/GRAILS-6754
76                templateTextFields type: 'text'
77
78        }
79
80        // The external identifier (studyToken) is currently the code of the study.
81        // It is used from within dbNP submodules to refer to particular study in this GSCF instance.
82
83        def getToken() { return giveUUID() }
84
85        /**
86         * return the domain fields for this domain class
87         * @return List
88         */
89        static List<TemplateField> giveDomainFields() { return Study.domainFields }
90
91        static final List<TemplateField> domainFields = [
92                new TemplateField(
93                name: 'title',
94                type: TemplateFieldType.STRING,
95                required: true),
96                new TemplateField(
97                name: 'description',
98                type: TemplateFieldType.TEXT,
99                comment:'Give a brief synopsis of what your study is about',
100                required: true),
101                new TemplateField(
102                name: 'code',
103                type: TemplateFieldType.STRING,
104                preferredIdentifier: true,
105                comment: 'Fill out the code by which many people will recognize your study',
106                required: false),
107                new TemplateField(
108                name: 'startDate',
109                type: TemplateFieldType.DATE,
110                comment: 'Fill out the official start date or date of first action',
111                required: true),
112                new TemplateField(
113                name: 'published',
114                type: TemplateFieldType.BOOLEAN,
115                comment: 'Determines whether this study is published (accessible for the study readers and, if the study is public, for anonymous users). A study can only be published if it meets certain quality criteria, which will be checked upon save.',
116                required: false)
117        ]
118
119        /**
120         * return the title of this study
121         */
122        def String toString() {
123                return ( (code) ? code : "[no code]") + " - "+ title
124        }
125
126        /**
127         * returns all events and sampling events that do not belong to a group
128         */
129        def List<Event> getOrphanEvents() {
130                def orphans = events.findAll { event -> !event.belongsToGroup(eventGroups) } +
131                samplingEvents.findAll { event -> !event.belongsToGroup(eventGroups) }
132
133                return orphans
134        }
135
136        /**
137         * Return the unique Subject templates that are used in this study
138         */
139        def List<Template> giveSubjectTemplates() {
140                TemplateEntity.giveTemplates(subjects)
141        }
142
143        /**
144         * Return all subjects for a specific template
145         * @param Template
146         * @return ArrayList
147         */
148        def ArrayList<Subject> giveSubjectsForTemplate(Template template) {
149                subjects.findAll { it.template.equals(template) }
150        }
151
152        /**
153         * Return all unique assay templates
154         * @return Set
155         */
156        List<Template> giveAllAssayTemplates() {
157                TemplateEntity.giveTemplates(((assays) ? assays : []))
158        }
159
160        /**
161         * Return all assays for a particular template
162         * @return ArrayList
163         */
164        def ArrayList giveAssaysForTemplate(Template template) {
165                assays.findAll { it && it.template.equals(template) }
166        }
167
168        /**
169         * Return the unique Event and SamplingEvent templates that are used in this study
170         */
171        List<Template> giveAllEventTemplates() {
172                // For some reason, giveAllEventTemplates() + giveAllSamplingEventTemplates()
173                // gives trouble when asking .size() to the result
174                // So we also use giveTemplates here
175                TemplateEntity.giveTemplates(((events) ? events : []) + ((samplingEvents) ? samplingEvents : []))
176        }
177
178        /**
179         * Return all events and samplingEvenets for a specific template
180         * @param Template
181         * @return ArrayList
182         */
183        def ArrayList giveEventsForTemplate(Template template) {
184                def events = events.findAll { it.template.equals(template) }
185                def samplingEvents = samplingEvents.findAll { it.template.equals(template) }
186
187                return (events) ? events : samplingEvents
188        }
189
190        /**
191         * Return the unique Event templates that are used in this study
192         */
193        List<Template> giveEventTemplates() {
194                TemplateEntity.giveTemplates(events)
195        }
196
197        /**
198         * Return the unique SamplingEvent templates that are used in this study
199         */
200        List<Template> giveSamplingEventTemplates() {
201                TemplateEntity.giveTemplates(samplingEvents)
202        }
203
204        /**
205         * Returns the unique Sample templates that are used in the study
206         */
207        List<Template> giveSampleTemplates() {
208                TemplateEntity.giveTemplates(samples)
209        }
210
211        /**
212         * Return all samples for a specific template, sorted by subject name
213         * @param Template
214         * @return ArrayList
215         */
216        def ArrayList<Subject> giveSamplesForTemplate(Template template) {
217                // sort in a concatenated string as sorting on 3 seperate elements
218                // in a map does not seem to work properly
219                samples.findAll { it.template.equals(template) }.sort {
220                        "${it.parentEvent?.template}|${it.parentEvent?.startTime}|${it.parentSubject?.name}"
221                }
222        }
223
224        /**
225         * Returns the template of the study
226         */
227        Template giveStudyTemplate() {
228                return this.template
229        }
230
231        /**
232         * Delete a specific subject from this study, including all its relations
233         * @param subject The subject to be deleted
234         * @void
235         */
236        void deleteSubject(Subject subject) {
237                // Delete the subject from the event groups it was referenced in
238                this.eventGroups.each {
239                        if (it.subjects?.contains(subject)) {
240                                it.removeFromSubjects(subject)
241                        }
242                }
243
244                // Delete the samples that have this subject as parent
245                this.samples.findAll { it.parentSubject.equals(subject) }.each {
246                        this.deleteSample(it)
247                }
248
249                // This should remove the subject itself too, because of the cascading belongsTo relation
250                this.removeFromSubjects(subject)
251
252                // But apparently it needs an explicit delete() too
253                subject.delete()
254        }
255
256        /**
257         * Delete an assay from the study
258         * @param Assay
259         * @void
260         */
261        def deleteAssay(Assay assay) {
262                if (assay && assay instanceof Assay) {
263                        // iterate through linked samples
264                        assay.samples.findAll { true }.each() { sample ->
265                                assay.removeFromSamples(sample)
266                        }
267
268                        // remove this assay from the study
269                        this.removeFromAssays(assay)
270
271                        // and delete it explicitly
272                        assay.delete()
273                }
274        }
275
276        /**
277         * Delete an event from the study, including all its relations
278         * @param Event
279         * @void
280         */
281        void deleteEvent(Event event) {
282                // remove event from eventGroups
283                this.eventGroups.each() { eventGroup ->
284                        eventGroup.removeFromEvents(event)
285                }
286
287                // remove event from the study
288                this.removeFromEvents(event)
289
290                // and perform a hard delete
291                event.delete()
292        }
293
294        /**
295         * Delete a sample from the study, including all its relations
296         * @param Event
297         * @void
298         */
299        void deleteSample(Sample sample) {
300                // remove the sample from the study
301                this.removeFromSamples(sample)
302
303                // remove the sample from any sampling events it belongs to
304                this.samplingEvents.findAll { it.samples.any { it == sample }}.each {
305                        it.removeFromSamples(sample)
306                }
307
308                // remove the sample from any assays it belongs to
309                this.assays.findAll { it.samples.any { it == sample }}.each {
310                        it.removeFromSamples(sample)
311                }
312
313                // Also here, contrary to documentation, an extra delete() is needed
314                // otherwise date is not properly deleted!
315                sample.delete()
316        }
317
318        /**
319         * Delete a samplingEvent from the study, including all its relations
320         * @param SamplingEvent
321         * @void
322         */
323        void deleteSamplingEvent(SamplingEvent samplingEvent) {
324                // remove event from eventGroups
325                this.eventGroups.each() { eventGroup ->
326                        eventGroup.removeFromSamplingEvents(samplingEvent)
327                }
328
329                // Delete the samples that have this sampling event as parent
330                this.samples.findAll { it.parentEvent.equals(samplingEvent) }.each {
331                        // This should remove the sample itself too, because of the cascading belongsTo relation
332                        this.deleteSample(it)
333                }
334
335                // Remove event from the study
336                // This should remove the event group itself too, because of the cascading belongsTo relation
337                this.removeFromSamplingEvents(samplingEvent)
338
339                // But apparently it needs an explicit delete() too
340                // (Which can be verified by outcommenting this line, then SampleTests.testDeleteViaParentSamplingEvent fails
341                samplingEvent.delete()
342        }
343
344        /**
345         * Delete an eventGroup from the study, including all its relations
346         * @param EventGroup
347         * @void
348         */
349        void deleteEventGroup(EventGroup eventGroup) {
350                // If the event group contains sampling events
351                if (eventGroup.samplingEvents) {
352                        // remove all samples that originate from this eventGroup
353                        if (eventGroup.samplingEvents.size()) {
354                                // find all samples related to this eventGroup
355                                // - subject comparison is relatively straightforward and
356                                //   behaves as expected
357                                // - event comparison behaves strange, so now we compare
358                                //              1. database id's or,
359                                //              2. object identifiers or,
360                                //              3. objects itself
361                                //   this seems now to work as expected
362                                this.samples.findAll { sample ->
363                                        (
364                                                        (eventGroup.subjects.findAll {
365                                                                it.equals(sample.parentSubject)
366                                                        })
367                                                        &&
368                                                        (eventGroup.samplingEvents.findAll {
369                                                                (
370                                                                                (it.id && sample.parentEvent.id && it.id == sample.parentEvent.id)
371                                                                                ||
372                                                                                (it.getIdentifier() == sample.parentEvent.getIdentifier())
373                                                                                ||
374                                                                                it.equals(sample.parentEvent)
375                                                                                )
376                                                        })
377                                                        )
378                                }.each() { sample ->
379                                        // remove sample from study
380                                        this.deleteSample(sample)
381                                }
382                        }
383
384                        // remove all samplingEvents from this eventGroup
385                        eventGroup.samplingEvents.findAll {}.each() {
386                                eventGroup.removeFromSamplingEvents(it)
387                        }
388                }
389
390                // If the event group contains subjects
391                if (eventGroup.subjects) {
392                        // remove all subject from this eventGroup
393                        eventGroup.subjects.findAll {}.each() {
394                                eventGroup.removeFromSubjects(it)
395                        }
396                }
397
398                // remove the eventGroup from the study
399                this.removeFromEventGroups(eventGroup)
400
401                // Also here, contrary to documentation, an extra delete() is needed
402                // otherwise cascaded deletes are not properly performed
403                eventGroup.delete()
404        }
405
406        /**
407         * Returns true if the given user is allowed to read this study
408         */
409        public boolean canRead(SecUser loggedInUser) {
410                // Anonymous readers are only given access when published and public
411                if (loggedInUser == null) {
412                        return this.publicstudy && this.published;
413                }
414
415                // Administrators are allowed to read every study
416                if (loggedInUser.hasAdminRights()) {
417                        return true;
418                }
419
420                // Owners and writers are allowed to read this study
421                if (this.owner == loggedInUser || this.writers.contains(loggedInUser)) {
422                        return true
423                }
424
425                // Readers are allowed to read this study when it is published
426                if (this.readers.contains(loggedInUser) && this.published) {
427                        return true
428                }
429
430                return false
431        }
432
433        /**
434         * Returns true if the given user is allowed to write this study
435         */
436        public boolean canWrite(SecUser loggedInUser) {
437                if (loggedInUser == null) {
438                        return false;
439                }
440
441                // Administrators are allowed to write every study
442                if (loggedInUser.hasAdminRights()) {
443                        return true;
444                }
445
446                return this.owner == loggedInUser || this.writers.contains(loggedInUser)
447        }
448
449        /**
450         * Returns true if the given user is the owner of this study
451         */
452        public boolean isOwner(SecUser loggedInUser) {
453                if (loggedInUser == null) {
454                        return false;
455                }
456                return this.owner == loggedInUser
457        }
458
459        /**
460         * Returns a list of studies that are writable for the given user
461         */
462        public static giveWritableStudies(SecUser user, Integer max = null) {
463                // User that are not logged in, are not allowed to write to a study
464                if (user == null)
465                        return [];
466
467                def c = Study.createCriteria()
468
469                // Administrators are allowed to read everything
470                if (user.hasAdminRights()) {
471                        return c.listDistinct {
472                                if (max != null) maxResults(max)
473                                order("title", "asc")
474                               
475                        }
476                }
477
478                return c.listDistinct {
479                        if (max != null) maxResults(max)
480                        order("title", "asc")
481                        or {
482                                eq("owner", user)
483                                writers {
484                                        eq("id", user.id)
485                                }
486                        }
487                }
488        }
489
490        /**
491         * Returns a list of studies that are readable by the given user
492         */
493        public static giveReadableStudies(SecUser user, Integer max = null, int offset = 0) {
494                def c = Study.createCriteria()
495
496                // Administrators are allowed to read everything
497                if (user == null) {
498                        return c.listDistinct {
499                                if (max != null) maxResults(max)
500                                firstResult(offset)
501                                order("title", "asc")
502                                and {
503                                        eq("published", true)
504                                        eq("publicstudy", true)
505                                }
506                        }
507                } else if (user.hasAdminRights()) {
508                        return c.listDistinct {
509                                if (max != null) maxResults(max)
510                                firstResult(offset)
511                                order("title", "asc")
512                        }
513                } else {
514                        return c.listDistinct {
515                                if (max != null) maxResults(max)
516                                firstResult(offset)
517                                order("title", "asc")
518                                or {
519                                        eq("owner", user)
520                                        writers {
521                                                eq("id", user.id)
522                                        }
523                                        and {
524                                                readers {
525                                                        eq("id", user.id)
526                                                }
527                                                eq("published", true)
528                                        }
529                                }
530                        }
531                }
532        }
533
534        /**
535         * perform a text search on studies
536         * @param query
537         * @return
538         */
539        public static textSearchReadableStudies(SecUser user, String query) {
540                def c = Study.createCriteria()
541
542                if (user == null) {
543                        // regular user
544                        return c.listDistinct {
545                                or {
546                                        ilike("title", "%${query}%")
547                                        ilike("description", "%${query}%")
548                                }
549                                and {
550                                        eq("published", true)
551                                        eq("publicstudy", true)
552                                }
553                        }
554                } else if (user.hasAdminRights()) {
555                        // admin can search everything
556                        return c.listDistinct {
557                                or {
558                                        ilike("title", "%${query}%")
559                                        ilike("description", "%${query}%")
560                                }
561                        }
562                } else {
563                        return c.listDistinct {
564                                or {
565                                        ilike("title", "%${query}%")
566                                        ilike("description", "%${query}%")
567                                }
568                                and {
569                                        or {
570                                                eq("owner", user)
571                                                writers {
572                                                        eq("id", user.id)
573                                                }
574                                                and {
575                                                        readers {
576                                                                eq("id", user.id)
577                                                        }
578                                                        eq("published", true)
579                                                }
580                                        }
581                                }
582                        }
583
584                }
585        }
586
587        /**
588         * Returns the number of public studies
589         * @return int
590         */
591        public static countPublicStudies() { return countPublicStudies(true) }
592        public static countPublicStudies(boolean published) {
593                def c = Study.createCriteria()
594                return (c.listDistinct {
595                        and {
596                                eq("published", published)
597                                eq("publicstudy", true)
598                        }
599                }).size()
600        }
601
602        /**
603         * Returns the number of private studies
604         * @return int
605         */
606        public static countPrivateStudies() { return countPrivateStudies(false) }
607        public static countPrivateStudies(boolean published) {
608                def c = Study.createCriteria()
609                return (c.listDistinct {
610                        and {
611                                eq("publicstudy", false)
612                        }
613                        or {
614                                eq("published", published)
615                                eq("publicstudy", true)
616                        }
617                }).size()
618        }
619
620        /**
621         * Returns the number of studies that are readable by the given user
622         */
623        public static countReadableStudies(SecUser user) {
624                def c = Study.createCriteria()
625
626                // got a user?
627                if (user == null) {
628                        return c.count {
629                                and {
630                                        eq("published", true)
631                                        eq("publicstudy", true)
632                                }
633                        }
634                } else if (user.hasAdminRights()) {
635                        // Administrators are allowed to read everything
636                        return Study.count()
637                } else {
638                        return (c.listDistinct {
639                                or {
640                                        eq("owner", user)
641                                        writers {
642                                                eq("id", user.id)
643                                        }
644                                        and {
645                                                readers {
646                                                        eq("id", user.id)
647                                                }
648                                                eq("published", true)
649                                        }
650                                }
651                        }).size()
652                }
653        }
654
655        /**
656         * Returns the number of studies that are readable & writable by the given user
657         */
658        public static countReadableAndWritableStudies(SecUser user) {
659                def c = Study.createCriteria()
660
661                // got a user?
662                if (user == null) {
663                        return 0
664                } else if (user.hasAdminRights()) {
665                        return Study.count()
666                } else {
667                        return (c.listDistinct {
668                                or {
669                                        eq("owner", user)
670                                        writers {
671                                                eq("id", user.id)
672                                        }
673                                }
674                        }).size()
675                }
676        }
677
678        /**
679         * Returns the UUID of this study and generates one if needed
680         */
681        public String giveUUID() {
682                if( !this.studyUUID ) {
683                        this.studyUUID = UUID.randomUUID().toString();
684                        if( !this.save(flush:true) ) {
685                                log.error "Couldn't save study UUID: " + this.getErrors();
686                        }
687                }
688
689                return this.studyUUID;
690        }
691
692        /**
693         * Basic equals method to check whether objects are equals, by comparing the ids
694         * @param o             Object to compare with
695         * @return              True iff the id of the given Study is equal to the id of this Study
696         */
697        public boolean equals( Object o ) {
698                if( o == null )
699                        return false;
700
701                if( !( o instanceof Study ) )
702                        return false
703
704                Study s = (Study) o;
705
706                return this.id == s.id
707        }
708
709    // This closure is used in the before{Insert,Update,Delete} closures below.
710    // It is necessary to prevent flushing in the same session as a top level
711    // database action such as 'save' or 'addTo...'. This confuses hibernate and
712    // produces hard to trace errors.
713    // The same holds for flushing during validation (but that's not the case
714    // here).
715    // http://grails.1312388.n4.nabble.com/Grails-hibernate-flush-causes-IndexOutOfBoundsException-td3031979.html
716    static manualFlush(closure) {
717        withSession {session ->
718            def save
719            try {
720                save = session.flushMode
721                session.flushMode = org.hibernate.FlushMode.MANUAL
722                closure()
723            } finally {
724                if (save) {
725                    session.flushMode = save
726                }
727         }
728        }
729    }
730
731        // Send messages to modules about changes in this study
732        def beforeInsert = {
733        manualFlush{
734            moduleNotificationService.invalidateStudy( this )
735        }
736        }
737        def beforeUpdate = {
738        manualFlush{
739            moduleNotificationService.invalidateStudy( this )
740        }
741        }
742        def beforeDelete = {
743                manualFlush{
744            moduleNotificationService.invalidateStudy( this )
745        }
746        }
747    }
Note: See TracBrowser for help on using the repository browser.