source: trunk/grails-app/controllers/dbnp/studycapturing/SimpleWizardController.groovy @ 1609

Last change on this file since 1609 was 1609, checked in by robert@…, 9 years ago

Improved simple editing wizard

  • Property svn:keywords set to Rev Author Date
File size: 35.1 KB
Line 
1/**
2 * SimpleWizardController Controler
3 *
4 * Description of my controller
5 *
6 * @author  your email (+name?)
7 * @since       2010mmdd
8 * @package     ???
9 *
10 * Revision information:
11 * $Rev: 1609 $
12 * $Author: robert@isdat.nl $
13 * $Date: 2011-03-09 16:28:45 +0000 (wo, 09 mrt 2011) $
14 */
15package dbnp.studycapturing
16
17import org.apache.poi.ss.usermodel.DataFormatter
18import org.dbnp.gdt.*
19import grails.plugins.springsecurity.Secured
20import dbnp.authentication.SecUser
21import dbnp.importer.ImportCell
22import dbnp.importer.ImportRecord
23import dbnp.importer.MappingColumn
24
25@Secured(['IS_AUTHENTICATED_REMEMBERED'])
26class SimpleWizardController extends StudyWizardController {
27        def authenticationService
28        def fileService
29        def importerService
30        def gdtService = new GdtService()
31
32        /**
33         * index closure
34         */
35        def index = {
36                if( params.id )
37                        redirect( action: "simpleWizard", id: params.id );
38                else
39                        redirect( action: "simpleWizard" );
40        }
41
42        def simpleWizardFlow = {
43                entry {
44                        action{
45                                flow.study = getStudyFromRequest( params )
46                                if (!flow.study) retrievalError()
47                        }
48                        on("retrievalError").to "handleError"
49                        on("success").to "study"
50                }
51
52                study {
53                        on("next") {
54                                handleStudy( flow.study, params )
55                                if( !validateObject( flow.study ) )
56                                        error()
57                        }.to "decisionState"
58                        on("refresh") { handleStudy( flow.study, params ); }.to "study"
59                        on( "success" ) { handleStudy( flow.study, params ) }.to "study"
60                }
61
62                decisionState {
63                        action {
64                                // Create data in the flow
65                                flow.templates = [
66                                                        'Sample': Template.findAllByEntity( Sample.class ),
67                                                        'Subject': Template.findAllByEntity( Subject.class ),
68                                                        'Event': Template.findAllByEntity( Event.class ),
69                                                        'SamplingEvent': Template.findAllByEntity( SamplingEvent.class )
70                                ];
71                                flow.encodedEntity = [
72                                                        'Sample': gdtService.encryptEntity( Sample.class.name ),
73                                                        'Subject': gdtService.encryptEntity( Subject.class.name ),
74                                                        'Event': gdtService.encryptEntity( Event.class.name ),
75                                                        'SamplingEvent': gdtService.encryptEntity( SamplingEvent.class.name )
76                                                ]
77
78                                if (flow.study.samples)
79                                        checkStudySimplicity(flow.study) ? existingSamples() : complexStudy()
80                                else
81                                        samples()
82                        }
83                        on ("existingSamples").to "startExistingSamples"
84                        on ("complexStudy").to "complexStudy"
85                        on ("samples").to "samples"
86                }
87               
88                startExistingSamples {
89                        action {
90                                def records = importerService.getRecords( flow.study );
91                                flow.records = records
92                                flow.templateCombinations = records.templateCombination.unique()
93                                success();
94                        }
95                        on( "success" ).to "existingSamples"
96                }
97
98                existingSamples {
99                        on("next") {
100                                handleExistingSamples( flow.study, params, flow ) ? success() : error()
101                        }.to "startAssays"
102                        on("previous").to "study"
103                        on("update") {
104                                handleExistingSamples( flow.study, params, flow ) ? success() : error()
105                        }.to "samples"
106
107                        on("skip").to "startAssays"
108                }
109
110                complexStudy {
111                        on("save").to "save"
112                        on("previous").to "study"
113                }
114
115                samples {
116                        on("next") {
117                                if( !handleSamples( flow.study, params, flow ) )
118                                        return error();
119                               
120                                // Add domain fields for all entities
121                                flow.domainFields = [:]
122                               
123                                flow.templates.each { 
124                                        if( it.value ) {
125                                                flow.domainFields[ it.key ] = it.value[0].entity.giveDomainFields();
126                                        }
127                                }
128                               
129                                println flow.sampleForm.template
130                        }.to "columns"
131                        on("refresh") {
132                                def filename = params.get( 'importfile' );
133               
134                                // Handle 'existing*' in front of the filename. This is put in front to make a distinction between
135                                // an already uploaded file test.txt (maybe moved to some other directory) and a newly uploaded file test.txt
136                                // still being in the temporary directory.
137                                // This import step doesn't have to make that distinction, since all files remain in the temporary directory.
138                                if( filename == 'existing*' )
139                                        filename = '';
140                                else if( filename[0..8] == 'existing*' )
141                                        filename = filename[9..-1]
142                               
143                                // Refresh the templates, since the template editor has been opened
144                                flow.templates = [
145                                                'Sample': Template.findAllByEntity( Sample.class ),
146                                                'Subject': Template.findAllByEntity( Subject.class ),
147                                                'Event': Template.findAllByEntity( Event.class ),
148                                                'SamplingEvent': Template.findAllByEntity( SamplingEvent.class )
149                                ];
150                                                                               
151                                flow.sampleForm = [ importFile: filename ]
152                        }.to "samples"
153                        on("previous").to "returnFromSamples"
154                        on("study").to "study"
155                        on("skip").to "startAssays"
156                }
157
158                returnFromSamples {
159                        action {
160                                flow.study.samples ? existingSamples() : study();
161                        }
162                        on( "existingSamples" ).to "startExistingSamples"
163                        on( "study" ).to "study"
164                }
165               
166                columns {
167                        on( "next" ) {
168                                handleColumns( flow.study, params, flow ) ? success() : error()
169                        }.to "checkImportedEntities"
170                        on( "previous" ).to "samples" 
171                }
172               
173                checkImportedEntities {
174                        action {
175                                // Only continue to the next page if the information entered is correct
176                                if( flow.imported.numInvalidEntities > 0 ) {
177                                        missingFields();
178                                } else {
179                                        // The import of the excel file has finished. Now delete the excelfile
180                                        if( flow.excel.filename )
181                                                fileService.delete( flow.excel.filename );
182       
183                                        flow.sampleForm = null
184       
185                                        assays();
186                                }
187                        }
188                        on( "missingFields" ).to "missingFields"
189                        on( "assays" ).to "startAssays" 
190                }
191               
192                missingFields {
193                        on( "next" ) {
194                                if( !handleMissingFields( flow.study, params, flow ) ) {
195                                        return error();
196                                }
197                               
198                                // The import of the excel file has finished. Now delete the excelfile
199                                if( flow.excel.filename )
200                                        fileService.delete( flow.excel.filename );
201
202                                flow.sampleForm = null
203                               
204                                success();
205                        }.to "startAssays"
206                        on( "previous" ) {
207                                // The user goes back to the previous page, so the already imported entities
208                                // (of which some gave an error) should be removed again.
209                                // Add all samples
210                                flow.imported.data.each { record ->
211                                        record.each { entity ->
212                                                if( entity ) {
213                                                        switch( entity.class ) {
214                                                                case Sample:    flow.study.removeFromSamples( entity ); break;
215                                                                case Subject:   flow.study.removeFromSubjects( entity ); break;
216                                                                case Event:             flow.study.removeFromEvents( entity ); break;
217                                                                case SamplingEvent:     flow.study.removeFromSamplingEvents( entity ); break;
218                                                        }
219                                                }
220                                        }
221                                }
222                               
223                                success();
224                        }.to "columns"
225                }
226               
227                startAssays {
228                        action {
229                                if( !flow.assay ) 
230                                        flow.assay = new Assay( parent: flow.study );
231                                       
232                                success();
233                        }
234                        on( "success" ).to "assays"
235                }
236               
237                assays {
238                        on( "next" ) { 
239                                handleAssays( flow.assay, params, flow );
240                                if( !validateObject( flow.assay ) )
241                                        error();
242                         }.to "overview"
243                        on( "skip" ) {
244                                // In case the user has created an assay before he clicked 'skip', it should only be kept if it
245                                // existed before this step
246                                if( flow.assay != null && !flow.assay.id ) {
247                                        flow.remove( "assay" )
248                                }
249
250                         }.to "overview"
251                        on( "previous" ).to "returnFromAssays"
252                        on("refresh") { handleAssays( flow.assay, params, flow ); success() }.to "assays"
253                }
254
255                returnFromAssays {
256                        action {
257                                flow.study.samples ? existingSamples() : samples();
258                        }
259                        on( "existingSamples" ).to "existingSamples"
260                        on( "samples" ).to "samples"
261                }
262               
263                overview { 
264                        on( "save" ).to "saveStudy" 
265                        on( "previous" ).to "startAssays"
266                }
267               
268                saveStudy {
269                        action {
270                                if( flow.assay && !flow.study.assays?.contains( flow.assay ) ) {
271                                        flow.study.addToAssays( flow.assay );
272                                }
273                               
274                                if( flow.study.save( flush: true ) ) {
275                                        // Make sure all samples are attached to all assays
276                                        flow.study.assays.each { assay ->
277                                                def l = []+ assay.samples;
278                                                l.each { sample ->
279                                                        if( sample )
280                                                                assay.removeFromSamples( sample );
281                                                }
282                                                assay.samples?.clear();
283               
284                                                flow.study.samples.each { sample ->
285                                                        assay.addToSamples( sample )
286                                                }
287                                        }
288                       
289                                        flash.message = "Your study is succesfully saved.";
290                                       
291                                        finish();
292                                } else {
293                                        flash.error = "An error occurred while saving your study: <br />"
294                                        flow.study.getErrors().each { flash.error += it.toString() + "<br />"}
295                                       
296                                        // Remove the assay from the study again, since it is still available
297                                        // in the session
298                                        if( flow.assay ) {
299                                                flow.study.removeFromAssays( flow.assay );
300                                                flow.assay.parent = flow.study;
301                                        }
302                                       
303                                        overview();
304                                }
305                        }
306                        on( "finish" ).to "finish"
307                        on( "overview" ).to "overview"
308                }
309               
310                finish()
311               
312                handleError{
313                        redirect action: "errorPage"
314                }
315        }
316
317        /**
318         * Retrieves the required study from the database or return an empty Study object if
319         * no id is given
320         *
321         * @param params        Request parameters with params.id being the ID of the study to be retrieved
322         * @return                      A study from the database or an empty study if no id was given
323         */
324        protected Study getStudyFromRequest( def params ) {
325                int id = params.int( "id" );
326
327                if( !id ) {
328                        return new Study( title: "New study", owner: authenticationService.getLoggedInUser() );
329                }
330
331                Study s = Study.get( id );
332
333                if( !s ) {
334                        flash.error = "No study found with given id";
335                        return null;
336                }
337                if( !s.canWrite( authenticationService.getLoggedInUser() ) ) {
338                        flash.error = "No authorization to edit this study."
339                        return null;
340                }
341
342                return s
343        }
344
345        /**
346         * Handles study input
347         * @param study         Study to update
348         * @param params        Request parameter map
349         * @return                      True if everything went OK, false otherwise. An error message is put in flash.error
350         */
351        def handleStudy( study, params ) {
352                // did the study template change?
353                if (params.get('template') && study.template?.name != params.get('template')) {
354                        // set the template
355                        study.template = Template.findByName(params.remove('template'))
356                }
357
358                // does the study have a template set?
359                if (study.template && study.template instanceof Template) {
360                        // yes, iterate through template fields
361                        study.giveFields().each() {
362                                // and set their values
363                                study.setFieldValue(it.name, params.get(it.escapedName()))
364                        }
365                }
366
367                // handle public checkbox
368                if (params.get("publicstudy")) {
369                        study.publicstudy = params.get("publicstudy")
370                }
371
372                // handle publications
373                handleStudyPublications(study, params)
374
375                // handle contacts
376                handleStudyContacts(study, params)
377
378                // handle users (readers, writers)
379                handleStudyUsers(study, params, 'readers')
380                handleStudyUsers(study, params, 'writers')
381
382                return true
383        }
384       
385        /**
386        * Handles the editing of existing samples
387        * @param study          Study to update
388        * @param params         Request parameter map
389        * @return                       True if everything went OK, false otherwise. An error message is put in flash.error
390        */
391   def handleExistingSamples( study, params, flow ) {
392           flash.validationErrors = [];
393
394           def errors = false;
395           
396           // iterate through objects; set field values and validate the object
397           def eventgroups = study.samples.parentEventGroup.findAll { it }
398           def events;
399           if( !eventgroups )
400                   events = []
401           else
402                   events = eventgroups.events?.getAt(0);
403           
404           def objects = [
405                   'Sample': study.samples,
406                   'Subject': study.samples.parentSubject.findAll { it },
407                   'SamplingEvent': study.samples.parentEvent.findAll { it },
408                   'Event': events.flatten().findAll { it }
409           ];
410           objects.each {
411                   def type = it.key;
412                   def entities = it.value;
413                   
414                   entities.each { entity ->
415                           // iterate through entity fields
416                           entity.giveFields().each() { field ->
417                                   def value = params.get( type.toLowerCase() + '_' + entity.getIdentifier() + '_' + field.escapedName())
418
419                                   // set field value; name cannot be set to an empty value
420                                   if (field.name != 'name' || value) {
421                                           log.info "setting "+field.name+" to "+value
422                                           entity.setFieldValue(field.name, value)
423                                   }
424                           }
425                           
426                           // has the template changed?
427                           def templateName = params.get(type.toLowerCase() + '_' + entity.getIdentifier() + '_template')
428                           if (templateName && entity.template?.name != templateName) {
429                                   entity.template = Template.findByName(templateName)
430                           }
431   
432                           // validate sample
433                           if (!entity.validate()) {
434                                   errors = true;
435                                   
436                                   def entityName = entity.class.name[ entity.class.name.lastIndexOf( "." ) + 1 .. -1 ]
437                                   getHumanReadableErrors( entity ).each {
438                                                flash.validationErrors << [ key: it.key, value: "(" + entityName + ") " + it.value ];
439                                   }
440                           }
441                   }
442           }
443
444           return !errors
445   }
446
447        /**
448         * Handles the upload of sample data
449         * @param study         Study to update
450         * @param params        Request parameter map
451         * @return                      True if everything went OK, false otherwise. An error message is put in flash.error
452         */
453        def handleSamples( study, params, flow ) {
454                def filename = params.get( 'importfile' );
455
456                // Handle 'existing*' in front of the filename. This is put in front to make a distinction between
457                // an already uploaded file test.txt (maybe moved to some other directory) and a newly uploaded file test.txt
458                // still being in the temporary directory.
459                // This import step doesn't have to make that distinction, since all files remain in the temporary directory.
460                if( filename == 'existing*' )
461                        filename = '';
462                else if( filename[0..8] == 'existing*' )
463                        filename = filename[9..-1]
464
465                def sampleTemplateId  = params.long( 'sample_template_id' )
466                def subjectTemplateId  = params.long( 'subject_template_id' )
467                def eventTemplateId  = params.long( 'event_template_id' )
468                def samplingEventTemplateId  = params.long( 'samplingEvent_template_id' )
469
470                // These fields have been removed from the form, so will always contain
471                // their default value. The code however remains like this for future use.
472                int sheetIndex = (params.int( 'sheetindex' ) ?: 1 )
473                int dataMatrixStart = (params.int( 'datamatrix_start' ) ?: 2 )
474                int headerRow = (params.int( 'headerrow' ) ?: 1 )
475
476                // Save form data in session
477                flow.sampleForm = [
478                                        importFile: filename,
479                                        templateId: [
480                                                'Sample': sampleTemplateId,
481                                                'Subject': subjectTemplateId,
482                                                'Event': eventTemplateId,
483                                                'SamplingEvent': samplingEventTemplateId
484                                        ],
485                                        template: [
486                                                'Sample': sampleTemplateId ? Template.get( sampleTemplateId ) : null,
487                                                'Subject': subjectTemplateId ? Template.get( subjectTemplateId ) : null,
488                                                'Event': eventTemplateId ? Template.get( eventTemplateId ) : null,
489                                                'SamplingEvent': samplingEventTemplateId ? Template.get( samplingEventTemplateId ) : null
490                                        ],
491                                        sheetIndex: sheetIndex,
492                                        dataMatrixStart: dataMatrixStart,
493                                        headerRow: headerRow
494                                ];
495
496                // Check whether the template exists
497                if (!sampleTemplateId || !Template.get( sampleTemplateId ) ){
498                        log.error ".simple study wizard not all fields are filled in: " + sampleTemplateId
499                        flash.error = "No template was chosen. Please choose a template for the samples you provided."
500                        return false
501                }
502               
503                def importedfile = fileService.get( filename )
504                def workbook
505                if (importedfile.exists()) {
506                        try {
507                                workbook = importerService.getWorkbook(new FileInputStream(importedfile))
508                        } catch (Exception e) {
509                                log.error ".simple study wizard could not load file: " + e
510                                flash.error = "The given file doesn't seem to be an excel file. Please provide an excel file for entering samples.";
511                                return false
512                        }
513                } else {
514                        log.error ".simple study wizard no file given";
515                        flash.error = "No file was given. Please provide an excel file for entering samples.";
516                        return false;
517                }
518
519                if( !workbook ) {
520                        log.error ".simple study wizard could not load file into a workbook"
521                        flash.error = "The given file doesn't seem to be an excel file. Please provide an excel file for entering samples.";
522                        return false
523                }
524
525                def selectedentities = []
526
527                if( !excelChecks( workbook, sheetIndex, headerRow, dataMatrixStart ) )
528                        return false;
529
530                // Get the header from the Excel file using the arguments given in the first step of the wizard
531                def importerHeader;
532                def importerDataMatrix;
533
534                try {           
535                        importerHeader = importerService.getHeader(workbook,
536                                        sheetIndex - 1,                 // 0 == first sheet
537                                        headerRow,                              // 1 == first row :s
538                                        dataMatrixStart - 1,    // 0 == first row
539                                        Sample.class)
540               
541                        importerDataMatrix = importerService.getDatamatrix(
542                                        workbook,
543                                        importerHeader,
544                                        sheetIndex - 1,                 // 0 == first sheet
545                                        dataMatrixStart - 1,    // 0 == first row
546                                        5)
547                } catch( Exception e ) {
548                        // An error occurred while reading the excel file.
549                        log.error ".simple study wizard error while reading the excel file";
550                        e.printStackTrace();
551
552                        // Show a message to the user
553                        flash.error = "An error occurred while reading the excel file. Have you provided the right sheet number and row numbers. Contact your system administrator if this problem persists.";
554                        return false;
555                }
556
557                // Match excel columns with template fields
558                def fieldNames = [];
559                flow.sampleForm.template.each { template ->
560                        if( template.value ) {
561                                def fields = template.value.entity.giveDomainFields() + template.value.getFields();
562                                fields.each { field ->
563                                        if( !field.entity )
564                                                field.entity = template.value.entity
565                                               
566                                        fieldNames << field
567                                }
568                        }
569                }
570                importerHeader.each { mc ->
571                        def bestfit = importerService.mostSimilar( mc.name, fieldNames, 0.8);
572                        if( bestfit ) {
573                                // Remove this fit from the list
574                                fieldNames.remove( bestfit );
575                               
576                                mc.entityclass = bestfit.entity
577                                mc.property = bestfit.name
578                        }
579                }
580               
581                // Save read excel data into session
582                def dataMatrix = [];
583                def df = new DataFormatter();
584                importerDataMatrix.each {
585                        dataMatrix << it.collect{ it ? df.formatCellValue(it) : "" }
586                }
587               
588                flow.excel = [
589                                        filename: filename,
590                                        sheetIndex: sheetIndex,
591                                        dataMatrixStart: dataMatrixStart,
592                                        headerRow: headerRow,
593                                        data: [
594                                                header: importerHeader,
595                                                dataMatrix: dataMatrix
596                                        ]
597                                ]
598
599                return true
600        }
601
602       
603        /**
604         * Handles the matching of template fields with excel columns by the user
605         * @param study         Study to update
606         * @param params        Request parameter map
607         * @return                      True if everything went OK, false otherwise. An error message is put in flash.error
608         *                                      The field session.simpleWizard.imported.numInvalidEntities reflects the number of
609         *                                      entities that have errors, and should be fixed before saving. The errors for those entities
610         *                                      are saved into session.simpleWizard.imported.errors
611         */
612        def handleColumns( study, params, flow ) {
613                // Find actual Template object from the chosen template name
614                def templates = [:];
615                flow.sampleForm.templateId.each {
616                        templates[ it.key ] = it.value ? Template.get( it.value ) : null;
617                }
618               
619                def headers = flow.excel.data.header;
620
621                if( !params.matches ) {
622                        log.error( ".simple study wizard no column matches given" );
623                        flash.error = "No column matches given";
624                        return false;
625                }
626
627                // Retrieve the chosen matches from the request parameters and put them into
628                // the headers-structure, for later reference
629                params.matches.index.each { columnindex, value ->
630                        // Determine the entity and property by splitting it
631                        def parts = value.toString().tokenize( "||" );
632                       
633                        def property
634                        def entityName
635                        if( parts.size() > 1 ) {
636                                property = parts[ 1 ];
637                                entityName = "dbnp.studycapturing." + parts[ 0 ];
638                        } else if( parts.size() == 1 ) {
639                                property = parts[ 0 ];
640                                entityName = headers[columnindex.toInteger()].entityclass.getName();
641                        }
642                       
643                        // Create an actual class instance of the selected entity with the selected template
644                        // This should be inside the closure because in some cases in the advanced importer, the fields can have different target entities
645                        def entityClass = Class.forName( entityName, true, this.getClass().getClassLoader())
646                        def entityObj = entityClass.newInstance(template: templates[ entityName[entityName.lastIndexOf( '.' ) + 1..-1] ])
647
648                        headers[ columnindex.toInteger() ].entityclass = entityClass
649                       
650                        // Store the selected property for this column into the column map for the ImporterService
651                        headers[columnindex.toInteger()].property = property
652
653                        // Look up the template field type of the target TemplateField and store it also in the map
654                        headers[columnindex.toInteger()].templatefieldtype = entityObj.giveFieldType(property)
655
656                        // Is a "Don't import" property assigned to the column?
657                        headers[columnindex.toInteger()].dontimport = (property == "dontimport") ? true : false
658
659                        //if it's an identifier set the mapping column true or false
660                        entityClass.giveDomainFields().each {
661                                headers[columnindex.toInteger()].identifier = ( it.preferredIdentifier && (it.name == property) )
662                        }
663                }
664
665                // Import the workbook and store the table with entity records and store the failed cells
666                println "Importing samples for study " + study + " (" + study.id + ")";
667               
668                def importedfile = fileService.get( flow.excel.filename )
669                def workbook
670                if (importedfile.exists()) {
671                        try {
672                                workbook = importerService.getWorkbook(new FileInputStream(importedfile))
673                        } catch (Exception e) {
674                                log.error ".simple study wizard could not load file: " + e
675                                flash.error = "The given file doesn't seem to be an excel file. Please provide an excel file for entering samples.";
676                                return false
677                        }
678                } else {
679                        log.error ".simple study wizard no file given";
680                        flash.error = "No file was given. Please provide an excel file for entering samples.";
681                        return false;
682                }
683
684                if( !workbook ) {
685                        log.error ".simple study wizard could not load file into a workbook"
686                        flash.error = "The given file doesn't seem to be an excel file. Please provide an excel file for entering samples.";
687                        return false
688                }
689                       
690                def imported = importerService.importOrUpdateDataBySampleIdentifier(templates,
691                                workbook,
692                                flow.excel.sheetIndex - 1,
693                                flow.excel.dataMatrixStart - 1,
694                                flow.excel.data.header,
695                                flow.study,
696                                true                    // Also create entities for which no data is imported but where templates were chosen
697                );
698
699                def table = imported.table
700                def failedcells = imported.failedCells
701
702                flow.imported = [
703                        data: table,
704                        failedCells: failedcells
705                ];
706       
707                // loop through all entities to validate them and add them to failedcells if an error occurs
708                def numInvalidEntities = 0;
709                def errors = [];
710
711                // Add all samples
712                table.each { record ->
713                        record.each { entity ->
714                                if( entity ) {
715                                        // Determine entity class and add a parent. Add the entity to the study
716                                        def preferredIdentifier = importerService.givePreferredIdentifier( entity.class );
717                                        def equalClosure = { it.getFieldValue( preferredIdentifier.name ) == entity.getFieldValue( preferredIdentifier.name ) }
718                                        def entityName = entity.class.name[ entity.class.name.lastIndexOf( "." ) + 1 .. -1 ]
719
720                                        entity.parent = study
721                                       
722                                        switch( entity.class ) {
723                                                case Sample:
724                                                        if( !preferredIdentifier || !study.samples?.find( equalClosure ) ) {
725                                                                study.addToSamples( entity );
726                                                        }
727                                                        break;
728                                                case Subject:
729                                                        if( !preferredIdentifier || !study.subjects?.find( equalClosure ) ) {
730                                                                study.addToSubjects( entity );
731                                                        }
732                                                        break;
733                                                case Event:
734                                                        if( !preferredIdentifier || !study.events?.find( equalClosure ) ) {
735                                                                study.addToEvents( entity );
736                                                        }
737                                                        break;
738                                                case SamplingEvent:
739                                                        if( !preferredIdentifier || !study.samplingEvents?.find( equalClosure ) ) {
740                                                                study.addToSamplingEvents( entity );
741                                                        }
742                                                        break;
743                                        }
744                                       
745                                        if (!entity.validate()) {
746                                                numInvalidEntities++;
747                                               
748                                                // Add this field to the list of failed cells, in order to give the user feedback
749                                                failedcells = addNonValidatingCells( failedcells, entity, flow )
750       
751                                                // Also create a full list of errors
752                                                def currentErrors = getHumanReadableErrors( entity )
753                                                if( currentErrors ) {
754                                                        currentErrors.each {
755                                                                errors += "(" + entityName + ") " + it.value;
756                                                        }
757                                                }
758                                        }
759                                }
760                        }
761                }
762
763                flow.imported.numInvalidEntities = numInvalidEntities + failedcells?.size();
764                flow.imported.errors = errors;
765
766                return true
767        }
768       
769        /**
770         * Handles the update of the edited fields by the user
771         * @param study         Study to update
772         * @param params                Request parameter map
773         * @return                      True if everything went OK, false otherwise. An error message is put in flash.error.
774         *                                      The field session.simpleWizard.imported.numInvalidEntities reflects the number of
775         *                                      entities that still have errors, and should be fixed before saving. The errors for those entities
776         *                                      are saved into session.simpleWizard.imported.errors
777         */
778        def handleMissingFields( study, params, flow ) {
779                def numInvalidEntities = 0;
780                def errors = [];
781
782                // Check which fields failed previously
783                def failedCells = flow.imported.failedCells
784                def newFailedCells = [];
785
786                flow.imported.data.each { table ->
787                        table.each { entity ->
788                                def invalidFields = 0
789                                def failed = new ImportRecord();
790                                def entityName = entity.class.name[ entity.class.name.lastIndexOf( "." ) + 1 .. -1 ]
791                               
792
793                                // Set the fields for this entity by retrieving values from the params
794                                entity.giveFields().each { field ->
795                                        def fieldName = importerService.getFieldNameInTableEditor( entity, field );
796
797                                        if( params[ fieldName ] == "#invalidterm" ) {
798                                                // If the value '#invalidterm' is chosen, the user hasn't fixed anything, so this field is still incorrect
799                                                invalidFields++;
800                                               
801                                                // store the mapping column and value which failed
802                                                def identifier = entityName.toLowerCase() + "_" + entity.getIdentifier() + "_" + fieldName
803                                                def mcInstance = new MappingColumn()
804                                                failed.addToImportcells(new ImportCell(mappingcolumn: mcInstance, value: params[ fieldName ], entityidentifier: identifier))
805                                        } else {
806                                                if( field.type == org.dbnp.gdt.TemplateFieldType.ONTOLOGYTERM || field.type == org.dbnp.gdt.TemplateFieldType.STRINGLIST ) {
807                                                        // If this field is an ontologyterm field or a stringlist field, the value has changed, so remove the field from
808                                                        // the failedCells list
809                                                        importerService.removeFailedCell( failedCells, entity, field )
810                                                }
811
812                                                // Update the field, regardless of the type of field
813                                                entity.setFieldValue(field.name, params[ fieldName ] )
814                                        }
815                                }
816                               
817                                // Try to validate the entity now all fields have been set. If it fails, return an error
818                                if (!entity.validate() || invalidFields) {
819                                        numInvalidEntities++;
820
821                                        // Add this field to the list of failed cells, in order to give the user feedback
822                                        failedCells = addNonValidatingCellsToImportRecord( failed, entity, flow )
823
824                                        // Also create a full list of errors
825                                        def currentErrors = getHumanReadableErrors( entity )
826                                        if( currentErrors ) {
827                                                currentErrors.each {
828                                                        errors += "(" + entityName + ") " + it.value;
829                                                }
830                                        }
831                                       
832                                        newFailedCells << failed;
833                                } else {
834                                        importerService.removeFailedCell( failedCells, entity )
835                                }
836                        } // end of record
837                } // end of table
838
839                flow.imported.failedCells = newFailedCells
840                flow.imported.numInvalidEntities = numInvalidEntities;
841                flow.imported.errors = errors;
842
843                return numInvalidEntities == 0
844        }
845       
846        /**
847        * Handles assay input
848        * @param study          Study to update
849        * @param params         Request parameter map
850        * @return                       True if everything went OK, false otherwise. An error message is put in flash.error
851        */
852   def handleAssays( assay, params, flow ) {
853           // did the study template change?
854           if (params.get('template') && assay.template?.name != params.get('template')) {
855                   // set the template
856                   assay.template = Template.findByName(params.remove('template'))
857           }
858
859           // does the study have a template set?
860           if (assay.template && assay.template instanceof Template) {
861                   // yes, iterate through template fields
862                   assay.giveFields().each() {
863                           // and set their values
864                           assay.setFieldValue(it.name, params.get(it.escapedName()))
865                   }
866           }
867
868           return true
869   }
870       
871       
872        /**
873         * Checks whether the given study is simple enough to be edited using this controller.
874         *
875         * The study is simple enough if the samples, subjects, events and samplingEvents can be
876         * edited as a flat table. That is:
877         *              - Every subject belongs to 0 or 1 eventgroup
878         *              - Every eventgroup belongs to 0 or 1 sample
879         *              - Every eventgroup has 0 or 1 subjects, 0 or 1 event and 0 or 1 samplingEvents
880         *              - If a sample belongs to an eventgroup:
881         *                      - If that eventgroup has a samplingEvent, that same samplingEvent must also be
882         *                              the sampling event that generated this sample
883         *                      - If that eventgroup has a subject, that same subject must also be the subject
884         *                              from whom the sample was taken
885         *
886         * @param study         Study to check
887         * @return                      True if the study can be edited by this controller, false otherwise
888         */
889        def checkStudySimplicity( study ) {
890                def simplicity = true;
891
892                if( !study )
893                        return false
894
895                if( study.eventGroups ) {
896                        study.eventGroups.each { eventGroup ->
897                                // Check for simplicity of eventgroups: only 0 or 1 subject, 0 or 1 event and 0 or 1 samplingEvent
898                                if( eventGroup.subjects?.size() > 1 || eventGroup.events?.size() > 1 || eventGroup.samplingEvents?.size() > 1 ) {
899                                        flash.message = "One or more eventgroups contain multiple subjects or events."
900                                        simplicity = false;
901                                }
902
903                                // Check whether this eventgroup only belongs to (max) 1 sample
904                                def numSamples = 0;
905                                study.samples.each { sample ->
906                                        // If no id is given for the eventGroup, it has been entered in this wizard, but
907                                        // not yet saved. In that case, it is always OK
908                                        if( eventGroup.id && sample.parentEventGroup?.id == eventGroup.id )
909                                                numSamples++;
910                                }
911
912                                if( numSamples > 1 ) {
913                                        flash.message = "One or more eventgroups belong to multiple samples."
914                                        simplicity = false;
915                                }
916                        }
917
918                        if( !simplicity ) return false;
919
920                        // Check whether subject only belong to zero or one event group
921                        if( study.subjects ) {
922                                study.subjects.each { subject ->
923                                        def numEventGroups = 0
924                                        study.eventGroups.each { eventGroup ->
925                                                // If no id is given for the subject, it has been entered in this wizard, but
926                                                // not yet saved. In that case, it is always OK
927                                                if( subject.id && eventGroup.subjects[0]?.id == subject.id )
928                                                        numEventGroups++
929                                        }
930
931                                        if( numEventGroups > 1 ) {
932                                                flash.message = "One or more subjects belong to multiple eventgroups."
933                                                simplicity = false;
934                                        }
935                                }
936                        }
937
938                        if( !simplicity ) return false;
939
940                        // Check whether the samples that belong to an eventgroup have the right parentObjects
941                        study.samples.each { sample ->
942                                if( sample.parentEventGroup ) {
943                                        // If no id is given for the subject, it has been entered in this wizard, but
944                                        // not yet saved. In that case, it is always OK
945                                        if( sample.parentSubject && sample.parentSubject.id) {
946                                                if( !sample.parentEventGroup.subjects || sample.parentEventGroup.subjects[0]?.id != sample.parentSubject.id ) {
947                                                        flash.message = "The structure of the eventgroups of one or more samples is too complex"
948                                                        simplicity = false;
949                                                }
950                                        }
951
952                                        // If no id is given for the sampling event, it has been entered in this wizard, but
953                                        // not yet saved. In that case, it is always OK
954                                        if( sample.parentEvent && sample.parentEvent.id) {
955                                                if( !sample.parentEventGroup.samplingEvents || sample.parentEventGroup.samplingEvents[0]?.id != sample.parentEvent.id ) {
956                                                        flash.message = "The structure of the eventgroups of one or more samples is too complex"
957                                                        simplicity = false;
958                                                }
959                                        }
960                                }
961                        }
962
963                        if( !simplicity ) return false;
964                }
965
966                return simplicity;
967        }
968
969       
970        /**
971         * Adds all fields of this entity that have given an error when validating to the failedcells list
972         * @param failedcells   Current list of ImportRecords
973         * @param entity                Entity to check. The entity must have been validated before
974         * @return                              Updated list of ImportRecords
975         */
976        protected def addNonValidatingCells( failedcells, entity, flow ) {
977                // Add this entity and the fields with an error to the failedCells list
978                ImportRecord failedRecord = addNonValidatingCellsToImportRecord( new ImportRecord(), entity, flow );
979
980                failedcells.add( failedRecord );
981
982                return failedcells
983        }
984       
985        /**
986        * Adds all fields of this entity that have given an error when validating to the failedcells list
987        * @param failedcells    Current list of ImportRecords
988        * @param entity         Entity to check. The entity must have been validated before
989        * @return                               Updated list of ImportRecords
990        */
991   protected def addNonValidatingCellsToImportRecord( failedRecord, entity, flow ) {
992           entity.getErrors().getFieldErrors().each { error ->
993                   String field = error.getField();
994                   
995                   def mc = importerService.findMappingColumn( flow.excel.data.header, field );
996                   def mcInstance = new MappingColumn( name: field, entityClass: Sample.class, index: -1, property: field.toLowerCase(), templateFieldType: entity.giveFieldType( field ) );
997
998                   // Create a clone of the mapping column
999                   if( mc ) {
1000                           mcInstance.properties = mc.properties
1001                   }
1002
1003                   failedRecord.addToImportcells( new ImportCell(mappingcolumn: mcInstance, value: error.getRejectedValue(), entityidentifier: importerService.getFieldNameInTableEditor( entity, field ) ) )
1004           }
1005           
1006           return failedRecord
1007   }
1008
1009       
1010        /**
1011        * Checks an excel workbook whether the given sheetindex and rownumbers are correct
1012        * @param workbook                       Excel workbook to read
1013        * @param sheetIndex             1-based sheet index for the sheet to read (1=first sheet)
1014        * @param headerRow                      1-based row number for the header row (1=first row)
1015        * @param dataMatrixStart        1-based row number for the first data row (1=first row)
1016        * @return                                       True if the sheet index and row numbers are correct.
1017        */
1018   protected boolean excelChecks( def workbook, int sheetIndex, int headerRow, int dataMatrixStart ) {
1019           // Perform some basic checks on the excel file. These checks should be performed by the importerservice
1020           // in a perfect scenario.
1021           if( sheetIndex > workbook.getNumberOfSheets() ) {
1022                   log.error ".simple study wizard Sheet index is too high: " + sheetIndex + " / " + workbook.getNumberOfSheets();
1023                   flash.error = "Your excel sheet contains too few excel sheets. The provided excel sheet has only " + workbook.getNumberOfSheets() + " sheet(s).";
1024                   return false
1025           }
1026
1027           def sheet = workbook.getSheetAt(sheetIndex - 1);
1028           def firstRowNum = sheet.getFirstRowNum();
1029           def lastRowNum = sheet.getLastRowNum();
1030           def numRows = lastRowNum - firstRowNum + 1;
1031
1032           if( headerRow > numRows  ) {
1033                   log.error ".simple study wizard Header row number is incorrect: " + headerRow + " / " + numRows;
1034                   flash.error = "Your excel sheet doesn't contain enough rows (" + numRows + "). Please provide an excel sheet with one header row and data below";
1035                   return false
1036           }
1037
1038           if( dataMatrixStart > numRows  ) {
1039                   log.error ".simple study wizard Data row number is incorrect: " + dataMatrixStart + " / " + numRows;
1040                   flash.error = "Your excel sheet doesn't contain enough rows (" + numRows + "). Please provide an excel sheet with one header row and data below";
1041                   return false
1042           }
1043
1044           return true;
1045   }
1046       
1047        /**
1048         * Validates an object and puts human readable errors in validationErrors variable
1049         * @param entity                Entity to validate
1050         * @return                      True iff the entity validates, false otherwise
1051         */
1052        protected boolean validateObject( def entity ) {
1053                if( !entity.validate() ) {
1054                        flash.validationErrors = getHumanReadableErrors( entity )
1055                        return false;
1056                }
1057                return true;
1058        }
1059
1060        /**
1061         * transform domain class validation errors into a human readable
1062         * linked hash map
1063         * @param object validated domain class
1064         * @return object  linkedHashMap
1065         */
1066        def getHumanReadableErrors(object) {
1067                def errors = [:]
1068                object.errors.getAllErrors().each() { error ->
1069                        // error.codes.each() { code -> println code }
1070
1071                        // generally speaking g.message(...) should work,
1072                        // however it fails in some steps of the wizard
1073                        // (add event, add assay, etc) so g is not always
1074                        // availably. Using our own instance of the
1075                        // validationTagLib instead so it is always
1076                        // available to us
1077                        errors[error.getArguments()[0]] = validationTagLib.message(error: error)
1078                }
1079
1080                return errors
1081        }
1082}
Note: See TracBrowser for help on using the repository browser.