source: trunk/grails-app/controllers/dbnp/studycapturing/AssayController.groovy @ 1799

Last change on this file since 1799 was 1799, checked in by robert@…, 10 years ago

Adjusted assay exporting to use CSV export method

  • Property svn:keywords set to Rev Author Date
File size: 10.5 KB
Line 
1package dbnp.studycapturing
2
3class AssayController {
4
5        def assayService
6        def authenticationService
7        def fileService
8
9        static allowedMethods = [save: "POST", update: "POST", delete: "POST"]
10
11        def index = {
12                redirect(action: "list", params: params)
13        }
14
15        def list = {
16                params.max = Math.min(params.max ? params.int('max') : 10, 100)
17                [assayInstanceList: Assay.list(params), assayInstanceTotal: Assay.count()]
18        }
19
20        def create = {
21                def assayInstance = new Assay()
22                assayInstance.properties = params
23                return [assayInstance: assayInstance]
24        }
25
26        def save = {
27                def assayInstance = new Assay(params)
28
29                // The following lines deviate from the generate-all generated code.
30                // See http://jira.codehaus.org/browse/GRAILS-3783 for why we have this shameful workaround...
31                def study = assayInstance.parent
32                study.addToAssays(assayInstance)
33
34                if (assayInstance.save(flush: true)) {
35                        flash.message = "${message(code: 'default.created.message', args: [message(code: 'assay.label', default: 'Assay'), assayInstance.id])}"
36                        redirect(action: "show", id: assayInstance.id)
37                }
38                else {
39                        render(view: "create", model: [assayInstance: assayInstance])
40                }
41        }
42
43        def show = {
44                def assayInstance = Assay.get(params.id)
45                if (!assayInstance) {
46                        flash.message = "${message(code: 'default.not.found.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
47                        redirect(action: "list")
48                }
49                else {
50                        [assayInstance: assayInstance]
51                }
52        }
53
54        def showByToken = {
55                def assayInstance = Assay.findByAssayUUID(params.id)
56                if (!assayInstance) {
57                        flash.message = "${message(code: 'default.not.found.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
58                        redirect(action: "list")
59                }
60                else {
61                        redirect(action: "show", id: assayInstance.id)
62                }
63        }
64
65        def edit = {
66                def assayInstance = Assay.get(params.id)
67                if (!assayInstance) {
68                        flash.message = "${message(code: 'default.not.found.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
69                        redirect(action: "list")
70                }
71                else {
72                        return [assayInstance: assayInstance]
73                }
74        }
75
76        def update = {
77                def assayInstance = Assay.get(params.id)
78                if (assayInstance) {
79                        if (params.version) {
80                                def version = params.version.toLong()
81                                if (assayInstance.version > version) {
82
83                                        assayInstance.errors.rejectValue("version", "default.optimistic.locking.failure", [message(code: 'assay.label', default: 'Assay')] as Object[], "Another user has updated this Assay while you were editing")
84                                        render(view: "edit", model: [assayInstance: assayInstance])
85                                        return
86                                }
87                        }
88                        assayInstance.properties = params
89                        if (!assayInstance.hasErrors() && assayInstance.save(flush: true)) {
90                                flash.message = "${message(code: 'default.updated.message', args: [message(code: 'assay.label', default: 'Assay'), assayInstance.id])}"
91                                redirect(action: "show", id: assayInstance.id)
92                        }
93                        else {
94                                render(view: "edit", model: [assayInstance: assayInstance])
95                        }
96                }
97                else {
98                        flash.message = "${message(code: 'default.not.found.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
99                        redirect(action: "list")
100                }
101        }
102
103        def delete = {
104                def assayInstance = Assay.get(params.id)
105                if (assayInstance) {
106                        try {
107                                assayInstance.delete(flush: true)
108                                flash.message = "${message(code: 'default.deleted.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
109                                redirect(action: "list")
110                        }
111                        catch (org.springframework.dao.DataIntegrityViolationException e) {
112                                flash.message = "${message(code: 'default.not.deleted.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
113                                redirect(action: "show", id: params.id)
114                        }
115                }
116                else {
117                        flash.message = "${message(code: 'default.not.found.message', args: [message(code: 'assay.label', default: 'Assay'), params.id])}"
118                        redirect(action: "list")
119                }
120        }
121
122        def assayExportFlow = {
123                entry {
124                        action{
125                                def user            = authenticationService.getLoggedInUser()
126                                flow.userStudies    = Study.giveReadableStudies(user)
127                        }
128                        on("success").to "selectAssay"
129                }
130
131                selectAssay {
132                        on ("submit"){
133                                flow.assay = Assay.get(params.assayId)
134
135                                // check if assay exists
136                                if (!flow.assay) throw new Exception("No assay found with id: ${params.assayId}")
137
138                                // obtain fields for each category
139                                flow.fieldMap = assayService.collectAssayTemplateFields(flow.assay)
140
141                                flow.measurementTokens = flow.fieldMap.remove('Module Measurement Data')
142                        }.to "selectFields"
143
144                        on(Exception).to "handleError"
145                }
146
147                selectFields {
148                        on ("submit"){
149                                def fieldMapSelection = [:]
150
151                                flow.fieldMap.eachWithIndex { cat, cat_i ->
152
153                                        if (params."cat_$cat_i" == 'on') {
154                                                fieldMapSelection[cat.key] = []
155
156                                                cat.value.eachWithIndex { field, field_i ->
157
158                                                        if (params."cat_${cat_i}_${field_i}" == 'on')
159                                                                fieldMapSelection[cat.key] += field
160                                                }
161
162                                                if (fieldMapSelection[cat.key] == [])
163                                                        fieldMapSelection.remove(cat.key)
164                                        }
165                                }
166
167                                def measurementTokens = []
168
169                                if (params."cat_4" == 'on') {
170                                        measurementTokens = params.list( "measurementToken" )
171                                }
172
173                                def assayData           = assayService.collectAssayData(flow.assay, fieldMapSelection, measurementTokens)
174                                flow.rowData            = assayService.convertColumnToRowStructure(assayData)
175
176                                def previewRows         = Math.min(flow.rowData.size()    as int, 5) - 1
177                                def previewCols         = Math.min(flow.rowData[0].size() as int, 5) - 1
178
179                                flow.assayDataPreview   = flow.rowData[0..previewRows].collect{ it[0..previewCols] as ArrayList }
180
181                        }.to "compileExportData"
182
183                        on(Exception).to "handleError"
184                }
185
186                compileExportData {
187                        on ("ok"){session.rowData = flow.rowData}.to "export"
188                        on ("cancel").to "selectAssay"
189                }
190
191                export {
192                        redirect(action: 'doExport')
193                }
194
195                handleError() {
196                        render(view: 'errorPage')
197                }
198        }
199
200        /**
201         * Export the row data in session.rowData to the outputStream of the http
202         * response.
203         */
204        def doExport = {
205
206                def filename = 'export.csv'
207                response.setHeader("Content-disposition", "attachment;filename=\"${filename}\"")
208                response.setContentType("application/octet-stream")
209                try {
210
211                        //                      assayService.exportRowWiseDataToExcelFile(session.rowData, response.outputStream)
212                        assayService.exportRowWiseDataToCSVFile(session.rowData, response.outputStream)
213
214                        // clear the data from the session
215                        session.removeAttribute('rowData')
216
217                } catch (Exception e) {
218
219                        flash.errorMessage = e.message
220                        redirect action: 'errorPage'
221
222                }
223        }
224
225        /**
226         * Method to export one or more assays to excel in separate sheets.
227         *
228         * @param       params.ids              One or more assay IDs to export
229         * @param       params.format   "list" in order to export all assays in one big excel sheet
230         *                                                      "sheets" in order to export every assay on its own sheet (default)
231         */
232        def exportToExcel = {
233                def format = params.get( 'format', 'sheets' );
234                if( format == 'list' ) {
235                        exportToExcelAsList( params );
236                } else {
237                        exportToExcelAsSheets( params );
238                }
239        }
240
241        /**
242         * Method to export one or more assays to excel in separate sheets.
243         *
244         * @param       params.ids              One or more assay IDs to export
245         */
246        def exportToExcelAsSheets = {
247                def assays = getAssaysFromParams( params );
248               
249                if( !assays )
250                        return;
251
252                // Send headers to the browser so the user can download the file
253                def filename = 'export.xlsx'
254                response.setHeader("Content-disposition", "attachment;filename=\"${filename}\"")
255                response.setContentType("application/octet-stream")
256
257                try {
258                        // Loop through all assays to collect the data
259                        def rowWiseAssayData = [];
260
261                        assays.each { assay ->
262                                // Determine which fields should be exported for this assay
263                                def fieldMap = assayService.collectAssayTemplateFields(assay)
264                                def measurementTokens = fieldMap.remove('Module Measurement Data')
265
266                                // Retrieve row based data for this assay
267                                def assayData = assayService.collectAssayData( assay, fieldMap, measurementTokens );
268                                def rowData   = assayService.convertColumnToRowStructure(assayData)
269
270                                // Put each assay on another sheet
271                                rowWiseAssayData << rowData;
272                        }
273
274                        assayService.exportRowWiseDataForMultipleAssaysToExcelFile( rowWiseAssayData, response.getOutputStream() )
275
276                        response.outputStream.flush()
277
278                } catch (Exception e) {
279                        throw e;
280                }
281        }
282
283        /**
284         * Method to export one or more assays to excel.
285         *
286         * @param       params.ids              One or more assay IDs to export
287         */
288        def exportToExcelAsList = {
289                def assays = getAssaysFromParams( params );
290               
291                if( !assays )
292                        return;
293
294                // Send headers to the browser so the user can download the file
295                def filename = 'export.csv'
296                response.setHeader("Content-disposition", "attachment;filename=\"${filename}\"")
297                response.setContentType("application/octet-stream")
298
299                try {
300                        // Loop through all assays to collect the data
301                        def columnWiseAssayData = [];
302
303                        assays.each { assay ->
304                                // Determine which fields should be exported for this assay
305                                def fieldMap = assayService.collectAssayTemplateFields(assay)
306                                def measurementTokens = fieldMap.remove('Module Measurement Data')
307
308                                // Retrieve row based data for this assay
309                                def assayData = assayService.collectAssayData( assay, fieldMap, measurementTokens );
310
311                                // Prepend study and assay data to the list
312                                assayData = assayService.prependAssayData( assayData, assay, assay.samples?.size() )
313                                assayData = assayService.prependStudyData( assayData, assay, assay.samples?.size() )
314
315                                // Put each assay on another sheet
316                                columnWiseAssayData << assayData;
317                        }
318
319                        // Merge data from all assays
320                        def mergedColumnWiseData = assayService.mergeColumnWiseDataOfMultipleStudies( columnWiseAssayData );
321
322                        def rowData   = assayService.convertColumnToRowStructure(mergedColumnWiseData)
323                        assayService.exportRowWiseDataToCSVFile( rowData, response.getOutputStream() )
324
325                        response.outputStream.flush()
326
327                } catch (Exception e) {
328                        throw e;
329                }
330        }
331
332        def getAssaysFromParams( params ) {
333                def ids = params.list( 'ids' ).findAll { it.isLong() }.collect { Long.valueOf( it ) };
334                def tokens = params.list( 'tokens' );
335
336                if( !ids && !tokens ) {
337                        flash.errorMessage = "No assay ids given";
338                        redirect( action: "errorPage" );
339                        return [];
340                }
341
342                // Find all assays for the given ids
343                def assays = [];
344                ids.each { id ->
345                        def assay = Assay.get( id );
346                        if( assay )
347                                assays << assay;
348                }
349
350                // Also accept tokens for defining studies
351                tokens.each { token ->
352                        def assay = Assay.findByAssayUUID( token );
353                        if( assay )
354                                assays << assay;
355                }
356               
357                if( !assays ) {
358                        flash.errorMessage = "No assays found";
359                        redirect( action: "errorPage" );
360                        return [];
361                }
362               
363                return assays.unique();
364        }
365
366        def errorPage = {
367                render(view: 'assayExport/errorPage')
368        }
369}
Note: See TracBrowser for help on using the repository browser.