source: trunk/test/integration/nl/tno/metagenomics/integration/MockGSCF.groovy @ 7

package nl.tno.metagenomics.integration

import com.sun.net.httpserver.*
import org.apache.commons.io.FileUtils

class MockGSCF {
        private String response = 'null'
        private def restResponse = [:]
        private def restStatus = [:]
        private HttpServer server =  null

        String contentType = 'text/html'
        Integer status = 200

        public MockGSCF(Integer port) {
                server = HttpServer.create(new InetSocketAddress(port),0)

                server.createContext('/', { HttpExchange exchange -> 
                        println "GSCF other URI: " + exchange.getRequestURI();
                        
                        MockGSCF.writeResponseData( exchange, status, response ) 
                }  as HttpHandler );
                server.createContext('/rest/getStudies', { HttpExchange exchange -> 
                        println "GSCF getStudies: " + exchange.getRequestURI();
                        
                        def studyToken = MockGSCF.getParameter( exchange, "studyToken" );
                        if( !studyToken ) {
                                studyToken = "-"
                        }
                        
                        println "StudyToken: " + studyToken
                        
                        MockGSCF.writeResponseData( exchange, getRestStatus( "getStudies", studyToken ), getRestResponse( "getStudies", studyToken ) );
                        
                }  as HttpHandler );
                server.createContext('/rest/getAssays', { HttpExchange exchange -> 
                        println "GSCF getAssays: " + exchange.getRequestURI();
                        def studyToken = MockGSCF.getParameter( exchange, "studyToken" );
                        def assayToken = MockGSCF.getParameter( exchange, "assayToken" );
                        
                        def method = "getAssays";
                        def token = studyToken
                        if( assayToken ) 
                                token = token + "-" + assayToken
                                
                        MockGSCF.writeResponseData( exchange, getRestStatus( method, token ), getRestResponse( method, token ) );
                }  as HttpHandler );
                server.createContext('/rest/getSamples', { HttpExchange exchange -> 
                        println "GSCF getSamples: " + exchange.getRequestURI();
                        def assayToken = MockGSCF.getParameter( exchange, "assayToken" );
                        def sampleToken = MockGSCF.getParameter( exchange, "sampleToken" );
                        
                        def method = "getSamples";
                        def token = assayToken
                        if( sampleToken )
                                token = token + "-" + sampleToken
                                
                        MockGSCF.writeResponseData( exchange, getRestStatus( method, token ), getRestResponse( method, token ) );
        
                }  as HttpHandler );
                server.createContext('/rest/getAuthorizationLevel', { HttpExchange exchange ->
                        println "GSCF getAuthorizationlevel: " + exchange.getRequestURI();
                        def studyToken = MockGSCF.getParameter( exchange, "studyToken" );
                                
                        def method = "getAuthorizationLevel";
                        def token = "-"
                        if( studyToken )
                                token = studyToken
                                
                        MockGSCF.writeResponseData( exchange, getRestStatus( method, token ), getRestResponse( method, token ) );

                }  as HttpHandler );
                
                server.start()
        }

        public void stop() {
                if (server)
                        server.stop(0);
        }

        public void setResponseByFile(String filename) {
                response = FileUtils.readFileToString(new File(filename), "UTF-8")
        }

        public void setRestResponse( String method, def response ) {
                restResponse[ method ] = response;
        }

        public void setRestResponse( String method, String token, def response ) {
                if( !restResponse[ method ] )
                        restResponse[ method ] = [:]

                restResponse[ method ][ token ] = response;
        }

        public void setRestStatus( String method, String token, Integer status ) {
                if( !restStatus[ method ] )
                        restStatus[ method ] = [:]

                restStatus[ method ][ token ] = status;
        }
        
        public Integer getRestStatus( String method, String token ) {
                if( restStatus[ method ] && restStatus[ method ][ token ] ) {
                        def r = restStatus[ method ][ token ];
                        
                        if( r instanceof Integer ) {
                                return r
                        } else {
                                try {
                                        return Integer.parseInt( r.toString() )
                                } catch( Exception e ) {
                                        return status;
                                }
                        }
                }
                
                return status
        }
        
        public String getRestResponse( String method, String token ) {
                if( restResponse[ method ] && restResponse[ method ][ token ] ) {
                        return restResponse[ method ][ token ].toString();
                }
                
                return this.response
        }

        public static void writeResponseData( HttpExchange exchange, Integer status, String resp ) {
                println "Returning " + resp
                
                exchange.responseHeaders[ "Content-Type" ] = "application/json"
                exchange.sendResponseHeaders(status, resp.bytes.length);
                exchange.responseBody.write(resp.bytes)
                exchange.responseBody.close()
                exchange.close();
        }
        
        public static String getParameter( HttpExchange exchange, String parameter ) {
                String query = exchange.getRequestURI().query
                
                def parts = query.split( '&' );
                for( it in parts ) {
                        def param = it.split( '=' );
                        
                        if( param.size() > 0 && param[0].toString().equals( parameter ) ) {
                                if( param.size() > 1)
                                        return param[ 1 ]
                                else 
                                        return param[ 0 ]
                        }
                }
                
                return null
        }

}