source: trunk/grails-app/domain/nl/tno/metagenomics/Study.groovy @ 7

package nl.tno.metagenomics

import nl.tno.metagenomics.auth.*;

/**
 * Minimal representation of a study. The studyToken is the link with a study object in GSCF.
 * 
 * @see GscfService.getStudy
 */
class Study {
        def gscfService
        
        String studyToken
        String name

        // Set to true only on the specific study object that acts as
        // a trash can for deleted objects. If objects are deleted in GSCF but still
        // contain data in this module, they will be moved to the trashcan.
        Boolean trashcan = false 
        
        // If a study is set to be dirty, it should be updated
        // the next time synchronization takes place.
        Boolean isDirty = true;
        
        public String viewUrl() {
                return gscfService.urlViewStudy( studyToken );
        }
        
        static hasMany = [assays: Assay, samples: Sample, auth: Auth]
        static mapping = {
                columns {
                        studyToken index:'studytoken_idx'
                }
                assays cascade: "all-delete-orphan"
                samples cascade: "all-delete-orphan"
                auth cascade: "all-delete-orphan"
        }

        static constraints = {
                studyToken(unique:true)
                trashcan(nullable:true)
                isDirty(nullable:true)
        }
        
        public boolean equals( Object o ) {
                if( o == null )
                        return false
                
                if( o instanceof Study ) {
                        return (o.id != null && this.id != null && o.id == this.id);
                } else {
                        return false
                }
        }

        public boolean canRead( User user ) {
                Auth authorization = auth.find { it.user.equals( user ) }
                
                if( !authorization ) 
                        return false
                
                return authorization.canRead
        }
        
        public boolean canWrite( User user ) {
                Auth authorization = auth.find { it.user.equals( user ) }
                
                if( !authorization ) 
                        return false
                
                return authorization.canWrite
        }

        public boolean isOwner( User user ) {
                Auth authorization = auth.find { it.user.equals( user ) }
                
                if( !authorization ) 
                        return false
                
                return authorization.isOwner
        }

}