source: trunk/grails-app/domain/nl/tno/metagenomics/Run.groovy @ 7

package nl.tno.metagenomics

import org.codehaus.groovy.grails.commons.ConfigurationHolder

/**
 * Holds data belonging to a sequencing run
 * 
 * @author Robert Horlings (robert@isdat.nl)
 *
 */
class Run {
        def fileService

        String  name
        Date    date
        String  machine
        String  supplier
        String  parameterFile

        static hasMany = [assaySamples: AssaySample, assays: Assay]
        static belongsTo = Assay        // Only used to determine the owner of the many-to-many relationship assay-run

        static mapping = {
                columns {
                        name index:'runname_idx'
                }
        }
        static constraints = {
                name(unique:true)
                date(nullable:true)
                machine(nullable:true)
                supplier(nullable:true)
                parameterFile(nullable:true)
        }

        def beforeDelete = {
                // Remove the file if the object is deleted
                if( this.parameterFile )
                        fileService.delete( this.parameterFile, fileService.absolutePath( ConfigurationHolder.config.metagenomics.fileDir ) )
        }

        /**
         * Sets the properties of this run from a form
         * @param params
         * @return
         */
        public setPropertiesFromForm( params ) {
                this.properties = params.run

                // Enter date or default NULL
                if( params.run_date ) {
                        this.date = Date.parse( "yyyy-mm-dd", params.run_date );
                } else {
                        this.date = null
                }

                // Enter filename if needed
                if( params.parameterFile ) {
                        this.parameterFile = fileService.handleUploadedFile(
                                        fileService.get( params.parameterFile ),
                                        "",
                                        fileService.absolutePath( ConfigurationHolder.config.metagenomics.fileDir )
                                        );
                }
        }

        /**
         * Returns the number of files in the system, belonging to this run
         *
         * @return
         */
        public int numFiles() {
                if( !assaySamples )
                        return 0

                int numFiles = 0;
                assaySamples.each { numFiles += it.numFiles() }

                return numFiles;
        }

        /**
         * Returns the number of sequences in the files in the system, belonging to this run
         *
         * @return
         */
        public long numSequences() {
                if( !assaySamples )
                        return 0

                long numSequences = 0;
                assaySamples.each { numSequences += it.numSequences() }

                return numSequences;
        }

        /**
         * Returns the assaySamples associated with this run
         *
         * @return
         */
        public ArrayList samples( def assayId ) {
                if( !assaySamples )
                        return []

                def list = []
                assaySamples.each {
                        if( it.assay.id == assayId )
                                list << it
                }

                return list.unique().toList();
        }
}