source: trunk/grails-app/domain/nl/tno/metagenomics/AssaySample.groovy @ 7

package nl.tno.metagenomics

/**
 * Represents a samples that is used in an assay.
 * 
 * @author Robert Horlings (robert@isdat.nl)
 *
 */
class AssaySample {
        // To be computed in run time
        private long _numSequences = -1;
        private float _averageQuality = -1.0;

        Integer numUniqueSequences      // Number of unique sequences / OTUs. Is only available after preprocessing

        String oligoNumber              // Oligonumber used to identify the sample
        String tagSequence              // Tag originally used to identify the sample

        static belongsTo  = [ assay: Assay, sample: Sample, run: Run ]
        static hasMany    = [ sequenceData: SequenceData ]

        static constraints = {
                numUniqueSequences(nullable: true)
                oligoNumber(nullable: true)
                tagSequence(nullable: true)
                run(nullable: true);
        }

        static mapping = {
                columns {
                        numSequences index:'numsequences_idx'
                }
                sequenceData cascade: "all-delete-orphan"
        }

        /**
         * Returns the number of files in the system, belonging to this 
         * assay-sample combination. 
         * 
         * @return
         */
        public int numFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each { numFiles += it.numFiles() }

                return numFiles;
        }

        /**
         * Returns the number of sequence files in the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public int numSequenceFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each {
                        if( it.sequenceFile )
                                numFiles++
                }

                return numFiles;
        }
        
        /**
         * Returns the number of quality files in the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public int numQualityFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each {
                        if( it.qualityFile )
                                numFiles++
                }

                return numFiles;
        }
        
        /**
         * Returns the number of sequences in the files on the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public long numSequences() {
                if( _numSequences > -1 )
                        return _numSequences;

                if( !sequenceData )
                        return 0

                long numSequences = 0;
                sequenceData.each { numSequences += it.numSequences }

                // Save as cache
                _numSequences = numSequences;

                return numSequences;
        }

        /**
         * Returns the average quality of the sequences in the files on the system, 
         * belonging to this assay-sample combination.
         *
         * @return
         */
        public float averageQuality() {
                if( _averageQuality > -1 )
                        return _averageQuality;

                if( !sequenceData )
                        return 0.0

                int numSequences = 0;
                float averageQuality = 0.0;

                sequenceData.each {
                        numSequences += it.numSequences
                        averageQuality = averageQuality + ( it.averageQuality - averageQuality ) / numSequences * it.numSequences;
                }

                // Save as cache
                _averageQuality = averageQuality;

                return averageQuality;
        }
        
        /**
         * Reset the statistics to their default value, in order to ensure that the values are recomputed next time.
         */
        public void resetStats() {
                _numSequences = -1;
                _averageQuality = -1;
        }
        
        /**
         * Check whether this assay-sample combination contains information that should be saved in trash on a delete
         * @return
         */
        public boolean containsData() {
                return tagSequence || oligoNumber || numFiles() > 0;
        }
        
        /**
         * Move information that should be kept on delete to another assaySample object.
         * 
         * N.B. The sequencedata objects are really moved, so removed from the original object!
         * 
         * @param otherAssaySample      Object to move
         */
        public void moveValuableDataTo( AssaySample otherAssaySample ) {
                // Copy properties
                otherAssaySample.tagSequence = tagSequence;
                otherAssaySample.oligoNumber = oligoNumber;
                otherAssaySample.run         = run;
                
                // Move attached data
                def dataList = sequenceData?.toList()
                def otherAssay = otherAssaySample.assay;
                
                if( dataList && dataList.size() > 0 ) {
                        for( def j = dataList.size() - 1; j >= 0; j-- ) {
                                // Copy data
                                dataList[j].sample = otherAssaySample;
                                this.removeFromSequenceData( dataList[j] );
                                otherAssaySample.addToSequenceData( dataList[j] );
                                dataList[j].save();
                        }
                }
        }
}