source: trunk/grails-app/domain/nl/tno/metagenomics/AssaySample.groovy @ 20

package nl.tno.metagenomics

/**
 * Represents a samples that is used in an assay.
 * 
 * @author Robert Horlings (robert@isdat.nl)
 *
 */
class AssaySample {
        // To be computed in run time
        private long _numSequences = -1;
        private float _averageQuality = -1.0;
        private long _numQualScores = -1;

        Integer numUniqueSequences      // Number of unique sequences / OTUs. Is only available after preprocessing

        String oligoNumber              // Oligonumber used to identify the sample
        String tagSequence              // Tag originally used to identify the sample
        String tagName                  // Tag name

        static belongsTo  = [ assay: Assay, sample: Sample, run: Run ]
        static hasMany    = [ sequenceData: SequenceData ]

        static constraints = {
                numUniqueSequences(nullable: true)
                oligoNumber(nullable: true)
                
                /*
                , validator: { value, obj, errors ->
                        // When one oligoNumber is used in different assaysamples,
                        // they must also have the same tagSequences and tagNames
                        
                        // Check whether this oligoNumber exists in the database
                        def otherAssaySamples = AssaySample.findAllByOligoNumber( value )
                        if( !otherAssaySamples || otherAssaySamples.size() == 0 ) {
                                return true;
                        }
                        
                        // Loop through the other assaysamples with this oligonumber
                        otherAssaySamples.each { otherAS ->
                                // Only check other objects, don't compare with itself (because that
                                // way it wouldn't be possible anymore to edit an object)
                                if( otherAS.id != obj.id ) {
                                        if( otherAS.tagSequence != obj.tagSequence || otherAS.tagName != obj.tagName ) {
                                                return false;
                                        }
                                }
                        }
                        
                        return true
                } 
                 */
                tagSequence(nullable: true)
                tagName(nullable:true)
                run(nullable: true);
        }

        static mapping = {
                columns {
                        numSequences index:'numsequences_idx'
                }
                sequenceData cascade: "all-delete-orphan"
        }

        /**
         * Returns the number of files in the system, belonging to this 
         * assay-sample combination. 
         * 
         * @return
         */
        public int numFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each { numFiles += it.numFiles() }

                return numFiles;
        }

        /**
         * Returns the number of sequence files in the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public int numSequenceFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each {
                        if( it.sequenceFile )
                                numFiles++
                }

                return numFiles;
        }
        
        /**
         * Returns the number of quality files in the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public int numQualityFiles() {
                if( !sequenceData )
                        return 0

                int numFiles = 0;
                sequenceData.each {
                        if( it.qualityFile )
                                numFiles++
                }

                return numFiles;
        }
        
        /**
         * Returns the number of sequences in the files on the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public long numSequences() {
                if( _numSequences > -1 )
                        return _numSequences;

                if( !sequenceData )
                        return 0

                long numSequences = 0;
                sequenceData.each { numSequences += it.numSequences }

                // Save as cache
                _numSequences = numSequences;

                return numSequences;
        }
        
        /**
         * Returns the number of quality scores in the files on the system, belonging to this
         * assay-sample combination.
         *
         * @return
         */
        public long numQualScores() {
                if( _numQualScores > -1 )
                        return _numQualScores;

                if( !sequenceData )
                        return 0

                long numQualScores = 0;
                sequenceData.each { numQualScores += it.numQualScores() }

                // Save as cache
                _numQualScores = numQualScores;

                return numQualScores;
        }
        /**
         * Returns the average quality of the sequences in the files on the system, 
         * belonging to this assay-sample combination.
         *
         * @return
         */
        public float averageQuality() {
                if( _averageQuality > -1 )
                        return _averageQuality;

                if( !sequenceData )
                        return 0.0

                int numSequences = 0;
                float averageQuality = 0.0;

                sequenceData.each {
                        numSequences += it.numSequences
                        averageQuality = averageQuality + ( it.averageQuality - averageQuality ) / numSequences * it.numSequences;
                }

                // Save as cache
                _averageQuality = averageQuality;

                return averageQuality;
        }
        
        /**
         * Reset the statistics to their default value, in order to ensure that the values are recomputed next time.
         */
        public void resetStats() {
                _numSequences = -1;
                _numQualScores = -1;
                _averageQuality = -1;
        }
        
        /**
         * Check whether this assay-sample combination contains information that should be saved in trash on a delete
         * @return
         */
        public boolean containsData() {
                return tagSequence || tagName || oligoNumber || numFiles() > 0;
        }
        
        /**
         * Move information that should be kept on delete to another assaySample object.
         * 
         * N.B. The sequencedata objects are really moved, so removed from the original object!
         * 
         * @param otherAssaySample      Object to move
         */
        public void moveValuableDataTo( AssaySample otherAssaySample ) {
                // Copy properties
                otherAssaySample.tagSequence = tagSequence;
                otherAssaySample.oligoNumber = oligoNumber;
                otherAssaySample.tagName         = tagName;
                
                // Move attached data
                def dataList = [] + sequenceData?.toList()
                def otherAssay = otherAssaySample.assay;
                
                if( dataList && dataList.size() > 0 ) {
                        for( def j = dataList.size() - 1; j >= 0; j-- ) {
                                // Copy data to a new sequencedata object.
                                // Just moving the sequencedata object to the other assay sample resulted
                                // in a 'deleted object would be re-saved by cascade' exception
                                
                                // Clone the sequencedata object
                                def sd = dataList[ j ]?.clone();
                                
                                if( sd )
                                        otherAssaySample.addToSequenceData( sd );
                                        
                                // Remove the old sequencedata object
                                this.removeFromSequenceData( dataList[ j ] );
                        }
                }

                // Copy run properties
                if( otherAssaySample.run ) {
                        otherAssaySample.run.removeFromAssaySamples( otherAssaySample );
                }
                
                // Remove this sample from the run.
                if( run ) {
                        def copyRun = run;
                        copyRun.removeFromAssaySamples( this );
                        copyRun.addToAssaySamples( otherAssaySample );
                } else {
                        otherAssaySample.run = null;
                }
        }
}