source: trunk/grails-app/domain/nl/tno/metagenomics/Assay.groovy @ 2

package nl.tno.metagenomics

/**
 * Minimal representation of an assay. The studyToken is the link with an assay object in GSCF.
 * 
 * @see GscfService.getAssay
 */
class Assay {
        String assayToken
        String name
        
        static belongsTo = [ study: Study ]
        static hasMany   = [ assaySamples: AssaySample, runs: Run ]
        static mapping = {
                columns {
                        assayToken index:'assaytoken_idx'
                }
        }
        
        static constraints = {
                assayToken(unique:true)
        }
        
        /**
         * Removes all assay samples from this assay
         */
        public void removeAssaySamples() {
                if( assaySamples == null ) 
                        return
                        
                def assaySamples = assaySamples.toArray();
                def numAssaySamples = assaySamples.size();
                for( int i = numAssaySamples - 1; i >= 0; i-- ) {
                        def existingSample = assaySamples[i];
                        
                        // Delete the sample and also the association
                        existingSample.delete()
                        removeFromAssaySamples( existingSample );
                }
        }
        
        /**
         * Returns the total number of sequences found in this assay. It is computed
         * as the sum of the number of sequences of all samples
         * @return
         */
        public int numSequences() {
                if( !assaySamples )
                        return 0
                
                int numSequences = 0;
                assaySamples.each { numSequences += it.numSequences() } 

                return numSequences; 
        }

        /**
         * Returns the total number of files in the system, belonging to this assay.
         * It is computed as the sum of the number of files of all samples
         * @return
         */
        public int numFiles() {
                if( !assaySamples )
                        return 0
                
                int numFiles = 0;
                assaySamples.each { numFiles += it.numFiles() }
                
                return numFiles; 
        }       
}