source: trunk/grails-app/controllers/nl/tno/metagenomics/StudyController.groovy @ 14

package nl.tno.metagenomics

import java.util.List;

class StudyController {
        def synchronizationService
        def gscfService
        def fileService
        def trashService
        def fastaService
        def sampleExcelService
        
        def index = {
                // Clean the upload directory
                fileService.cleanDirectory();
                
                // Clean the trash if needed
                trashService.cleanTrash();
                
                // Filter studies for the ones the user is allowed to see
                def studies = Study.list();
                [studies: studies.findAll { it.canRead( session.user ) }, 
                        gscfAddUrl: gscfService.urlAddStudy(), 
                        lastSynchronized: synchronizationService.lastFullSynchronization ] 
        }
        

        /**
         * Exports data about one or more studies in fasta format
         */
        def exportAsFasta = {
                def assaySamples = getAssaySamples( params );
                def name

                if( assaySamples == null ) {
                        return
                } else if( assaySamples*.assay*.study.unique().size() == 1 ) {
                        name = "Study_" + assaySamples[0].assay.study.name?.replace( ' ', '_' );
                } else {
                        name = "studies";
                }

                // Export the sequences and quality scores
                response.setHeader "Content-disposition", "attachment; filename=" + name.trim() + ".zip"
                try {
                        fastaService.export( assaySamples.unique(), response.getOutputStream(), name );
                        response.outputStream.flush();
                } catch( Exception e ) {
                        log.error( "Exception occurred during export of sequences. Probably the user has cancelled the download." );
                }
        }

        /**
         * Export metadata of one or more studies in excel format
         */
        def exportMetaData = {
                def assaySamples = getAssaySamples( params );
                def name

                if( assaySamples == null ) {
                        return
                } else if( assaySamples*.assay*.study.unique().size() == 1 ) {
                        name = "Study_" + assaySamples[0].assay.study.name?.replace( ' ', '_' );
                } else {
                        name = "studies";
                }

                // Export the metadata
                response.setHeader "Content-disposition", "attachment; filename=${name}.xls"
                try {
                        // The export functionality needs a assaySample-tag list, but it
                        // should be empty when only exporting metadata
                        def tags = [];
                        assaySamples.unique().each { assaySample ->
                                tags << [assaySampleId: assaySample.id, sampleName: assaySample.sample.name, assayName: assaySample.assay.name, studyName: assaySample.assay.study.name, tag: "-"]
                        }
                        sampleExcelService.exportExcelSampleData( assaySamples.unique(), tags, response.getOutputStream() );
                        response.outputStream.flush();
                } catch( Exception e ) {
                        log.error( "Exception occurred during export of metadata. Probably the user has cancelled the download." );
                        e.printStackTrace();
                }
        }

        /**
         * Parse the given parameters and try to extract studies using ids and tokens
         * @param params
         * @return
         */
        protected List getAssaySamples( params ) {
                def tokens = params.list( 'tokens' );
                def ids = params.list( 'ids' );
                def name;

                ids = ids.findAll { it.isLong() }.collect { Long.parseLong( it ) }

                if( !tokens && !ids ) {
                        def message = "No assay tokens or ids given"
                        flash.error = message
                        redirect( action: "index" );
                        return;
                }

                def assaySamples = [];

                // Determine which assaySamples to export
                def study;
                tokens.each { token ->
                        study = Study.findByStudyToken( token );
                        if( study && study.canRead( session.user ) )
                                assaySamples += study.assays*.assaySamples.flatten();
                }
                ids.each { id ->
                        study = Study.get( id );
                        if( study && study.canRead( session.user ) )
                                assaySamples += study.assays*.assaySamples.flatten();
                }

                return assaySamples;
        }

}